/*
 * #sccs	"@(#)libmain:ifile.0413	1.1"
 * Loader directives file for magic 0413 -z option.
 *
 * Produces a file that can be demand paged directly from the
 *	disk file, with read-only shareable text segment.
 *
 * The directives result in:
 *	Specifying that virtual memory has its origin at 0x80000,
 *		and extends for another 0x27f000 bytes.
 *	Specifying that the text & data be loaded so that:
 *		text virtual address relocated (bonded) to 0x80000 origin.
 *		text beginning in file at a 1024 byte boundary
 *		data virtual address relocated to next 65536 boundary
 *		data beginning in file at next 1024 boundary after text
 *		bss appearing right after data in file and in virtual memory
 *
 * This directives file is used with the SGS Common Object File loader
 *	that is shipped with Unix System V.
 *	The target processor is the AT&T UNIX pc (PC7300, Safari 4),
 *	a virtual process 68010 implementation with demand paging.
 *
 * Convergent Technologies
 * 7 March 85
 * Bob Glossman
 */

MEMORY {
	user_mem : origin = 0x80000 , length = 0x27f000
}

SECTIONS {
	.text 0x80000 BLOCK(1024) : {}
	GROUP ALIGN(65536) BLOCK(1024) : {
		.data : {}
		.bss  : {}
	}
}