/ SUBROUTINE IN SABR
/ LIEST DATEN VOM ANDIMAT
/ WIRD VON FORTRAN II GERUFEN MIT :
/ CALL WANDI(ID1,ID2,ID3,ID4,ID5,ID6,ID7)
/ AUTOR W. WEIGMANN
	ENTRY WANDI
	DUMMY ID1S
	DUMMY ID2S
	DUMMY ID3S
	DUMMY ID4S
	DUMMY ID5S
	DUMMY ID6S
	DUMMY ID7S
ID1S,	BLOCK 2
ID2S,	BLOCK 2
ID3S,	BLOCK 2
ID4S,	BLOCK 2
ID5S,	BLOCK 2
ID6S,	BLOCK 2
ID7S,	BLOCK 2
EPNT,	ID1S
PNTR,	0
CNTR,	0
CZL,	CZLR
CZLR,	0
	0
	0
	0
	0
	0
	0
CZLR1,	0
P4000,	4000
ZEIT,	26
P7,	7444
COUNT,	0
ZEIT1,	0
DZLR,	0
PCM215,	-215
PCM260,	-260
PCM305,	-305
DATA,	0
PCM6,	-7
INDEX,	0
CLIST0,	0
PCM7,	-10
GZLR,	0
WANDI,	BLOCK 2
	TAD EPNT
	DCA PNTR
	TAD (-16
	DCA CNTR
A1,	TAD I WANDI
	INC WANDI#
	DCA I PNTR
	INC PNTR
	ISZ CNTR
	JMP A1
	CLA
	TAD CZL
	DCA CZLR1
	TAD PCM6
	DCA CLIST0
ANT11,	CLA
	DCA I CZLR1
	ISZ CZLR1
	ISZ CLIST0
	JMP ANT11
	CLA
	TAD CZL
	DCA CZLR1	/DATENLISTE
	TAD PCM7
	DCA GZLR
ANT1,	CLA IAC
	6161		/SKIP-LINE ABFR.
	JMP ANT1	/WARTE-SCHLEIFE
	CLA
	TAD ZEIT
	CIA
	DCA ZEIT1
	TAD P7
	DCA COUNT
ANT2,	ISZ COUNT	/ZEITSCHLEIFE
	JMP ANT2
	TAD P7
	DCA COUNT
	ISZ ZEIT1
	JMP ANT2
	CLA
	TAD P4000
	6162		/DATENUEBERN.-FLAG
	JMP ANT6	/KEINE DATEN
	CLA
	JMP ANT3
ANT3,	ISZ GZLR
	JMP ANT12	/<7 DATENSTELLEN
	JMP ANT13	/>7 DATENSTELLEN
ANT12,	6144
	TAD PCM215
	SZA CLA
	JMP ANT4	/#0
ANT13,	TAD CZL
	DCA INDEX
	TAD I INDEX
	DCA I ID1S
	ISZ INDEX
	TAD I INDEX
	DCA I ID2S
	ISZ INDEX
	TAD I INDEX
	DCA I ID3S
	ISZ INDEX
	TAD I INDEX
	DCA I ID4S
	ISZ INDEX
	TAD I INDEX
	DCA I ID5S
	ISZ INDEX
	TAD I INDEX
	DCA I ID6S
	ISZ INDEX
	TAD I INDEX
	DCA I ID7S
	TAD P4000
	6164		/DATENUEBERN. -FLAG RUECKS.
	CLA CLL
	RETRN WANDI
ANT4,	6144		/DATEN
	DCA DATA
	TAD DATA
	TAD PCM305	/E
	SZA CLA
	JMP ANT7	/KEIN ENDE-ZEICHEN
	TAD DATA
	DCA I CZLR1
	ISZ CZLR1
	JMP ANT5
ANT7,	TAD DATA	/DATEN 0...9
	TAD PCM260	/-260
	DCA I CZLR1
	ISZ CZLR1
ANT5,	TAD P4000
	6164		/DATENUEBERN.-FLAG RUECKS.
	JMP ANT1
ANT6,	CLA
	TAD P4000
	6161		/SYNCHRON. IMP. -DATEN BEREITST.
	JMP ANT1
	END