Directory of image this file is from
This file as a plain text file

CLEAR=JMS I 40
SET=JMS I 41
PULSE=JMS I 42
INPUT=JMS I 43
OUTPUT=JMS I 44
SETSEL=JMS I 45
CLRSEL=JMS I 46
LOAD=JMS I 47
READ=JMS I 50

HIGH=400
LOW=200

MEMADR=0
DEVADR=0
MEMDAT=1000
PDPDAT=3000
PERDAT=2000


*40
SRCLR
SRSET
SRPULS
SRINPT
SROUT
SRSTSE
SRCLSE
SRLOAD
SRREAD


*1000


/CALL SRCLR, STEUERSIGNALE =0
/1. ARGUMENT: STEUERSIGNALE


SRCLR,	0
	CLA
	TAD I SRCLR
	6506
	ISZ SRCLR
	CLA
	JMP I SRCLR



/CALL SRSET, STEUERSIGNALE = 1
/1. ARGUMENT: STEUERSIGNALE


SRSET,	0
	CLA
	TAD I SRSET
	6505
	ISZ SRSET
	CLA
	JMP I SRSET


/CALL SRPULS, STEUERSIGNALE =0,1,0
/1. ARGUMENT: STEUERSIGNALE


SRPULS,	0
	CLA
	TAD I SRPULS
	6506
	6505
	6506
	ISZ SRPULS
	CLA
	JMP I SRPULS


/CALL SRPDPI, AUSLESEN AUS MEMORY IN RECHNER
/INPUT IN AC


SRINPT,	0
	6504
	AND 377
	JMP I SRINPT


/CALL SRPDOT, AUSLESEN AUS RECHNER INS 4KRAM
/OUTPUT IN AC


SROUT,	0
	6506
	CMA
	6505

	PULSE
	STROBE

	JMP I SROUT



/CALL SRSTSE, SETZEN OUTPUTSELECTOR
/SELECTOR IN AC


SRSTSE,	0
	AND N7400
	6515

	PULSE
	STROBE

	CLA
	JMP I SRSTSE


/CALL SRCLSE, CLEAR OUTPUTSELECTOR
/SELECTOR IN AC


SRCLSE,	0
	AND N7400
	6516
	CLA
	JMP I SRCLSE




/CALL SRLOAD
/1. ARGUMENT: INPUTSELECTOR A,B,C,D

/400=HIGH <AC> NACH HIGH XXX
/200=LOW,  <AC> NACH LOW XXX
/000=LOW,HIGH, <AC,MQ> NACH LOW,HIGH XXX
/XXX= MEMADR, MEMDAT, PDPINP


SRLOAD,	0
	AND 377
	DCA SRTEM

	TAD I SRLOAD
	AND NLOW
	SZA CLA
	JMP SRLDLO

	TAD I SRLOAD
	AND NHIGH
	SZA CLA
	JMP SRLDHG

	TAD SRTEM
	MQL
	AND 377
	DCA SRTEM

SRLDLO,	TAD I SRLOAD
	AND N7400
	TAD SRTEM
	OUTPUT

	TAD I SRLOAD
	AND NLOW
	SZA CLA
	JMP SRLDED

	MQA
	DCA SRTEM

SRLDHG,	TAD I SRLOAD
	AND N7400
	TAD N400
	TAD SRTEM
	OUTPUT

SRLDED,	ISZ SRLOAD
	CAM
	JMP I SRLOAD






/CALL SRREAD
/1. ARGUMENT: OUTPUTSELECTOR RA,RB,RC

/400=HIGH, <AC> NACH HIGH XXX
/200=LOW , <AC> NACH LOW XXX
/000=LOW,HIGH, <AC,MQ> NACH <HIGH, LOW XXX>
/XXX= DEVADR, MEMDAT, PERDAT



SRREAD,	0
	CLA
	TAD I SRREAD
	AND NHIGH
	SZA CLA
	JMP SRREHG

	TAD I SRREAD
	SETSEL		/SET OUTPUTSELECTOR
	INPUT
	DCA SRTEM
	CLRSEL		/CLEAR OUTPUTSELECTOR

	TAD I SRREAD
	AND NLOW
	SZA CLA
	JMP SRREED

	TAD SRTEM
	MQL

SRREHG,	TAD I SRREAD
	SETSEL		/SET OUTPUTSELECTOR
	INPUT
	DCA SRTEM
	CLRSEL		/CLEAR OUTPUTSELECTOR

SRREED,	TAD SRTEM
	ISZ SRREAD
	JMP I SRREAD



SRTEM,	0
NLOW,	200
NHIGH,	400
N377,	377
N7400,	7400
N400,	400


STROBE=400
TESTCL=200
PDP8CL=100
PDP8WR=40
PDP8WL=20