/  TTR.12

/  REMOTE TTY  HANDLER
/  FOR OS/12  BUILD
/  JAMES  H. DONNELLY, JR

/  1/3/73

	VERSION="A-300

*0
	-1
	DEVICE	TTR
	DEVICE	TTR
	1220
	0001		/ENTRY POINT OFFSET
	ZBLOCK 2
*200
TTY360,	360
TTY,	VERSION
TT7600,	7600
	RDF
	TAD	TTYCIF
	DCA	TTYXIT	/SAVE RETURN FIELD
	TAD I	TTY
	AND	TT70
	TAD	TTCDF
	DCA	TTYCDF	/DATA FIELD OF BUFFER
	CLA CLL CML RAR
	TAD I	TTY
	AND	TT3700
	CMA
	DCA	TTYWC
	ISZ	TTY
	TAD I	TTY
	DCA	TTYCA	/SAVE BUFFER ADDRESS
	ISZ	TTY
	ISZ	TTY
	JMP	TTKLG
TTYLP,	SNL CLA
	JMP	TTYGLP	/ZERO LINK MEANS READ
	JMS	TTYTST	/TEST FOR ^C
	TAD	TTYM14	/-203-14=-217 =-^O
	SNA CLA
	JMP	TTYCTO
	TAD I	TTYCA	/CHARACTER 1 IS LOW ORDER 8 BITS OF WORD 1
	JMS	TTYPCH
	AND	TT7400
	DCA	TTYGCH
	ISZ	TTYCA
TT7400,	7400
	TAD I	TTYCA	/CHARACTER 2 IS LOW ORDER 8 BITS OF WORD 2
	JMS	TTYPCH
	AND	TT7400
	CLL RTR
	RTR
	TAD	TTYGCH
	RTR
	RTR		/CHARACTER 3 IS HIGH ORDER 4 BITS OF WORDS 1 AND 2
	JMS	TTYPCH	/WILL SET LINK ON
/AC IS NON ZERO HERE BUT WE DON'T CARE
TTLOOP,	ISZ	TTYCA
TT70,	70
TTKLG,	ISZ	TTYWC
	JMP	TTYLP
TTYRTN,	TAD	TTYCDF
	CLL CIA
	SNL CLA
	ISZ	TTY	/SKIP PAST ERROR RETURN
TTYXIT,	HLT		/RESTORE CALLING FIELD
	RAL
	JMP I	TTY
TTYPCH,	0
	TAD	TTM232
	SNA
	JMP	TTYRTN
	TAD	TTY232
	JMS	TTPRNT
	JMP I	TTYPCH
TTYTST,	0
TTYCDF,	0
	TAD	TTY200
	KRS		/TEST FOR ^C WITH FLAG UP
	TAD	TTM203
	KSF
	CLA IAC
	SZA		/YESS.. BACK TO MONITOR
	JMP I	TTYTST
TTYCIF,	CDF CIF 0
	JMP I	TT7600
TTPRNT,	0
	6416
	6411
	JMP .-1
	JMP I	TTPRNT
TTYCA,	0
TTYWC,	0
TTCDF,	CDF 0
/FOLLOWING CODE READS TTY AND PACKS IN BUFFER
TTYGLP,	JMS	TTYGCH
	DCA I	TTYCA
	JMS	TTYGCH
	DCA	TTYPCH
	JMS	TTYGCH
	RTL
	RTL
	DCA	TTYGCH
	TAD	TTYGCH
	AND	TT7400
	TAD I	TTYCA
	DCA I	TTYCA
	TAD	TTYGCH
TTY200,	AND	TTY360
	CLL RTL
	RTL
	TAD	TTYPCH
	ISZ	TTYCA
	DCA I	TTYCA
	JMP	TTLOOP
TTYGCH,	0
	TAD	TTYCDF
TT7700,	SMA CLA
	JMP I	TTYGCH
	ISZ	TTYTST
	JMP	TTYKSF
	TAD	TTY212
	JMP	TTECHO
TTYKSF,	6401
	JMP .-1
	JMS	TTYTST
	TAD	TTM27
	SNA		/IS IT A ^Z
	DCA	TTYCDF	/YES SET END OF FILE FLAG
	TAD	TTY14
	DCA	TTYTST	/TTYTST=-1 IF CARRIAGE RETURN
	6406
TTECHO,	JMS	TTPRNT	/ECHO THE INPUT CHARACTER
	JMP I	TTYGCH
TTY232,	232
TTY212,	212
TTY14,	14
TTM203,	-203
TTM27,	-27
TTYM14,	-14
TTM232,	-232
TTYCTO,	6402
	JMP	TTYRTN
TT3700,	3700
	$
12
	JMP	TTECHO
TTYKSF,	6401
	JMP .-1
	JMS	TTYTST
	TAD	TTM27
	SNA		/IS IT A ^Z
	DCA	TTYCDF	/YES SET END OF FILE FLAG
	TAD	TTY14
	DCA	TTYTST	/TTYTST=-1 IF CARRIAGE RETURN
	6406
TTECHO,	JMS	TTPRNT	/ECHO THE INPUT CHARACTER
	JMP I	TTYGCH
TTY232,	232
TTY212,	212
TTY14,	14
TTM203,	-203
TTM27,	-27
TTYM14,	-14
TTM232,	-232
TTYCTO,	6402
	JMP	TTYRTN