File ZA1GK1.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

10 REM AUSWERTUNG DER ZUR QUALIFIKATION GEHOERIGEEN GRUNDKURSE FUER
20 REM DIE ERSTE KONFERENZ DES ZA, EINTRAGUNG DER L-KURS-ERGEBNISSE
30 REM VON 13(2), SPEICHERUNG DER DATEN AUS DEN 4 ABI-FAECHERN AUF
40 REM  D = ANZAHL DER KURSE UNTER 5 PUNKTEN
50REM  E=0,FALLS ZULASS-BEDING.ERFUELLT, S=PUNKTSUMME IM FACH
60 REM  T= TOTALE PUNKTSUMME IM G-BEREICH
70 REM N$ = SCHUELERNAME         T$ = TERMIN
80 REM F$(I)=1. BIS 4. ABI-FACH   F(I,4)=PKTE AUS 13(2)
90 REM F(I,5) = PUNKTSUMME 12(1) BIS 13(1) IM 1. - 3. ABI-FACH
100 PRINT "BIS ZU WELCHEM TERMIN MUESSEN DIEJENIGEN KURSE ANGEMEL-"
110 PRINT"DET WERDEN, DIE AUSSERHALB DER QUALIFIKATION INS ABI-"
120 PRINT"ZEUGNIS AUFGENOMMEN WERDEN SOLLEN";\INPUT T$
130 PRINT\PRINT"ZU DEN L-FAECHERN MUSS PKT-ZAHL VON 13(2), ZU DEN"
140 PRINT"G-FAECHERN MUESSEN 4 PKT-ZAHLEN IN ZEITLICHER REIHENFOLGE"
150 PRINT"NOTFALLS '0', EINGEGEBEN WERDEN. NACH EINGABE ALLER FAECHER"
160 PRINT"UND PKT-ZAHLEN JEDES SCHUELERS 'SUM' EINGEBEN."
170 PRINT
175 DIM N$(20),F(4,5),X$(14),Y$(14)
180 PRINT"NAME DES ABZURUFENDEN DATENSATZES";\INPUTX$
185 X$="DTA1:"&X$&".BA"
190PRINT"NAME DES AUFZUBAUENDEN DATENSATZES";\INPUTY$
195 Y$="DTA1:"&Y$&".BA"
200 FILE#1: X$\FILEV#2: Y$
210  Z1=0\Z2=0\Z3=0\Z4=0\Z5=0\Z6=0\Z7=0\Z8=0\Z9=0\Z0=0
220 INPUT#1:N$,X
230 FOR I = 1 TO 2\INPUT#1:F$(I),X\NEXT I
240 INPUT#1:F(1,5),F(2,5),X,X
250 FOR I = 1 TO 5\ PRINT\ NEXT I
260 PRINT N$\ IF N$="ENDE" THEN 830
270 D=0\E=0\S=0\T=0\Z=0
280 REM 
290 REM   1.  UND  2.  A B I - F A C H
300 FOR I = 1 TO 2\ PRINT I;". L-FACH ";F$(I)
310 PRINT"SUMME BIS 13(1):";F(I,5)
320PRINT,"PUNKTE 13(2)";\INPUT F(I,4)\NEXT I
330 REM   3.   UND   4.  A B I - F A C H
340 FOR I = 3 TO 4
350 F(I,5) = 0
360 PRINT I;". ABI-FACH";\INPUT F$(I)\IF F$(I)="N" THEN 220
370 PRINT ,"PUNKTE";\INPUTF(I,1),F(I,2),F(I,3),F(I,4)
380 FOR J = 1 TO 3
390 IF F(I,J)=0 THEN 410\ Z = Z+1
400 IF F(I,J)>4 THEN 410\D  = D+1
410 F(I,5)= F(I,5) + F(I,J)
420 NEXT J
430 T = T + F(I,5)
440 PRINT TAB(10);"SUMME 12(1) BIS 13(1)";TAB(36);F$(I);": ";F(I,5)
450 NEXT I
460 REM
470 PRINT\PRINT"WEITERE G-FAECHER:"\PRINT
480 FOR J = 1 TO 4\G(J)=0\NEXT J
490 S=0
500 PRINT"FACH";\INPUT F$
510 IF F$="SUM" THEN 610
520 PRINT,"PUNKTE";\INPUT G(1),G(2),G(3),G(4)
530 FOR J = 1 TO 4
540 IF G(J)=0 THEN 570\Z=Z+1
550 IF G(J)>4 THEN 560\ D=D+1
560 S = S + G(J)
570 NEXT J
580 PRINT TAB(25);"SUMME";TAB(36);F$;": ";S
590 T = T+S
600 GOTO 480
610 IF Z = 20 THEN 660\PRINT"ZAHL DER G-KURSE: ";Z
620 PRINT"BITTE NEU EINGEBEN. FALLS WENIGER ALS 20 ANRECHENBARE "
630 PRINT"G-KURSE VORHANDEN, AUF ABFRAGE '3. ABI-FACH' DEN"
640 PRINT"BUCHSTABEN 'N' EINGEBEN."
650 GOTO 250
660 IF D < 6 THEN 690
670 PRINT D;" KURSE UNTER 5 PKTE."
680 GOSUB 1060
690 IF T>99 THEN 710\ PRINT TAB(10);"NUR ";T;" PUNKTE."
700 GOSUB 1060
710 IF E > 0 THEN 220
720 PRINT"IM G-BEREICH ";TAB(35);T;" PKTE."\PRINT
730PRINT"EINTRAGUNG WEITERER KURSE UND DES RELIGIONSBEKENNTNISSES"
740PRINT"INS ABI-ZEUGNIS AAUF SCHRIFTLICHEN ANTRAG."
750PRINT"TERMIN: ";T$;" IM SEKRETARIAT."
760 GOSUB 1130
770 PRINT#2:N$
780 FOR I = 1 TO 4\PRINT#2:F$(I)\NEXT I
790 FOR I = 1 TO 4
800 PRINT#2:F(I,5),F(I,4),
810 NEXT I
820 PRINT#2:\GOTO 220
830PRINT#2:N$
840 FOR I = 1 TO 4\PRINT#2:"O"\NEXT I
850 FOR I = 1 TO 8\PRINT#2:"0",\NEXT I
860 PRINT#2:
870 CLOSE#2
880 PRINT
890 PRINT, " U E B E R S I C H T"
900 PRINT"UEBER DIE GRUPPIERUNG DER ZUGELASSENEN SCHUELER IM"
910 PRINT"IM G-BEREICH FUER DIE MELDUNG NACH PARA 18 AB-PO."\PRINT
920 PRINT"PKT-ZAHL","ANZAHL DER SCHUELER"
930 PRINT"300-276",Z1
940 PRINT"275-251",Z2
950 PRINT"250-231",Z3
960 PRINT"230-211",Z4
970 PRINT"210-191",Z5
980 PRINT"190-171",Z6
990 PRINT"170-151",Z7
1000 PRINT"150-131",Z8
1010 PRINT"130-116",Z9
1020 PRINT"115-100",Z0
1030 STOP
1040 REM
1050 REM   U N T E R P R O G R A M M
1060 PRINT"KANN DAS DEFIZIT VERMIEDEN WERDEN (JA ODER NEIN)";
1070 INPUT D$\ IF D$ = "JA" THEN 250
1080 PRINT"NICHT ZUZULASSEN."\E=E+1
1090 RETURN
1100 REM
1110 REM UNTERPROGRAMM  Z A E  H L U N G  FUER DIE GRUPPIERUNG
1120 REM DER ZUGELASSENEN SCHUELER
1130 IF T<276 THEN 1140\Z1=Z1+1\GOTO 1230
1140 IF T<251 THEN 1150\Z2=Z2+1\GOTO 1230
1150 IF T<231 THEN 1160\Z3=Z3+1\GOTO 1230
1160 IF T<211 THEN 1170\Z4=Z4+1\GOTO 1230
1170 IF T<191 THEN 1180\Z5=Z5+1\GOTO 1230
1180 IF T<171 THEN 1190\Z6=Z6+1\GOTO 1230
1190 IF T<151 THEN 1200\Z7=Z7+1\GOTO 1230
1200 IF T<131 THEN 1210\Z8=Z8+1\GOTO 1230
1210 IF  T<116 THEN 1220\Z9=Z9+1\GOTO 1230
1220 Z0=Z0+1
1230 RETURN 
1240 END
1250PRINT"



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search