File ZZG4.A3

Directory of image this file is from
This file as a plain text file

/************** ZZG4 *********************************************
/3.4.74
/CALL:	ZZG4	/MULTIPL.ZZG: Z(N+1)=C*Z(N)MOD(B)
/	SCHWELLE	/DOPPELTGENAU
/	UEBERLAUF	/=1,WENNZUF.ZAHL>SCHWELLE

/MERKE: C=(2^15+3)DEZIMAL;B=2^31DEZIMAL;Z(0)=1
/C IST MAX DOPPELTGENAU; B,Z SIND MAX. DREIFACH-GENAU
/ZZG4 IST GEPACKTE VERSION VON ZZG3

*6600


ZZG4,	2
	BLOTNT
	ZZG4NT
	
	SWAB
	CAM DST
	ZAC1
	CAM DST
	ZAC3

	JMS MUL	/C0*ZN0*2^0
	C0
	ZN0
	ZAC0

	CAM DAD	/+
	ZAC1

	JMS MUL	/C0*ZN1*2^14
	C0
	ZN1
	ZAC1

	CAM DAD	/+
	ZAC1

	JMS MUL	/C1*ZN0*2^14
	C1
	ZN0
	ZAC1

	CAM DAD	/+
	ZAC2

	JMS MUL	/C0*ZN2*2^30
	C0
	ZN2
	ZAC2

	CAM DAD	/+
	ZAC2

	JMS MUL	/C1*ZN1*2^30
	C1
	ZN1
	ZAC2

	CAM DAD
	ZAC0
	DST
	ZN0	/Z(N+1) VORBEREITET
	CLA
	TAD ZAC2
	AND ZMSK2
	DCA ZN2

	TAD ZM5
	DCA ZCNT

ZLP,	TAD ZAC0	/NORMALISIERUNG WEGEN KOMPATIBILITAET
	CLL RAL
	DCA ZAC0
	TAD ZAC1
	RAL
	DCA ZAC1
	TAD ZAC2
	RAL
	DCA ZAC2
	ISZ ZCNT
	JMP ZLP

	GETAD
	1
	DCA Z3POI
	CAM DAD
Z3POI,	0
	DAD
	ZAC1
	CLA RAL
	PUT
	2
	INEND

ZZG4NT,	SWAB
	TAD Z0
	DCA ZN0
	CAM DST
	ZN1
	JMP .-10


MUL,	0
	CLL
	DST
	SACMQ	/SAVE AC+MQ
	CAM

	TAD I MUL
	DCA MTP1
	ISZ MUL
	TAD I MTP1
	MQL

	TAD I MUL
	DCA MTP1
	ISZ MUL

	TAD SACMQA
	DCA MTP2
	
	TAD I MUL
	DCA MTP3
	ISZ MUL

	MUY
MTP1,	0
	DAD
MTP2,	0
	DST
MTP3,	0
	CAM
	SNL
	JMP I MUL

	DPIC
	CLA CLL IAC RAL
	TAD MTP3
	DCA MTP3
	TAD MTP3
	DCA MTP2

	JMP MTP1+1

SACMQ,	0
	0
SACMQA,	SACMQ
ZMSK2,	177	/MOD B
ZM5,	-5
ZCNT,	0
C0,	3	/
C1,	10	/2^15+3
ZN0,	0	/Z(N)
ZN1,	0
ZN2,	0
Z0,	1	/Z(0)
	0
ZAC0,	0
ZAC1,	0
ZAC2,	0
ZAC3,	0
	0



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search