Directory of image this file is from
This file as a plain text file

/ CHECK THE STATUS OF THE STACKER TRAYS         5-AUG-91
/
/
/
/	TTTTT  RRRR    AAA   Y   Y   CCCC  K   K
/	  T    R   R  A   A  Y   Y  C      K  K
/	  T    R   R  A   A   Y Y   C      K K
/	  T    RRRR   A   A    Y    C      KK
/	  T    R R    AAAAA    Y    C      K K
/	  T    R  R   A   A    Y    C      K  K
/	  T    R   R  A   A    Y     CCCC  K   K
/
/
/

/
/EDIT HISTORY:
/
/18-JUN-90	(LHN)
/	1) CHANGED "JMP I TRAYCK" TO "JMP START", THERE
/	   FROM ORIGINAL CODE TRANSFER FROM #12
/
/13-JUL-90	(LHN)
/	1) CHANGED SAMPLE TRAY OUT TEST TO LOOK AT THE
/	   NUMBER OF SHEETS LEFT IN THE CURRENT PRODUCT
/	   TRAY
/
/30-AUG-90	(LHN)
/	1)  ADDED MESSAGE CODE TO INLOCK MESSAGE
/	
/
/
/27-JUL-91	(LHN)		FOR VERSION 4
/	1)  ADDED CHECK FOR FIELD INPUTS DISABLED
/

/


	TASK=	TRAYCK
	CUR=	TRYCKFLD
	INIWT=	0
	VERS=	3



	FIELD  TRYCKFLD%10
	*TRYCKLOC



/
/
/%R	CHECK THE STATUS OF THE STACKER TRAYS
/
/%TW	COME HERE ONCE PER CHOP VIA THE JUMP TABLE TO 
/	MONITOR THE STATUS OF THE STACKER TRAYS.  TURN
/	ON THE "TRAY NEEDED" INDICATORS AS REQUIRED AND
/	STOP THE FINISHING MACHINE IF NEEDED TRAYS
/	ARE NOT RETURNED IN TIME.  WHEN ANY "TRAY NEEDED"
/	INDICATOR IS FLASHING, THE "TRAY OUT" MESSAGE IS 
/	DISPLAYED ON THE OPERATOR'S CRT, AND THE ALERT
/	ALARM IS SOUNDED.
/
/%TW	THE SAMPLE TRAY NEEDED LIGHT WILL COME ON AS
/	SOON AS THE SAMPLE TRAY GOES OUT. WHEN THE SAMPLE
/	TRAY IS OUT, THS MACHINE WILL STOP WHEN THE 
/	CURRENT PRODUCT TRAY WILL HOLD ONLY 10 MORE 
/	SHEETS.
/	NORMAL SAMPLING IS INTERRUPTED WHENEVER THE SAMPLE
/	TRAY IS OUT.
/
/%TW	WHEN A REJECT TRAY IS EJECTED, IT MAY STAY OUT
/	UNTIL THE ACTIVE REJECT TRAY SHEET COUNT IS
/	WITHIN 20 OF THE TRAY CAPACITY BEFORE THE TRAY
/	NEEDED INDICATOR COMES ON.  IF THE TRAY IS STILL
/	OUT WHEN THE ACTIVE REJECT TRAY GETS WITHIN 1
/	SHEETS OF ITS CAPACITY, THE MACHINE WILL STOP.
/
/%TW	THE PRODUCT TRAY ARE HANDLED THE SAME AS THE 
/	REJECT TRAYS.
/
START,  CLB
	CAL
	SUSPND		/GO TO SLEEP 'TIL NEEDED

	DBRI52		/ARE WE IN STACKER TEST ?
/	AND (200)
	AND (0240)
	SZA CLA
	JMP START	/YES, JUST EXIT.

/	DBRI52		/ARE THE FIELD INPUTS DISABLED ?
/SEE	AND (0040)
/ABOVE	SZA CLA
/	JMP START	/YES, QUIT NOW

	DBRI51		/READ THE TRAY POSITION DATA
	AND (7700)	/ARE ANY STACKER TRAYS OUT ?
	SNA
	JMP START	/NO, RETURN
	CLL RAL
	DCA TRAYZ2	/YES, SAVE THE TRAY OUT DATA FOR
			/ LATER
	SNL CLA		/IS THE SAMPLE TRAY OUT ?
	JMP TRAY1	/NO

	TAD (40)	/YES, GO SET UP TO TURN ON THE
	JMS TRAY5	/SAMPLE TRAY NEEDED INDICATOR.
	TAD PROCNT	/WILL THE ACTIVE PRODUCT TRAY HOLD
	TAD (10)	/ 10 MORE SHEETS ?
	SPA CLA
	JMP TRAY1	/YES, GO ON
	JMS TRAY6	/NO, OPEN THE "TRAY OUT"
			/INTERLOCK

