Directory of image this file is from
This file as a plain text file

/ SUBROUTINE IN SABR
/ ERZEUGT ZUFALLSZAHLEN IM BEREICH -1...+1
/ HAT DREI EINGAENGE :
/  RANDOM (INITIALISIERT DEN GENERATOR UEBER SCHALTREGISTER)
/  CALL RANDI(J,K,L) (INITIALISIERT DURCH PROGRAMMAUFRUF)
/  FUNCTION RANDU(0) (0 OHNE BEDEUTUNG)
/ BEARBEITUNG VON DECUS #8-582
	ENTRY RANDI	/ GENERATOR INITIALIZER
	ENTRY RANDU	/ GENERATOR ITSELF
	ENTRY RANDOM
	DUMMY J
	DUMMY K
	DUMMY L
RANDOM,	0		/ RANDOM NUMBER FORMED HERE
HIGH,	0
MID,	0
LOW,	1
J,	0		/ DUMMY VARIABLES USED IN
K,	0		/ INITIALIZATION PROCESS
L,	BLOCK 2
RANDI,	BLOCK 2
	TAD I RANDI	/ GET ADDRESS OF J
	INC RANDI#
	DCA J
	TAD I RANDI
	INC RANDI#
	DCA J#
	TAD I J		/ GET VALUE OF J
	DCA HIGH	/ HIGH ORDER INITIALIZED
	TAD I RANDI	/ GET ADDRESS OF K
	INC RANDI#
	DCA K
	TAD I RANDI
	INC RANDI#
	DCA K#
	TAD I K		/ GET VALUE OF K
	DCA MID		/ MIDDLE ORDER INITIALIZED
	TAD I RANDI	/ GET ADDRESS OF L
	INC RANDI#
	DCA L
	TAD I RANDI
	INC RANDI#
	DCA L#
	TAD I L		/ GET VALUE OF L
	DCA LOW		/ LOW ORDER INITIALIZED
	RETRN RANDI
RANDU,	BLOCK 2
	TAD LOW
	RAL		/ BEGIN DECUS #5-25
	AND (7400
	DCA TEMP2
	TAD MID
	AND(177
	TAD TEMP2
	RTL
	RTL
	RAL
	DCA TEMP
	TAD LOW
	AND (177
	RTL
	RTL
	RAL
	TAD MID
	DCA TEMP1
	SNL
	INC TEMP
	NOP
	TAD LOW
	CLL RAL
	SNL
	INC TEMP1
	SKP
	INC TEMP
	NOP
	CLL
	TAD LOW
	DCA LOW
	TAD MID
	RAL
	SNL
	INC TEMP
	NOP
	CLL
	TAD TEMP1
	DCA MID
	TAD HIGH
	RAL
	TAD HIGH
	TAD TEMP
	DCA HIGH	/ END OF DECUS #5-25
	INC RANDU#	/ SET RETURN POINTER
	INC RANDU#
	TAD HIGH
	CALL 0,FLOT	/ PUT RANDOM NUMBER IN FAC
	CALL 1,FDV	/ PUT IN RANGE -1...+1
	ARG C
	RETRN RANDU
C,	2144		/ C=2048(10)
	0
	0
TEMP,	0
TEMP1,	0
TEMP2,	0
	END