100 DEF FNA(Z1)=SQR(Z1/(N-1))
110 DEF FNB(Z3,Z2)=Z2-Z3*Z3/N
120 GOSUB 560
130 GOTO 290
140 PRINT\PRINT\ PRINT "OPTION NR <9 FOR HELP>";
150 INPUT O
160 IF O=9 THEN 990
170 IF O=1 THEN 680
180 IF O=2 THEN 740
190 IF O=3 THEN 790
200 IF O=4 THEN 920
210 IF O<>0 THEN 140
220 PRINT"INPUT 99 TO CLEAR DATA";
230 INPUT O
240 IF O <> 99 THEN 270
250 GOSUB 560
260 O=1\GOTO 290
270 PRINT "INPUT 1 TO ADD DATA 2 TO DELETE ";
280 INPUT O
290 PRINT "NO OF DATA ";\ INPUT M
300 Q1=0
310 IF O=2 THEN 440
320 FOR I=N+1 TO N+M
330 PRINT I;\INPUT X,Y
340 X1=X1+X
350 X2=X2+X*X
360 Y1=Y1+Y
370 Y2=Y2+Y*Y
380 S1=S1+Y*X
390 D1=D1+X-Y
400 D2=D2+(X-Y)^2
410 NEXT I
420 N=N+M
430 GOTO 140
440 FOR I=N TO N-M+1 STEP -1
450 PRINT I;\INPUT X,Y
460 X1=X1-X
470 X2=X2-X*X
480 Y1=Y1-Y
490 Y2=Y2-Y*Y
500 S1=S1-X*Y
510 D1=D1-(X-Y)
520 D2=D2-(X-Y)^2
530 NEXT I
540 N=N-M
550 GOTO 140
560 REM THE ZEROING RUTINE
570 X1=0\Y1=0\X2=0\Y2=0
580 S1=0\D1=0\D2=0\N=0
590 RETURN
600 REM CALCULATE SUMS OF SQUARES
610 IF Q1<>0 THEN 670
620 S2=SQR(N)
630 Q1=FNB(X1,X2)
640 Q2=FNB(Y1,Y2)
650 Q4=FNB(D1,D2)
660 Q3=S1-X1*Y1/N
670 RETURN
680 PRINT N;" OBSERVATIONS"
690 GOSUB 600
700 PRINT "GROUP","MEAN","SD","SEM"
710 PRINT "X",X1/N,FNA(Q1),FNA(Q1)/S2
720 PRINT "Y",Y1/N,FNA(Q2),FNA(Q2)/S2
730 GOTO 140
740 PRINT "T TEST PAIRED VALUES (TYPE 3)"
750 GOSUB 600
760 S=FNA(Q4)
770 PRINT "T= ";D1/N/S*SQR(N),"DF= ";N-1
780 GOTO 140
790 PRINT "Y=B*X+A"
800 GOSUB 600
810 PRINT "CONST","VALUE","S ERROR"
820 B=Q3/Q1\A=Y1/N-B*X1/N
830 S=Q2-Q3*Q3/Q1\S=S/(N-2)
840 PRINT "A",A,SQR(S*(1/N+(X1/N)^2/Q1))
850 PRINT "B",B,SQR(S/Q1)
860 PRINT "PLOT LINE ? INPUT 1 FOR YES";\INPUT O
870 IF O<>1 THEN 140
880 PRINT" INPUT X;END WITH X=0"
890 INPUT X\IF X=0 THEN 140
900 Y=A+B*X\PRINT ,"Y=";Y,"ERROR Y =";SQR(S*(1/N+(X-X1/N)^2/Q1))
910 GOTO 890
920 PRINT  "VARIABLE ","SUM","SUMSQ","SUM OF SQUARES"
930 GOSUB 600
940 PRINT "X",X1,X2,Q1
950 PRINT "Y",Y1,Y2,Q2
960 PRINT "X*Y",S1,S2,Q4
970 PRINT "X-Y",D1,D2,Q3
980 GOTO 140
990 PRINT "OPTIONS ARE"
1000 PRINT" 0= NEW DATA <CAN BE ADDED OR DELETED>"
1010 PRINT" 1= MEANS ETC"
1020 PRINT "2= PAIRED T-TEST"
1030 PRINT "3= REGRESSION LINE"
1040 PRINT "4= SUMS OF SQUARES"
1050 GOTO 140
1060 END