Directory of image this file is from
This file as a plain text file

$1
JMP 20
$20
JMP p+2
0 [INTERUPT INSTRUCTION HERE
CLR
ATR  [SHUTTERS CLOSED
JMP 1Q
2A  [R OR S
2B
LDH [ANSWER IN ACC
4000+2B
SAE i [IF R
0045
JMP p+2
JMP 1A [R STRUCK
SAE i [IF S
0046
JMP p+2
JMP 3G
SAEi
51 [V
JMP 20 [INVAL CHAR
[
LDA i
JMP 9X
STC 9E+5
LDAi
51 [V
STC 3D+2
LDAi
JMP 9V [DELAY SUB
STC 3E
JMP 3F
[
[
#3G LDAi
46 [S
STC 3D+2
LDAi
JMP 9R
STC 3E
LDAi
JMP 9F
STC 9E+5
JMP 9S  [LOAD L OR R INSTRUCTIONS
#3F JMP 1Q [Q+AR
2C
2D
LDAi
2D
STC 1
JMP 9A [UNPACKED TO OCTAL
LDA
2      [ANSWER IN 2
STAi
#3A 0      [#RUNS PER HISTO
JMP 1Q
2G
2H
LDAi
2H
STC 1
JMP 9A [UNPACK
LDA
2
STA i
#3C 0
JMP 1Q
2E     [BIN WIDTH
2F
[SET UP BIN WIDTH+CLOCK
LDAi
2F
STC 1
JMP 9A [UNPACKED TO OCTAL
LDA
2     [ANSWER
STAi
#3B 0      [BIN WIDTH
[SETUP REAL TIME CLOCK
LDAi
4031
OPR 1 [LOAD STATUS
LDA
3B
COM
OPR 3 [LOAD PRESET BUFFER WITH NEG COUNT
[
#3D JMP 9P [CLEAR QN 6+7
LDA i
46   [S
STA
3770
LDA
3B   [BIN WIDTH
STA
3771
LDA
3A
COM
STC 5 [-NO. RUNS
[WAIT FOR TRAP AND SENSOR
#3E JMP 9R
[
JMP 9E [COLLECT HISTOGRAM
LDA
5
ADA i
1
ADD 3A
STA
3772
KST
JMP p+12
KBD
SAEi
45
JMP p+2
JMP 3D
SAEi
46
JMP p+2
JMP p+3
XSK i 5
JMP 3E [RUNS NOT OVER
[
JMP 9T [SUM SPIKES
LDA
3C
STC 9J-1
JMP 9J  [STORE MEMORY ON TAPE
JMP 9N [HISTO PARAMS
JMP 9H  [DISPLAY HISTO
#1B KST
JMP p-3
KBD
SAE i
45  [R
JMP p+2
JMP 3D [REPEAT
SAE i
24  [A
JMP p+2
JMP 1L
SAE i
25  [B
JMP p+2
JMP 1N
SAE i
43  [P
JMP p+2
JMP 1P
SAE i
40  [M
JMP p+2
JMP 1M
JMP 1B
[
#1L LDA
3C
ADA i
2   [ADVANCE BN
STC 3C
JMP 3D
[
[
#1N LDA
3C
ADA i
2     [ADVANCE BN
STC 3C
JMP 3C+1
[
#1P KST
JMP p-1
KBD
SAE i
43 [P
JMP 1B
JMP 9H  [DISPLAY HISTO
JMP 9N
KST
JMP p-1
KBD
SAEi
43 [P
JMP 1B+3
JMP p-10
[
#1M JMP 1Q  [Q+AR
2M  [DESIRED BN
2N
LDA i
2N
STC 1
JMP 9A  [UNPACK TO OCTAL
LDA
2
STC 9L-1
JMP 9L  [TAPE TO MEMORY
JMP 1B-1
HLT
[
[
[
[
#1A JMP 9S [R OR L INSTRUCTION
LDAi
JMP 9F
STC 9E+5
JMP 1Q
2I
2J  [#HISTOS
LDAi
2J
STC1
JMP 9A [UNPACK
LDA
2
STAi
#7A 0   [#HISTOS
JMP 1Q
2C
2D [#RUNS PER HISTO
LDAi
2D
STC 1
JMP 9A [UNPACK
LDA
2
STA i
#7B 0  [RUNS|HISTO
JMP 1Q
2E
2F  [BWIDTH
LDA i
2F
STC 1
JMP 9A [UNPACK
LDA
2
STA i
#7C 0   [BIN WIDTH
LDA i
4031
OPR 1
LDA
7C
COM
OPR3
JMP 1Q
2G
2H  [BN
LDAi
2H
STC1
JMP 9A [UNPACK
LDA
2
STA i
#7D 0   [BN
[
[CLEAR OUT BLOCKS
JMP 9P [CLEAR QN 6+7
LDA
7A
COM
STC1 [-# HISTOS
LDA
7D
ADAi
-2
STC 7F+1
#7F LDAi
0
ADAi
2
STA
7F+1
STC 9J-1
JMP 9J [MEM TO TAPE
XSK i 1
JMP 7F
[
LDA
7B [# RUNS
COM
STC 13
#7G LDA
7A [#HISTOS
COM
STC 7
#7E JMP 1Q
2W [ADVANCE
2X
LDH
4000+2X
SAEi
24 [A
JMP 7E
#7J LDA
7A
ADD 7
ROL 1
ADD 7D
STC 9L-1
JMP 9L [TP TO MEM
LDA i
45 [R
STA
3770
LDA
7C
STA
3771
JMP 9R [TRAP + SENSOR SIGS
JMP 9E [COLLECT HISTO
LDA i
1
ADD 7B
ADD 13
STA
3772 [RUNS SO FAR
JMP 9T [SUM SPIKES
[
#7I SET i 5
-7
JMP 9H
XSK i5
JMP p-2
JMP 1Q
2Y
2Z [SAVE OR REPEAT
LDH
4000+2Z
SAEi
46 [S
JMP p+2
JMP 7H
SAEi
45 [R
JMP 7I [INVALID
JMP 7J
[
#7H LDA
7
ADD 7A [#HISTOS
ROL 1
ADD 7D [BN
STC 9J-1
JMP 9J [MEM TO TAPE
[
XSK i 7
JMP 7E [NEXT POSITION
XSK i 13
JMP 7G
[
[END OF A SERIES
#7K JMP 1Q
2M
2N
LDAi
2N
STC1
JMP 9A [UNPACK
LDA
2
STC 9L-1
JMP 9L [TAPE TO MEM
JMP 9H [DISPLAY HISTO
JMP 9N
KST
JMP p-3
KBD
SAE i
43 [P
JMP 7K
KST
JMP p-1
KBD
SAE i
43 [P
JMP 7K
JMP 9H
JMP 9N
JMP p-10
[
[
[
[##################
[SUB TO DELAY
[
#9V LDA
0
STAi
0
[
SET i16
-200
SET i17
1
XSK i 17
JMP p-1
XSKi16
JMP p-5
SET i 17
-5
JMP 9H
XSK i 17
JMP p-2
SETi16
-144
SETi17
-454
[
LDAi
1
SNS 4
JMP p+3
ADAi
20
SNS3
JMP p+3
ADAi
10
STAi
#9Z NOP
LDAi
1
ATR
[
JMP 9V+3
[
[
[##################
[SUB TO SUM UP BINS
[
#9T LDA
0
STAi
0
[
SET i 10
7013 [-500
SET i 11
2777
CLR
ADA i 11
XSK i10
JMP p-2
STA
3773
JMP 9T+3
[
[
[##################
[SUB TO LOAD L OR R INSTRUCTIONS
[
#9S LDA
0
STAi
0
[
LDH
4001+2B
SAEi
45  [R
JMP p+2
JMP p+13
SAE i
37  [L
JMP 20 [INVAL CHAR
LDA i
SXL i 4
STC 9I
LDA i
SXL 4
STC 9I+5
JMP p+7
LDA i
SXL i3
STC 9I
LDA i
SXL 3
STC 9I+5
JMP 9S+3
[
[
[
[
[##################
SUB TO GET TRAP AND SENSOR SIGS
[
#9R LDA
0
STAi
0
[
LDA i
SXL i 2
STC 9W
JMP 9H
#9I SXL i  3
JMP p-2
CLR
COM
ATR  [OPEN SHUTTER
SXL 3
JMP p-1
[SENSOR YET
SXL 2
JMP p+4 [A BRITER
#9W SXL i 2
JMP p-1 [NO CHANGE
JMP 9R+3 [CHANGE
LDA i
SXL 2
STC p-5
JMP p-6
[
[
[##################
[SUBROUTINE TO COLLECT HISTOGRAM INTO QN 6+7
[DOESNT CLEAR QN 6+7
[
#9E LDA
0
STAi
0
[
LDAi
JMP 9F
STC 21 [INTERUPTTO HERE
[
SETi1
3000  [1ST MEMORY LOC
SET i 3
7013  [-# OF BINS
OPR 4 [START CLOCK
ENI
#9G SXL i 10
JMP p-1
LDA i [GOT A PULSE
1
ADM 1 [ ADD TO BIN
SXL 10
JMP p-1
JMP 9G
[
[
[
[##################
[   SERVICE ROUTINE FOR INTERRUPT
[ R+S MODES
[
#9F SXL 10
JMP p-1
XSK i 3 [# OF BINS
JMP p+5
OPR 10 [STOP CLOCK
CLR
ATR  [CLOSE SHUTTERS
JMP 9E+3
XSK i 1 [MOVE TO NEXT BIN
JMP 9G-1
JMP 9G-1
[
[##################
[SERVICE ROUTINE FOR V MODE
#9X SXL 10
JMP p-1
XSK i3 [#  BINS
JMP p+5
OPR 10 [STOP CLOCK
CLR
ATR
JMP 9E+3
XSKi1
NOP
XSK i16
JMP p+4
LDA
9Z
ATR
XSK i17
JMP 9G-1
LDAi
1
ATR
JMP 9G-1
[
[##################
[  SUBROUTINE TO CLEAR QN 6+7
[
#9P LDA
0
STAi
0
[
SET i 6
2777
CLR
STA i 6
XSK 6
JMP p-2
JMP 9P+3
[
[
[
[##################
[HISTO DISPLAY ROUTINE
[USES REG 10 11 12
[
#9H LDA
0
STAi
0
[
SET i 10
2777 [1ST STORAGE LOCATION
SET i 11
-764  [#OF BINS
SET i 12
0     [X COORDINATE
#9Q LDA i 10
ROL 2
ADAi
-100
SAEi
-100
JMP p+2
JMP p+5
DIS 12
ADAi
-1
JMP p-7
XSK i 12
XSK i 11
JMP 9Q
JMP 9H+3
[
[
[##################
[SUB TO PUT HISTO PARAMS ON SCREEN
0
#9N LDA
0
STA i
0
[
LDA i
300
STA
9O
LDA
3770
SAEi
45  [R
JMP p+2
JMP p+10 [R STRUCK
SAEi
46  [S
JMP p+2
JMP p+4 [S STRUCK
SAEi
51 [V
JMP 9O-11
SET i 1
100  [X COORD
ROL 1
ADAi
1R
STC 17  [ADDR OF PATTERN WORD
LDA i
-277 [Y COORD
DSC 17
DSC i 17
[
[
SET i 16
-2
LDA
3771  [BIN WIDTH
SET i 15
-3
ROL 3
STC 9N-1
SET i 1
#9O 300  [X COORD
LDA
9N-1
ROL 3
STA
9N-1
BCL i
7770
ROL 1
ADAi
1R
STC 17
LDA i
-277
DSC 17
DSC i 17
XSK i 15
JMP 9O+1
XSK i 16
JMP p+2
JMP 9N +3 [EXIT
LDA i
500
STA
9O
LDA
3772
JMP 9O-5
[
[
[##################
[SUB TO STORE QN 6+7 ON TAPE
[
0
#9J LDA
0
STAi
0
LDA
9J-1
ADAi
6000
STA
9K
ADAi
1001
STC 9K+2
WRC i u
#9K 0
WRC u
0
JMP 9J+3
[
[
[##################
[SUB TO GET INFO FROM TAPE TO QN 6+7
[
0
#9L LDA
0
STA i
0
[
LDA
9L-1
ADA i
6000
STA
9M
ADA i
1001
STC 9M+2
RDC i u
#9M 0
RDC u
0
JMP 9L+3
[
[
[##################
[Q+AR
$1347
#1Q LDAi
2
ADD 0
STAi
0
ADD p+133
STC 1
LDA 1
ADD p+170
STC p+35
LDAi 1
STC p+26
STC 6
SET 3
p+23
SET 4
p+26
JMP p+125
JMP p+3
JMP p+14
JMP p-3
STH 3
LDHi 4
COM
STC 6
ADD p+202
STHi 3 [LDHi 3
XSKi 6
JMP p-2
LDHi 3
JMP p-15
STH 3
SETi 4
0
LDAi
137
STC p+12
SETi 3
0
SET 5
p-7
SETi 1
100
LDAi
-40
ADMi
0
LDHi 3
JMP p+67
JMP p+303
JMP p+17
SHDi
1200
JMP p-14
JMP p+71
JMP p-10
JMP p+67
SROi
0
DIS 1
LDHi 5
JMP p+52
JMP p-17
JMP p-20
JMP p-10
KST
JMP p-40
KBD
SETi 2
p+233
SHD 2
JMP p+121
SHDi 2
JMP p-105
XSK 6
JMP p-51
SHDi 2
JMP p+20
SHDi 2
JMP p+131
SHDi 2
JMP p+21
JMP p+25
JMP p-106
JMP p-62
STC p+5
JMP p+20
JMP p+50
JMP p+47
LDAi
0
STH 4
JMP p-72
LDH 4
JMP p+11
JMP p-75
-6002
JMP p+36
JMP p+4
JMP p-101
JMP p-104
JMP p-3
LDHi 4
SHDi
7000
JMP 0
SAEi
76
XSKi 0
XSKi 0
JMP 0
ROL 1
ADD p+163
STC 2
ADD p+20
ADD 1
STC 1
ADD 5
COM
ADD 4
AZE
CLR
STC p-100
ADD p-115
DSC 2
DSCi 2
JMP 0
LDAi
-4000
ADM
4
JMP p-141
[CHARACTER PATTERNS
[KBD 0:CODE 00
#1R 4136
3641
[1:01
2101
0177
[2:02
4523
2151
[3:03
4122
2651
[4:04
2414
0477
[5:05
5172
0651
[6:06
1506
4225
[7:07
4443
6050
[8:10
5126
2651
[9:11
5122
3651
[EOL:12
KBDi
ADD p-212
[DEL:13
JMP 0
67
[SPACE:14
0000
0000
[i:15
0101
0126
[p:16
3700
3424
[-:17
0404
0404
[+:20
0404
0437
[|:21
0000
0077
[#:22
JMP p-102
JMP p-52
[CASE:23
JMP p-53
JMP p-211
[A:24
4477
7744
[B:25
5177
2651
[C:26
4136
2241
[D:27
4177
3641
[E:30
4577
4145
[F:31
4477
4044
[G:32
4136
2645
[H:33
1077
7710
[I:34
7741
0041
[J:35
4142
4076
[K:36
1077
4324
[L:37
0177
0301
[M:40
3077
7730
[N:41
3077
7706
[O:42
4177
7741
[P:43
4477
3044
[Q:44
4276
0376
[R:45
4477
3146
[S:46
5121
4651
[T:47
4040
4077
[U:50
0177
7701
[V:51
0176
7402
[W:52
0677
7701
[X:53
1463
6314
[Y:54
0770
7007
[Z:55
4543
6151
[META
[56
[CASE EOL
2356
1322
[57
[CASE DEL
1200
p-137
[?:60
[CASE SPACE
4020
2055
[=:61
[CASE i
1212
1212
[u:62
[CASE p
0107
0107
[,:63
[CASE -
0500
0006
[.:64
[CASE +
0001
0000
[$:65
[CASE |
4577
7745
[[:66
[CASE #
4177
0000
[_:67
[CASE CASE
0101
0101
[":70
[CASE A
LDHi 3
LDAi
[;:71
[CASE B
14
JMP p-277
[<:72
[CASE C
2410
0042
[>:73
[CASE D
4200
1024
[]:74
[CASE E
0000
7741
[*:75
[CASE F
2050
0050
[::76
[CASE G
[UNDEFINED:77
[Q+AR
[12|27|67
[
[
[
[##################
[SUB TO CONVERT ANSWER BUFFER TO OCTAL
[LOC BUFF REG 1
[NO. RET TO REG 2
[
#9A LDA
0
STAi
0
[
SET i3
7774
SET i2
7777
#9C LDHi1
SAEi
0067
JMPp+2 [NOT BLANK
JMP 9B [BLANK
ADD 2
ROL 3
STA
2
XSK i 3
JMP 9C
[
ROR 3
STC 2
JMP 9A+3
#9B LDA
2
JMP  p-5
[
[
$2002
#2A "REPETITIVE, SINGLE OR
VBSPOT?"1
TO LEFT OR RIGHT"1:;
#2B 0
0
0
#2C "NO. RUNS PER HISTO"3:;
#2D 0
0
0
#2E "BIN WIDTH"3:;
#2F 0
0
0
#2G "1ST STORAGE LOC"3:;
#2H 0
0
0
#2I "NO. OF HISTOS"3:;
#2J 0
0
0
#2M "DESIRED BLOCK"3:;
#2N 0
0
0
#2Y "SAVE OR REPEAT?"1:;
#2Z 0
0
0
[
[
#2W "ADVANCE?"1:;
#2X 0
0
0
[
[
[
[JULY 1,1976     R.R.A.
[
[##################