TRAY1,	TAD TRAYZ2	/ARE EITHER OF THE REJECT TRAYS OUT?
	CLL RAL
	SMA SNL CLA
	JMP TRAY2	/NO, GO ON TO THE PRODUCT TRAYS
	TAD REJCNT	/YES, WILL THE ACTIVE REJECT TRAY
	TAD (24)	/HOLD 20 MORE SHEETS ?
	SPA CLA
	JMP TRAY2	/YES, GO ON
	TAD REJFLG	/NO, SET "TRAY NEEDED" LIGHT FOR
	SZA CLA		/THE REJECT TRAY WHICH IS OUT
	TAD (10)	/REJECT A TRAY OUT
	TAD (10)	/REJECT B TRAY OUT
	JMS TRAY5	/GO SET UP TO TURN ON THE REQUIRED
			/REJECT TRAY NEEDED INDICATOR.
	TAD REJCNT	/WILL THE ACTIVE REJECT TRAY HOLD
	TAD (2)		/2 MORE SHEETS ?
	SPA CLA
	JMP TRAY2	/YES, GO ON
	JMS TRAY6	/NO, OPEN THE "TRAY OUT"INTERLOCK

TRAY2,	TAD TRAYZ2	/ARE ANY OF THE PRODUCT TRAYS OUT ?
	CLL RAL
	CLL RAL
	SNA CLA
	JMP TRAY4	/NO, GO ON
	TAD PROCNT	/HOLD ANOTHER 40. SHEETS ?
	TAD (50)
	SPA CLA
	JMP TRAY4	/YES, GO ON
	TAD PROFLG	/CHECK IF THE NEXT PRODUCT TRAY IN
	CLL RAL		/THE SEQUENCE IS OUT ?
	AND (0007)
	SNA 
	IAC
	DCA TRAYZ2
	DBRI51		/READ THE TRAY OUT BITS
	BSW
	AND TRAYZ2	/IS THE NEXT TRAY OUT ?
	SNA
	JMP TRAY4	/NO, GO ON.
	JMS TRAY5	/YES, SET UP TO TURN ON THE PROPER
			/TRAY NEEDED INDICATOR.
	TAD PROCNT	/WILL THE ACTIVE PRODUCT TRAY HOLD
	TAD (24)	/20. MORE SHEET ?
	SPA CLA
	JMP TRAY4	/YES, GO ON
TRAY3,	JMS TRAY6	/NO, GO OPEN THE "TRAY OUT"INTERLOCK

TRAY4,	CLB		/IS ANY "TRAY NEEDED" INDICATOR ON ?
	TAD TRAYNF
	SNA CLA
	JMP START	/NO, RETURN
	TAD TRAFLG	/YES, IS THE TRAY OUT ALARM FLAG
	SZA CLA		/SET ?
	JMP START	/YES, RETURN.
	DBRI52		/NO, ARE THE FIELD INPUTS DISABLED ?
	AND (40)
	SZA CLA
	JMP START	/WAS "JMP I TRAYCK"
	CAL		/NO, GO CUE THE "TRAY OUT" MESSAGE
	SENDW		/FOR THE CRT DISPLAY.
	CRTMSG
	TRAYM1
	CLB IAC
	DCA TRAFLG	/SET THE TRAY OUT ALARM FLAG
	JMP START	/RETURN
/
/
/	SUBROUTINE TO "OR" BITS INTO THE TRAY NEEDED FLAG.
/
/
TRAY5,	0
	MQL		/PUT THE NEW BIT IN THE M/Q REGISTER.
	TAD TRAYNF	/GET THE OLD TRAY NEEDED FLAG
	MQA		/"OR" IN THE NEW TRAY NEEDED BIT AND
	DCA TRAYNF	/PUT THE DATA BACK IN THE FLAG.
	JMP I TRAY5	/RETURN


TRAY6,	0
	CAL
	SENDW
	INLOCK
	TRAYM2
	JMP I TRAY6



TRAYM1, ZBLOCK 3	/SHOW "TRAY OUT" MESSAGE
	MOPM04

TRAYM2, ZBLOCK 3	/OPEN "TRAY OUT" INTERLOCK AND
	TRYINL+MOPM04	/ "TRAY OUT" MESSAGE

TRAYZ2, 0

	PAGE

	NOPUNCH		/FIELD 1 COMMON FOLLOWS
	XLIST 1