/********************ATAL LOW PASS FILTER*************************


/CALL:	ATALTP
/	INPUT
/	OUTPUT
/	SIGNAL DELAY LINE	/25 OCT LOCATIONS
/	STATE			/POINTER FOR SHFTRG



/PRECISION OF SIGNAL AND COEFFICIENTS 14 BITS


PAGE


ATALTP,	4


	COPY
	ZERO
	TPTEM2


	SHFTRG
	TPSHFT
	1

	BLOUT
	CLA IAC
	DCA TPTAPN

	TAD TPA0
	DCA TPA0P

	TAD N25
	CMA
	DCA TPCNT

TPLOOP,	ISZ TPCNT
	SKP
	JMP TPLPF


	INBLIP


	TAP
	TPTAPN
	TPTEM1


	MULTSG
	TPTEM1
	N14
TPA0P,	0
	N14
	TPTEM1
	N30


	ADDER
	TPTEM1
	NNX14
	TPTEM2
	NNX14
	ZERO
	TPTEM2


	CHOP		/CHOP TP - AC
	TPTEM2
	N30
	TPTEM2


	BLOUT

	ISZ TPTAPN
	ISZ TPA0P
	JMP TPLOOP

TPLPF,	INBLIP


	SCALSG
	TPTEM2
	N30
	CM14
	2


	BLEND


TPSHFT,	3
	N25
	ONE
	4
N25,	25
N30,	30
CM14,	-14
TPCNT,	0
TPTAPN,	0
TPTEM1,	ZBLOCK N
TPTEM2,	ZBLOCK N
TPA0,	.+1
	17
	35
	37
	-26
	-221
	-363
	-177
	521
	2057
	3342
	3776
	3342
	2057
	521
	-177
	-363
	-221
	-26
	37
	35
	17




PAGE



/****************** PITCH EXTRACTOR *********************


/CALL:	PITEX
/	INPUT
/	INPUT PRECISION
/	OUTPUT
/	STATE
/	STATE PRECISION
/	STATE UPDATE BLOCK
/	1.ARG
/	2.ARG.
/	3.ARG.



PITEX,	11

	6		/STATE UPDATE BLOCK
	7
	10
	11
	4
	5


	BLOTNT
	PXINT


PXSTRT,	JMS RECTGT
	SNL CLA
	JMP PXGOON

	JMS HWRSR
	INEND

PXGOON,	ACUM
	2
	CIA
	ACUM
	5
	DCA PXSHFT


	INBLIP


	SCALSG
	1
	2
	PXSHFT
	PXTEM1


	COMPLM
	4
	PXTEM2


	ADDER
	PXTEM1
	5
	PXTEM2
	5
	ONE
	PXTEM2


	BLOUT

	ACUM
	5
	DCA PRECIS

	TAD PXTM2P
	DCA TM2POI

	GETAD
	1
	DCA INPOI
	GETAD
	3
	DCA TM1POI
	JMS SIGNSR	/DON'T DISTURB LINK FROM NOW ON

	JMS HWRSR
	SZL CLA
	INEND

	TAD PXTM1P
	DCA INPOI
	GETAD
	4
	DCA TM1POI
	JMS HWRSR

	ACUM
	11
	CLL RAL
	CLL CML RAR
	PUT
	11
	INEND

PXINT,	INBLIP


	COPY
	ZERO
	4

	BLOUT

	JMP PXSTRT

PXTM1P,	PXTEM1
PXTM2P,	PXTEM2
PXTEM1,	ZBLOCK N
PXTEM2,	ZBLOCK N
PXSHFT,	0




/**************** LINEAR DECREMENT *******************************


/CALL:	LINDEC
/	DECREMENT
/	LOWER LIMIT
/	DUMMY
/	STATE
/	STATE PRECISION


LINDEC,	5


	ADDER
	1
	NNX14
	2
	NNX14
	ZERO
	DCMTEM


	COMPLM
	DCMTEM
	DCMTEM


	ADDER
	4
	5
	DCMTEM
	5
	ONE
	DCMTEM


	HWRECT
	DCMTEM
	5
	DCMTEM


	ADDER
	DCMTEM
	5
	2
	5
	ZERO
	4


	BLEND


DCMTEM,	ZBLOCK N






PAGE


/*************LINEAR + EXPONENTIAL DECAY**************************



/CALL:	LINEXP				/READS PXFLAG!!!!!!!
/	DECREMENT OF LINEAR PART
/	DECAY OF EXP. PART		/NEG., POWER OF 2
/	COUNT LIN-EXP			/SINGLE WORD STATE
/	STATE
/	STATE PRECISION



LINEXP,	5


	BLOTNT
	LEINIT

LESTRT,	GETAD
	3
	DCA LEPNT1
	TAD I LEPNT1
	CLL RAL			/FLAG IN LINK
	SNL
	JMP LEDO
	CLA
	TAD LENUM
	CIA
	JMP LINDO

LEDO,	CLL CML RAR
	IAC
	SZA
	JMP LINDO
	CLA CLL CMA RAR
	DCA I LEPNT1


	INBLIP

	SCALSG
	4
	5
	2
	LETEM


	COMPLM
	LETEM
	LETEM


	ADDER
	LETEM
	NNX14
	4
	NNX14
	ONE
	4


	BLEND


LINDO,	CLL RAL		/FLAG DOWN
	CLL RAR
	DCA I LEPNT1

	INBLIP


	LINDEC
	1
	ZERO
	ZERO
	4
	5


	BLEND

LEINIT,	CLA
	PUT
	3
	JMP LESTRT



LETEM,	ZBLOCK N
LENUM,	50
LEPNT1,	0







/*******************IMPULS GENERATOR*****************************



/CALL	:	IMPULS
/		OUTPUT
/		IMPULS
/		DISTANCE BETWEEN IMPULSES
/		STATE



IMPULS,	4

	BLOTNT
	IMPINT


IMPDO,	GETAD
	4
	DCA IMPPTR

	ISZ I IMPPTR
	JMP IMPNO

	ACUM
	3
	CIA
	DCA I IMPPTR

	INBLIP
	COPY
	2
	1


	BLEND


IMPNO,	INBLIP
	

	COPY
	ZERO
	1


	BLEND


IMPINT,	CLA CMA
	PUT
	4
	JMP IMPNO



IMPPTR,	0