/45
/
/
/%R	STACKER RUN OUT CONTROL
/
/%TW	THIS ROUTINE IS ENABLED BY "LP07" WHENEVER THE 
/	OPERATOR ENTERS THE STACKER RUNOUT MODE.  COME HERE
/	FROM "MEMORY" FOR EACH MOTION PULSE WHILE CLEARING
/	THE STACKER TO SEQUENCE THE SHEETS IN THE STACKER
/	BELTS INTO THE APPROPRIATE TRAYS.  "SROCTR" ALS0
/	CHECKS THE RUNOUT TRAP SET UP BY "LP07" AND WHEN THE
/	TRAP GOES TO ZERO, THE STACKER IS CLEAR AND THE MAST
/	MONITOR INTERLOCK IS USED TO STOP THE MACHINE.  THE
/	"STACKER RUNOUT FINISHED" MESSAGE IS ALSO DISPLAYED
/	ON THE OPERATOR'S CRT AND FURTHER MOTION PULSES ARE
/	DISABLED UNTIL THE MACHINE HAS STOPPED.
/
/%TD	DURING RUNOUT THE CHOPPER IS NOT MOVING AND "SROCTR"
/	SIMULATES THE NECESSARY CHOP PULSES.  THE PSUEDO
/	CHOP PULSES ARE GENERATED WHENEVER THE SHEET LENGTH
/	COUNTER EQUALS THE KNOWN SHEET LENGTH.  THESE CHOP
/	SIGNALS ARE NEEDED TO SEQUENCE THE JUMP TABLE.  THE
/	MOTION PULSES OCCUR AS USUAL SINCE THE MOTION 
/	ENCODER IS DRIVEN BY THE STACKER.
/
/
SROCTR,	CLB
	ISZ SROTRP	/YES, HAVE WE DONE ENOUGH RUN OUT ?
	JMP SROC1	/NO, GO ON
	CLB STL RTR	/YES, GO OPEN THE "MAST MONITOR"
	JMS INLOCK	/INTERLOCK.
	CIF 30
	JMS I (CRTMSG)	/GO DISPLAY THE "STACKER RUN OUT
	CRTM06		/FINISHED" MESSAGE.
	ISZ SRODNF	/SET THE STACKER RUN OUT DONE FLAG
	CLB IAC		/DISABLE THE MOTION ENCODER INTERRUPT
	DCA MOTENB
	CLB CMA
	DBCO50		/TURN OFF ALL THE STACKER GATES
	JMP INTRET	/RETURN THRU THE INTERRUPT RELEASE

SROC1,	TAD SHLCNT	/DOES THE SHEET LENGTH COUNTER EQUAL
	CIA		/THE KNOWN SHEET LENGTH ?
	TAD SHLENG
	SMA SZA CLA
	JMP SROC2	/NO, GO ON
	CLB CMA		/YES, INCREMENT THE MEMORY POINTER TO
	TAD MEMPTR	/FAKE A CHOP PULSE, SINCE THE CHOPPER
	AND P177	/IS NOT MOVING.
	TAD (MEMTBL)
	DCA MEMPTR
	DCA SHLCNT	/RESET THE SHEET LENGTH COUNTER
SROC2,	JMS MEMWRK	/GO DO THE JUMP TABLE WORK
	JMP INTRET	/RETURN THRU THE INTERRUPT RELEASE