/WVU LP08 HANDLER
/MODIFIED FROM DEC'S LP08 HANDLER
/VERTICAL TAB NOT SUPPORTED
/PRINTS FULL 96 CHARACTER SET
/DOESN'T IGNORE CR, RIGHT BRACE, TILD, OR RUBOUT

	VERSION="B-300

*0

	-1		/1 DEVICE HANDLER
	DEVICE LPWV	/IT'S NOT VERY DIFFERENT
	DEVICE LPT	/WE CAN RENAME THE BINARY
	1040		/WRITE ONLY - LINE PRINTER
	0000		/ZERO OFFSET, 1 PAGE
	ZBLOCK 2

PAGE
/LINE PRINTER HANDLER FOR LP08 LINE PRINTER - HANDLES TABS,
/LP08 HARDWARE HANDLES FORM FEEDS, CARRIAGE RETURNS  AND
/LINE FEEDS.

	LSF=6661
	LSR=6663
	LLS=6666

LPT,	VERSION
	CLL CML CLA RAR
	TAD I LPT	/LINK GOES ON HERE. IF NOT READ WAS REQUESTED
LPT215,	AND LP7700
	CMA
	DCA LPTWC
LPT214,	RDF
	TAD LPTCIF
	DCA LPTXIT	/SAVE CALLING FIELD IN RETURN SEQUENCE
	TAD I LPT
	AND LPT70
	TAD LPCDF0
	DCA LPTCDF	/GET BUFFER FIELD
/NOTE!!!!!!!! 
LP7700,	7700		/MUST BE AT LOC. 15 OF PAGE!
	ISZ LPT
	TAD I LPT
	DCA LPTCA	/LPTCA GETS BUFFER ADDRESS
	ISZ LPT
	TAD I LPT
LPTCDF,	HLT
	ISZ LPT
	SNL		/IF LINK NOT SET,GIVE ERROR
	JMP LPTERR
	SNA CLA
	TAD LPT214
	JMP LPTKLG	/POTENTIAL BUG, INTERCEPT NULLS


/NOW PICK UP THE CHARACTERS, UNPACK THEM AND PRINT.
/TEST FOR:TABS, LINE FEEDS,VERTICAL TABS

LPTLP,	TAD I LPTCA
	JMS LPTPCH
	TAD I LPTCA
	AND LP7400
	DCA LPTCDF
	ISZ LPTCA
LP7400,	7400
	TAD I LPTCA
	JMS LPTPCH
	TAD I LPTCA
	AND LP7400
	CLL RTR
LPTLF,	RTR
	TAD LPTCDF
	RTR
	RTR
	ISZ LPTCA
LPTKLG,	JMS LPTPCH
LPT177,	177
	ISZ LPTWC
	JMP LPTLP
LPRTRN,	ISZ LPT
LPTXIT,	HLT
	JMP I LPT

LPTWC,	0
LPTCA,	0

LPTPCH,	0
	AND LPT177
	CIA		/WATCH OUT FOR THE INITIAL
	TAD LPT175	/NULL
	SPA		/FUNNY CHARS ABOVE 174
	JMP LPGCHR
	TAD LPM143	/TESTING FOR 32 ^Z
	SNA
	JMP LPTCTZ
	TAD LPTM15	/RESULT IS 15-CHAR
	CLL CML CMA	/RESULT IS CHAR-16
	TAD LPT7	/NOW CHAR-7
	SNL SZA		/11<CHAR<16 ?
	JMP LPTCTL	/YES, SPECIAL
	TAD LPT7	/NO, JUST A CHAR
	SZA		/BUT WATCH FOR NULLS
	JMS LPWAIT	/LP08 NONPRINT=SPACE
LPTJMP,	JMP LPJTAB-2	/LPJTAB-2 = "JMP I LPTPCH"

LPTCTZ,	TAD LPT214
	JMS LPTPCH
	JMP LPRTRN

LPWAIT,	0
	LLS
LP7600,	7600
	TAD LP7600
	KRS
	TAD LPT175
	SNA CLA
	KSF
	JMP .+3
LPTCIF,	CDF CIF 0
	JMP I LP7600
	LSF
	JMP LP7600
	LSR
	JMP LPWISZ
LPTERR,	CLA CLL CML RAR	/FATAL ERROR EXIT
	JMP LPTXIT
LPWISZ,	ISZ LPLPTR
	JMP I LPWAIT
LPLF,	CLA CLL CMA RAL	/GETS -2

LPTFF,	TAD LPT214
	DCA LPLPTR
	TAD LPLPTR
	JMS LPWAIT
	TAD LPM120
	DCA LPLPTR	/FALL THROUGH LPTCTL!
LPTCTL,	TAD LPTJMP	/FORM JMP INSTRUCTION
	DCA .+1		/AND DO IT
LPTXXX,	HLT

LPTTAB,	TAD LPM140
	JMS LPWAIT
	TAD LPLPTR
	AND LPT7
	SNA CLA
	JMP I LPTPCH	/MUST BE AT LPJTAB-2!!!
LPT7,	7		/^N WILL COME HERE
LPJTAB,	JMP LPTTAB	/^N GOES OUT HERE
	JMP LPLF
	JMP LPLF	/WE DON'T SUPPORT VERTICAL TAB
	JMP LPTFF
	CLA IAC		/CARRIAGE RETURN COMES HERE
	JMP LPTFF	/JUST LIKE A FF EXCEPT THE CODE

LPM120,	-120		/BACK UP CHAR COUNT
LPT70,	70
LPTM15,	-15
LPT175,	175
LPM143,	-143
LPCDF0,	CDF	0
LPLPTR,	0

LPGCHR,	CIA		/LET'S GET BACK OUR
	TAD LPT175	/NEAT CHARACTER
	JMP LPTJMP-1	/AND GO PRINT IT

LPM140,	-140

PAGE

	$ * $ * $ * $
	/WE DON'T SUPPORT VERTICAL TAB
	JMP LPTFF
	CLA IAC		/CARRIAGE RETURN COMES HERE
	JMP LPTFF	/JUST LIKE A FF EXCEPT THE CODE

LPM120,	-120		/BACK UP CHAR COUNT
LPT70,	70
LPTM15,	-15
LPT175,	175
LPM143,	-143
LPCDF0,	CDF	0
LPLPTR,	0

LPGCHR,	CIA		/LET'S GET BACK OUR
	TAD LPT175	/NEAT CHARACTER
	JMP LPTJMP-1	/AND GO PRINT IT

LPM140,	-140

PAGE

	$ *