File TTSUBS.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

	/TTSUBS.PA
	/
	/
	*2000
	/RELOCATABLE AS REQUIRED BY USER
	/
/
/
/TTSUBS: A TELETYPE UTILITY PROGRAM WRITTEN BY
/BILL FRIEDMAN ON LINC-8,IN CPS-4K SYSTEM.
/
/
/GLOSSARY OF TTSUBS PROGRAMS
/
/TM-TYPE MESSAGE STORED BY TEXT
/   ENTER WITH MESSAGE ADDR IN AC
/CRLF-CARRIAGE RETURN-LINE FEED
/TYPE-TYPE A CHARACTER
/TWOSP-TYPE TWO SPACES
/READ-READ A DECIMAL NO.LESS THAN 4096
/     FROM TTY,DECODE & STORE IT IN
/     BINUM.NOTE: ENTER WITH ERROR RETURN
/     ADDR IN AC.
/     CALL+1: -NO. OF DIGITS
/ROCNUM-READ OCTAL NO. FROM TTY
/       ERROR RETURN ADDR IN AC
/       NO. OF DIGITS IS 1'ST PARAMETER
/GEDIG-GET A DIGIT
/GEL-  GET A LETTER;ENTER WITH ERROR RETURN 
/      ADDR IN AC.
/LISN-ACCEPT AN ASCII CHAR. FROM TTY KYBD.
/DIGTS-BCD DIGIT TO AC.
/DTB-  DECIMAL TO BINARY CONVERSION
/MU10- MULTIPLY BY 10.
/
/
MPT=READ
TM, 0
/ENTER WITH MES AD IN A
DCA MPT
JMS CRLF
TAD I MPT
CLL RTR
RTR
RTR
JMS TT
TAD I MPT
JMS TT
ISZ MPT
JMP TM+3
/
TT, 0
AND (77
SNA
JMP TX/MES DONE
TAD (-40
SPA
TAD (100
TAD (240
JMS TYPE
JMP I TT
/
TX, JMS TWOSP
JMP I TM
/*************
/
CRLF, 0
TAD (215
JMS TYPE
TAD (212
JMS TYPE
JMP I CRLF
/
BINUM=TM
CN=TT
EAD2=CRLF
T1=TWOSP
/
READ, 0
/ENTER WITH ERR RET AD IN A
/READ A DEC. NO. LESS THAN 4096 FROM TT
/DECODE AND STORE IT IN BINUM
/CALL+1: NO. OF DIGITS
DCA EAD2
TAD I READ
DCA CN
DCA BINUM
ISZ READ
/
RL, JMS LISN
JMS DIGTS
JMS DTB
ISZ CN
JMP RL
JMP I READ
/***********
LISN, 0
KSF
JMP .-1
KRB
DCA ASCHAR
TAD ASCHAR
JMS TYPE
TAD ASCHAR
JMP I LISN
/
/
DIGTS, 0
TAD (-272
SMA
JMP EREX
TAD (12
SPA
JMP .-3
/BCD DIG IN A
JMP I DIGTS
/
EREX, CLA CLL
JMP I EAD2
/
DTB, 0
DCA T1
TAD BINUM
CLL RTL
TAD BINUM
CLL RAL
TAD T1
DCA BINUM
JMP I DTB
/
TWOSP, 0
TAD (240
JMS TYPE
TAD (240
JMS TYPE 
JMP I TWOSP
/
CNDIG=TT
/READ OCTAL NUMBER FROM TT
/ERR RET ADDR IN AC, NO. OF DIGITS IS 1ST PARAM
ROCNUM, 0
DCA EAD2
TAD I ROCNUM
DCA CNDIG    /GET NO. OF DIGITS
ISZ ROCNUM
RELP, CLL RAL
RTL
DCA BINUM
JMS LISN
JMS DIGTS
TAD BINUM
ISZ CNDIG
JMP RELP
JMP I ROCNUM
/
TYPE, 0
TLS 
TSF
JMP .-1
CLA
JMP I TYPE
/
GEDIG, 0
JMS ROCNUM
-1
JMP I GEDIG
/
GEL, 0 /GET A LETTER
DCA EAD2
JMS LISN
TAD (-301
SPA CLA
JMP I EAD2
TAD ASCHAR
JMP I GEL
/
/
ASCHAR,0
/
/
/
$$$$$$$$$END$$$$$$$

Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with. I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation.

PDP-8 Home Page PDP-8 Site Map PDP-8 Site Search