CLEAR=JMS I 40
SET=JMS I 41
PULSE=JMS I 42
INPUT=JMS I 43
OUTPUT=JMS I 44
LOAD=JMS I 45
READ=JMS I 46

HIGH=400
LOW=200
SELECT=6400
MEMADR=0
DEVADR=0
MEMDAT=1000
PDPDAT=3000
PERDAT=2000

*40
SRCLR
SRSET
SRPULS
SRINPT
SROUT
SRLOAD
SRREAD

*N0003&7600+200
/CALL RAMLOD   LADEN VON DATEN AUS PDP8 IN TESTER-MEMORY
/1. ARGUMENT: ANFANGSADR. LOW TESTER-MEMORY 8 BIT
/2. ARGUMENT: ANFANGSADR. HIGH TESTER-MEMORY 8 BIR
/3. ARGUMENT: ENDADR. LOW TESTER-MEMORY 8 BIT
/4. ARGUMENT: ENDADR.: HIGH TESTER-MEMORY 8 BIT
/5. ARGUMENT: ANFANGSADR. LOW PDP8 12 BIT
/6. ARGUMENT: ANFANGSADR. HIGH PDP8 3 BIT






PAGE


/CALL SRCLR, STEUERSIGNALE =0
/1. ARGUMENT: STEUERSIGNALE


SRCLR,	0
	CLA
	TAD I SRCLR
	6506
	ISZ SRCLR
	CLA
	JMP I SRCLR



/CALL SRSET, STEUERSIGNALE = 1
/1. ARGUMENT: STEUERSIGNALE


SRSET,	0
	CLA
	TAD I SRSET
	6505
	ISZ SRSET
	CLA
	JMP I SRSET


/CALL SRPULS, STEUERSIGNALE =1,0
/1. ARGUMENT: STEUERSIGNALE


SRPULS,	0
	CLA
	TAD I SRPULS
	6505
	6506
	ISZ SRPULS
	CLA
	JMP I SRPULS


/CALL SRPDPI, AUSLESEN AUS TESTER-MEMORY IN PDP8
/INPUT IN AC


SRINPT,	0
	6504
	AND N377
	JMP I SRINPT


/CALL SRPDOT, AUSLESEN AUS PDP8 IN TESTER-MEMORY
/OUTPUT IN AC


SROUT,	0
	6506
	CMA
	6505

	PULSE
	STROBE

	JMP I SROUT








/CALL SRLOAD
/1. ARGUMENT: INPUTSELECTOR A,B,C,D

/400=HIGH <AC> NACH HIGH XXX
/200=LOW,  <AC> NACH LOW XXX
/000=LOW,HIGH, <AC,MQ> NACH LOW,HIGH XXX
/XXX= MEMADR, MEMDAT, PDPINP


SRLOAD,	0
	AND N377
	DCA SRTEM

	TAD I SRLOAD
	AND NLOW
	SZA CLA
	JMP SRLDLO

	TAD I SRLOAD
	AND NHIGH
	SZA CLA
	JMP SRLDHG

	TAD SRTEM
	SWP
	AND N377
	DCA SRTEM

SRLDLO,	TAD I SRLOAD
	AND N7000
	TAD SRTEM
	OUTPUT		/LOW

	TAD I SRLOAD
	AND NLOW
	SZA CLA
	JMP SRLDED

	MQA
	DCA SRTEM

SRLDHG,	TAD I SRLOAD
	AND N7000
	TAD NHIGH
	TAD SRTEM
	OUTPUT		/HIGH

SRLDED,	ISZ SRLOAD
	CAM
	JMP I SRLOAD






/CALL SRREAD
/1. ARGUMENT: OUTPUTSELECTOR RA,RB,RC

/400=HIGH, <AC> NACH HIGH XXX
/200=LOW , <AC> NACH LOW XXX
/000=LOW,HIGH, <AC,MQ> NACH <HIGH, LOW XXX>
/XXX= DEVADR, MEMDAT, PERDAT



SRREAD,	0

	CLEAR
	SELECT

	TAD I SRREAD
	AND N6000
	DCA SELARG

	SET
SELARG,	0

	CLA
	TAD I SRREAD
	AND NHIGH
	SZA CLA
	JMP SRREHG

	INPUT		/LOW
	DCA SRTEM

	TAD I SRREAD
	AND NLOW
	SZA CLA
	JMP SRREED

	TAD SRTEM
	MQL

SRREHG,	SET
	HIGH

	INPUT		/HIGH
	DCA SRTEM

SRREED,	TAD SRTEM
	ISZ SRREAD
	JMP I SRREAD



SRTEM,	0
NLOW,	LOW
NHIGH,	HIGH
N377,	377
N6000,	6000
N7000,	7000


STROBE=400
TESTCL=200
PDP8CL=100
PDP8WR=40
PDP8WL=20

PDP8CF,	100