100 DIM S(10),Q(10),N(500)
110 DEF FNA(Z1,Z2)=SQR(Z1/(Z2-1))
120 DEF FNB(Z1,Z2,Z3)=Z1-Z2*Z2/Z3
130 GOTO 210
140 PRINT\PRINT\ PRINT "OPTION NR <9 FOR HELP>";
150 INPUT O
160 IF O=9 THEN 960
170 IF O=1 THEN 710
180 IF O=2 THEN 780
190 IF O=4 THEN 900
200 IF O<>0 THEN 140
210 PRINT "GROUP NR ",
220 INPUT N0
230 IF N0=0 GOTO 210
240 IF N0>10 GOTO 210
250 N1=N0
252 N0=ABS(N0)
255 IF N(N0)=0GOTO 330
260 PRINT"INPUT 99 TO CLEAR DATA";
270 INPUT O
280 IF O <> 99 THEN 310
290 S(N0)=0
300 O=1\GOTO 330
310 PRINT "INPUT 1 TO ADD DATA 2 TO DELETE ";
320 INPUT O
330 IF N1<0 GOTO 520
340 PRINT "NO OF DATA ";\ INPUT M
350 N=N(N0)
360 IF O=2 THEN 440
370 FOR I=N+1 TO N+M
380 INPUT X
390 S(N0)=S(N0)+X
400 Q(N0)=Q(N0)+X*X
410 NEXT I
420 N(N0)=N(N0)+M
430 GOTO 140
440 FOR I=N TO N-M+1 STEP -1
450 INPUT X
460 S(N0)=S(N0)-X
470 Q(N0)=Q(N0)-X*X
490 NEXT I
500 N(N0)=N(N0)-M
510 GOTO 140
520 REM INPUT IN THE FORM OF N,M,SD OR SEM
540 PRINT "SEM OR SD BUT NOT BOTH MAY BE ZERO"
550 PRINT "INPUT N,M,SEM,SD",\INPUT N,M,S,S1
560 IF S1>0 GOTO 580
570 S1=S*SQR(N)
580 S=M*N
585 IF S1=0GOTO 540
590 Q=S1*S1*(N-1)+S*S/N
600 IF O<>2THEN640
610 N=-N
620 S=-S
630 Q=-Q
640 N(N0)=N(N0)+N
650 S(N0)=S(N0)+S
660 Q(N0)=Q(N0)+Q
670 GOTO 140
710 PRINT "GROUP","NUMBER","MEAN","SEM","SD"
720 FOR N0=1 TO 10
730 IF N(N0)<3 GOTO 760
740 S=FNA(FNB(Q(N0),S(N0),N(N0)),N(N0))\S2=S/SQR(N(N0))
750 PRINT N0,N(N0),S(N0)/N(N0),S2,S
760 NEXT N0
770 GOTO 140
780 PRINT "T TEST SD EQUAL (TYPE 1)"
790 PRINT "GROUPS NR ",
800 INPUT I,J
810 N1=N(I)\N2=N(J)
820 IF N1 < 3 GOTO 830\IF N2 < 3 GOTO 830\GOTO 840
830 PRINT "BAD DATA "\GOTO 140
840 S1=FNB(Q(I),S(I),N1)
850 S2=FNB(Q(J),S(J),N2)
860 S=(S1+S2)/(N1+N2-2)
870 T=(S(I)/N1-S(J)/N2)/SQR(S*(1/N1+1/N2))
880 PRINT "T= ",T,N1+N2-2;" DEGREES OF FREEDOM"
890 GOTO 140
900 PRINT  "VARIABLE ","SUM","SUMSQ","SUM OF SQUARES"
910 FOR N0=1 TO 10
920 IF N(N0)=0 GOTO 940
930 PRINT N0,S(N0),Q(N0),FNB(Q(N0),S(N0),N(N0))
940 NEXT N0
950 GOTO 140
960 PRINT "OPTIONS ARE"
970 PRINT" 0= NEW DATA <CAN BE ADDED OR DELETED>"
980 PRINT" 1= MEANS ETC"
990 PRINT "2= T-TEST"
1000 PRINT "4= SUMS "
1010 GOTO 140
1020 END