Directory of image this file is from
This file as a plain text file

120 PRINT"    THIS PROGRAM WILL GRAPH A FUNCTION OF X BETWEEN ANY LIMITS"
130 PRINT"(A AND B) YOU CHOOSE, WITH AN INTERVAL OF YOUR CHOICE (I)" 
140 PRINT"BETWEEN SUCCESIVE VALUES OF X, IF YOU TYPE THE FOLLOWING:" 
150 PRINT"         1 GO TO 220"
160 PRINT"        220 DEF FNY(X)=...(YOUR FUNCTION OF X)..." 
200 PRINT"        RUN" 
210 STOP 
220DEF FNY(X)=SIN(X) 
230PRINT"LOWER LIMIT OF X =";\INPUTA 
240PRINT"UPPER LIMIT OF X =";\INPUTB 
242 IF A<B THEN 250
244PRINT"YOUR LOWER LIMIT MUST BE LESS THAN YOUR UPPER LIMIT!" 
246PRINT\GOTO230 
250PRINT"INCREMENT OF X =";\INPUTI 
260 LET L=FNY(A) 
270 LET U=FNY(A) 
280 FOR X=A TO B STEP I
290 LET Y=FNY(X) 
300 IF Y-L<0 THEN 320
310 GO TO 330
320 GOSUB 380
330 IF Y-U>0 THEN 350
340 GO TO 360
350 GOSUB 400
360 NEXT X 
370 GO TO 420
380 LET L=Y
390 RETURN 
400 LET U=Y
410 RETURN 
420 IF INT(U)-U=0 THEN 450 
430 LET U1=INT(U)+1
440 GO TO 460
450 LET U1=U 
460 LET L1=INT(L)
470 LET D=U1-L1
480 IF INT(D/5)-D/5=0 THEN 570 
490 FOR K=1 TO 2 
500 LET L1=L1-1
510 LET D=U1-L1
520 IF INT(D/5)-D/5=0 THEN 570 
530 LET U1=U1+1
540 LET D=U1-L1
550 IF INT(D/5)-D/5=0 THEN 570 
560 NEXT K 
570 LET E=D/5
580 PRINT "X"
590 PRINT "-"
600 PRINT "V"
610 PRINT "A"
620 PRINT "L"
630 PRINT "U"
640 PRINT "E"
650 PRINT "S                     - - - - Y-VALUES - - - -" 
660 PRINT"              "L1," ";L1+E*1.5,"  ";L1+E*3,"   ";L1+E*4.5
670PRINT"                I---------I----+----I---------I---------I"; 
671 PRINT "----+----I" 
680 IF L1>0 THEN 1020
690 LET Q=INT((-L1)*(10/E)+.5) 
700 DEF FNP(Y)=INT((Y-L1)*(10/E)+.5) 
710 FOR X=A TO B STEP I
720 PRINTX,
730 LET Y=FNY(X) 
740 IF Y>=0 THEN 850 
760 PRINT TAB(15+FNP(Y));"*";TAB(Q+15);"I" 
840 GO TO 1000 
850 IF Y>0 THEN 910
860 PRINT TAB(Q+15);"*"
900 GO TO 1000 
910 PRINT TAB(15+Q);"I";TAB(15+FNP(Y));"*" 
1000 NEXT X 
1010 GO TO 1100 
1020 FOR X=A TO B STEP I
1030 PRINTX,
1040 LET Y=FNY(X) 
1050 PRINT TAB(INT((Y-L1)*(10/E)+.5)+14);"*"
1090 NEXT X 
1100 PRINT
1110 PRINT "NOTE: THE SIX I'S ON THE HORIZONTAL Y-AXIS REPRESENT:"
1120 PRINT L1;",";L1+E;",";L1+E*2;",";L1+E*3;",";L1+E*4;",";L1+E*5
1240 END