Directory of image this file is from
This file as a plain text file

/DECTAPE DEVICE HANDLER

SDSS=6771
SDST=6772
SDSQ=6773
SDLC=6774
SDLD=6775
SDRC=6776
SDRD=6777


*2607
NOPUNCH
*7607
ENPUNCH


DTA0,	0
	CLL CLA CMA RTL
	DCA TRYCNT
	RDF
	TAD SCIF
	DCA LEAVE
	TAD I DTA0
	DCA XFUNCT
	ISZ DTA0
	TAD I DTA0
	DCA XBUFFA
	ISZ DTA0
	TAD I DTA0
	CLL RAL
	DCA BLOCK
	ISZ DTA0
	TAD XFUNCT
	AND N3700
	BSW CMA
	CLL IAC
	DCA PGCT

GOREV,	SDRC
	CMA RTL
GO,	CLA RTR
C1000,	TAD C1000
	SDLC
	CLA CLL CML RAR
	TAD XFUNCT
	CDF CIF 20
	AND C70
	TAD C6201
	DCA I C7640	/XFIELD
	TAD XBUFFA
	DCA I S7600	/XBUFF
	RAL
C6201,	CDF 0
	JMS PAGE2

	JMP RWCOM
TRY3,	ISZ TRYCNT
	JMP GOREV
	JMP FATAL

RWCOM,	SDST
C7640,	SZA CLA
	JMP TRY3

	TAD C200
	TAD XBUFFA
	DCA XBUFFA
	ISZ BLOCK

GOA,	ISZ PGCT
	JMP GO
EXIT,	ISZ DTA0
FATAL,	SDLC
S7600,	7600
LEAVE,	HLT
	JMP I DTA0

N3700,	3700

C70,	70




KRBSR,	0
	CLA RAL
	DCA LINK
	RDF
	TAD SCIF
	DCA RETFLD
ROUND,
INS1,	KSF
	JMP .-1
INS5,	KRS
	TAD S7600
	SNA CLA
	JMP NEWMON
	TAD LINK
	CLL RAR
INS2,	KRB
RETFLD,	0
	JMP I KRBSR

C35,	35


NEWMON,	TAD C35
	CIF CDF 10
	JMP 7705




TRYCNT,
FELDSR,	0
	DCA SAVE
	RDF
	TAD SCIF
	DCA RTFLD2
SCIF,	CIF CDF 0
	TAD I FELDSR
	DCA .+3
	TAD SAVE
BACKGO,
XFUNCT,
RTFLD2,	0	/MULTI-OVERLAY AREA	/JMS 7607
XBUFFA,	0				/1010
BLOCK,	0				/0
SAVE,
PGCT,	0				/64
MQSAV,	0				/HLT
	HLT				/JMP ROUND




NOPUNCH
*.+3
ENPUNCH

C200,	200

LINK,
EAEMOD,
KSFSR,	0
INS6,	KSF
	SKP
	ISZ KSFSR
	JMS FELDSR
	JMP I KSFSR

FIELD 2


*7600


XBUFF,	0




UNIT,
WRQUAD,	0
	JMS EQUFUN
	SDSQ
	JMP .-1
	SDLD
	CLA
	JMP I WRQUAD


PAGE2,	0
	DCA UNIT
	JMS RDQUAD
	JMS RDQUAD
M20,	-20
SRCH,	SDSS
	JMP SRCH
ENDZ2,	SDRC
	CLL RTL
	AND C374
	TAD M110
	SNA
	JMP ENDZ
	TAD M20
	SZA CLA
	JMP SRCH
	SDRD
	SZL
	TAD C3
	CMA
	TAD I C7740
	CMA CML
	SZA
	JMP NTFUND


FOUND,
WORDS,
XFIELD,	HLT
	SNL CLA
	JMP RGO
REVGRD,	SDSS
	JMP REVGRD
	SDRC
C300,	AND K77
	TAD CM32
	SZA CLA
	JMP REVGRD
	TAD C7600
	DCA WORDS
	TAD UNIT
	CLL RTR
K7700,	SMA CLA
	JMP READ
WRITE,	SDRC
	AND C300
C7740,	SZA SMA CLA	/SMA FOR CONST.
	JMP TRYRET
	JMS RDQUAD
C7600,	7600
	TAD C1600
	TAD UNIT
	SDLC
	CMA CLA
	JMS WRQUAD
	CMA CLA
	DCA CHKSUM
C1600,
WRLP,	TAD I XBUFF
	JMS WRQUAD
	ISZ XBUFF
K77,	77
	ISZ WORDS
	JMP WRLP
	JMS WRQUAD
	JMS GETCHK
	JMS WRQUAD
	JMS WRQUAD
	JMP WRRET

NTFUND,
M110,	CLA SNA SZL
	JMP RGO
	JMP SRCH




ENDZ,	SNL CLA
RGO,	ISZ PAGE2
TRYRET,	ISZ PAGE2
WRRET,	CDF CIF 0
	JMP I PAGE2


GETCHK,	0
	TAD CHKSUM
	CMA BSW CLL
	JMS EQUFUN
	CLL CLA
	TAD CHKSUM
	AND K7700
	JMP I GETCHK




EQUTMP,
RDQUAD,	0
	SDSQ
	JMP .-1
	SDRD
	JMP I RDQUAD


EQUFUN,	0
	DCA EQUTMP
	TAD EQUTMP
C374,	AND CHKSUM
	CIA
	CLL RAL
	TAD EQUTMP
	TAD CHKSUM
	CMA
	DCA CHKSUM
	TAD EQUTMP
	JMP I EQUFUN


READ,	JMS RDQUAD
	JMS RDQUAD
	JMS RDQUAD
	AND K77
	TAD K7700
	DCA CHKSUM
RDLP,	JMS RDQUAD
	JMS EQUFUN
	DCA I XBUFF
	ISZ XBUFF
C3,	3
	ISZ WORDS
	JMP RDLP
	JMS RDQUAD
	JMS EQUFUN
RDLP2,	JMS RDQUAD
	AND K7700
	JMS EQUFUN
	CLA SKP
CHKSUM,	0
	JMS GETCHK
	JMP WRRET



CM32,	-32




$$$$$$$$$$$$$$$$$$$$$$