Directory of image this file is from
This file as a plain text file

[LAP5 CONVERT
[BLOCKS 330-332
[QUARTERS 0-2
[PASS II
$15
RCG 7E
1|7D+10 [DISPLAY
NOP
RDC i 7E
2|7D+47 [BIN TO Q2
#2Z JMP 3A
KST i
JMP 4D [RETURN
SET 4
3
JMP 2A
JMP 2Z
JMP 2T
JMP 2Z
[LINE DECODE
#2A SET 17
0
CLR
STC 2X
STC 2Y
SET i 6
4L
SET i 12
-3 [CONSTANT
SET i 13
JMP 2M+1
[CHARACTER CHECK
#2B LDH i 3
SET i 10
4P+4000
SHD i 10
JMP 2E [COMMENT
SHD i 10
JMP 4A  [$
SHD i 10
JMP 2E+4  [=
SHD i 10
JMP 2V  ["
SHD i 10
JMP 4B  [77
SHD i 10
JMP 2J  [u
[CHECK NUMBER
#2C JMP 3D+1
JMP 2F
JMP 3E
JMP 2H
BSE i
ROR
STC p+2
LDA 11
ROTATE N
APO
JMP 2U
[UNDEFINED
LDA
2Y
ROR 3
STH i 1
LDH 3
STH i 1
LDA
1L
STA i 1
LDA i
-0
STA i 1
JMP 3H
#2U LDA 10
JMP 13
[SPECIAL CHARACTER
#2D ADA i
2W+6000+11
STC p+1
JUMP TO DISPATCHER
[u
#2J LDA i
10
JMP 13
[COMMENT, EQUALITY
#2E LDH i 4
SAE i
66
XSK i 17
JMP 3G
JMP 17
[BETA 13 RETURN
#2M COM
ADD 2X
JMP 2A+3
[TEXT
#2V JMP 9M
JMP 1000 [LIST
JMP 3J [TEXT COUNT
JMP p+5 [;
JMP 2K  [EOL
JMP 2K+6  [77
JMP 2T [2 CHARS
JMP 2V+2
[;=71, END TEXT
XSK i 13
JMP 2E+4 [NO ASSIGNMENT
JMP 2E+3
[EOL IN TEXT
#2K SET i 12
JMP 2V+3
JMP 3A [CHECK MS
XSK i 13
JMP 3J+11
JMP 2V+6 [ASSIGN
[77 IN TEXT
XSK i 13
JMP 4B  [NO ASSIGN
JMP 2T
JMP 4B
[NUMBER, NOT TAG
#2H LDH 3
SHD i
1400
JMP 3C
JMP 3D+1
JMP p+2
JMP p-3
LDA i
-4000
ADM
3
LDA i
#2Y NUMBER
ROR 3
JMP 13
[$
#4A JMP 3B
JMP 9M
JMP 17 [LIST
JMP 4Q [CONVERT
[77-PREPARE SAVE BIN
#4B JMP 9M
JMP 1400 [LIST
JMP 4R [CONVERT
[i
#4F LDA i
20
JMP 13
[p
#4G ADD 1P
JMP 13
[-
#4H SET i 13
JMP 2M
JMP 2B
[|
#4J ADD 2X
ROR 3
JMP 2A+3
[TAG
#4K JMP 3C
LDH i 3
JMP 2B
[EOL
#4E XSK i 17
JMP 17
[DISPATCHER
#2W JMP 4E
JMP 2B [DEL
JMP 2B
JMP 4F
JMP 4G
JMP 4H
JMP 2B-2
JMP 4J
JMP 4K
[CHARACTER TABLE
#4P 0022
6665
6170
7762
[SAVE LETTERS
#4L 0
0
[CHECK LETTER
#2F ADA i
-12
APO
JMP 2D
LDH 3
STH i 6
XSK i 12
JMP 2B
ROL 6
ADD 4L
SET i 6
6A-6G-1
SET i 12
6A-1
XSK i 6
JMP 2Q
JMP 2B-6
#2Q SAE i 12
JMP 2Q-3
LDA i
6G-6A+1
ADD 6
ADA i
6A-6C-1
APO i
JMP 2S
#2R ADA i
6C-6A+1
ROL 5
JMP 13
[SUBSTITUTE
#2S ADA i
6G-1
STC 6
LDA 6
JMP 13
[CONVERT SUBROUTINES
[MS ADDRESS CHECK
#3A LDA i
1
ADM i
#1L 0
LDA
3
BCL i
4000
ADA i
-3377
APO
JMP 0
RDC i 7B
6|7A
ADD p-1
ADA i
1001
APO
STC p+2
RDC 7B
7|777
ADD p-10
ADD 3A+1
STC p-12
ADD 3
ADA i
#3L -400
STC 3
JMP 0
[$
#3B SET 10
0
JMP 3C
JMP 3D-2
JMP p+5
JMP 3C
JMP 3D+1
JMP p+2
JMP p-3
LDA
2Y
ROR 3
BCL i
4000
STC 1P
JMP 3G
JMP 10
[SPACE AVOID
#3C SET 11
0
LDH i 3
SHD i
1400
JMP 3C+2
JMP 11
[NUMBER CHECK
CLR
STC 2Y
#3D LDH 3
ADA i
-11
APO i
JMP 0
LDH 3
ADD 2Y
ROL 3
STC 2Y
XSK i 0
JMP 0
[SYMBOL CHECK
#3E LDH i 3
ADA i
-23
APO
JMP 0
ADA i
-32
APO i
JMP 0
LDA
2Y
AZE i
JMP 0
ROR 3
MUL i
32
ADA i
6B-32-24
STC 10
LDH 3
ADD 10
STC 10
[FIND MARK REGISTER
LDH 3
ADA i
6D-24
STC 11
ADD 2Y
ROR 3
XSK i 0
JMP 0
[UP p
#3F LDA i
1
ADM i
#1P 20
BCL i
4000
STC 1P
JMP 0
[FIND EOL
#3G SET 11
0
LDA i
12
SHD 3
JMP 11
SHD i 3
JMP 11
JMP p-2
[ERROR TABLE ADDRESS CHECK
#3H LDA i
4
ADD 1
STC p+2
SAE 
NEXT SLOT STILL ZERO?
APO
JMP 0
ADD 1
ADD 2B-3 [-3
STC 1
JMP 0
[TEXT COUNT
#2X 0  [FOR ASSIGN
#3J SET 12
0
SET i 13
-2
SET i 14
2X-1+4000
LDA i
1414
STC 2X
LDH i 3
SHD i
7100  [;
JMP 3K+3
SHD i
7700
JMP 3K+1
STH i 14
SHD i 
1200
JMP 3K+2
XSK i 13
JMP 3J+11
#3K XSK i 12
XSK i 12
XSK i 12
JMP 12
[PASS PRESET
#1T LDA i
6|7A
STC 1L+12
STC 1L
ADD 4F+1
STC 1P
SET i 3
7401
SET i 2
1017
JMP 0
[CHECK LIST
#9M SRO i
7777
XSK i 0 [CONVERT
JMP 0  [LIST
[LIST-PASS II
#9N JMP 1T [PASS PRESET
RDC i 7E
2|7D+27
JMP 1001
[DO NOT CHANGE ANYTHING BEFORE THIS POINT WITHOUT ALSO CHANGING LIST
[ORIGIN-CONVERT
#4Q LDA
1P
BCL i
7000
ADD 4C+13 [777
STC 2
ADD 1P
SCR 10
BCL i
1
ADD 2P-3
SHD
2G+3+4000
JMP p+4
STC 2P
JMP 2G
JMP 2N
JMP 17
[77-CONVERT. PREPARE FOR SB
#4R LDA
4C
AZE i
JMP 4D
SET i 11
-13
ROL 1
APO
JMP p+3
XSK i 11
JMP p-4
SET i 10
0
SRO
4C
JMP p+4
XSK i 11
XSK i 10
JMP p-5
LDA
10
ROR 3
STC 12
JMP 2G [WRITE BINARY
WRC i 7E
7D+30
LDA i
#4N LAST MEM
STC 1000
ADD 1
STC 1001
RDC i 7E
3|7D+34 [READ LNS
JMP 15
[NO BINARY
#4D CLR
STC 11
STC 10
WRC i 7E
7D+30
SET i 16
7|7D
JMP 15
[ASSIGNMENT SR
#2T LDA
1P
SCR 10
BSE i
ROL
STC p+2
ADD 3A+1
ROTATE N
BSE i
#4C 0
STC p-1
LDA
2X  [ASSIGN
SET 13
0
STA i 2
JMP 3F
XSK 2
JMP 13
SET i 2
777
JMP 2G
JMP 2N
JMP 13
[RDC BINARY
#2N SET 7
0
ADD 1P
AZE
JMP p+4
LDA i
2|7D+40
STC 2P
RDC i 7E
#2P 2|7D+42
ADD p-1
ADD 2G+5
STC p+2
RDC i 7E
FOURTH BIN BLK
ADD 2P
STA
2G+3
STA
2G+13
ADA i
2
STC 2P
JMP 7
[BINARY FULL
#2G SET 7
0
WRI i 7E
2|7D+40
LDA i
1001
ADD p-3
STC p+2
WRI i 7E
2ND BIN BLK
CHK i 7E
2|7D+40
AZE
JMP 2G+2
ADD 3A+1
ADD p-4
STC p+2
CHK i 7E
2ND BIN BLK
AZE
JMP 2G+2
JMP 7
[PASS I
$1000
JMP 9B [LIST WA
JMP 9A [LIST FILE
[CLEAR TABLES
#1Y SET i 1
8Z  [LAST MNEMONIC
SET i 2
8Z-6A [LENGTH OF MNEMONIC TABLE
RDC i 7E
5|7D+37
CLR
STA i 1
XSK i 2
JMP p-2
SET i 1
1377
STA i 1
XSK 1
JMP p-2
COM
SET i 1
6F-1
SET i 2
-26
STA i 1
XSK i 2
JMP p-2
SET i 5
6F
JMP 1T
STC 4C
SET i 1
6E-4000
LDA
1P
STA 5
[CHARACTER CHECK
JMP 3A
SET 4
3
#1A LDH i 3
SET i 10
4P  [CHAR TABLE
SHD i 10
JMP 1D [#
SHD i 10
JMP 1B [COMMENT
SHD i 10
JMP 1C [$
SHD i 10
JMP 1E [=
SHD i 10
JMP 1F ["
SHD i 10
JMP 1G [77
SAE i
12
JMP 1A
#1Z JMP 3F
JMP 1A-3
[COMMENT
#1B JMP 3G
LDH i 4
SAE i
66
JMP 1Z
JMP 1A-3
[$
#1C LDA
1P
SAE 5
JMP 1H
JMP 3B
JMP 1A-6
#1H ADD 2Y-4
BCL i
4000
STA i 5
XSK i 5
LDA
5
SAE i
6D
JMP 0
ADD 3J+3
STC 5
JMP 0
[TAG
#1D JMP 1Q
JMP 1R
JMP 1A
[=
#1E SET 2
3
SET 3
4
JMP 1Q
SET 3
2
SET 4
2
ADD 11
STC p+6
ADD 10
STC p+6
JMP 2A
JMP 1A-3
SET i 11
RESET
SET i 10
RESET
LDA
2X
JMP 1R+2
JMP 1A-3
[GET #,LETTER SYMBOL
#1Q SET 7
0
JMP 3C
JMP 3D-2
JMP 1X
JMP 3E
JMP 1X
STC 1R+6
LDH 3
STC 1J+4
JMP 7
[ASSIGN TO TABLE
#1R LDA
1P
SET 7
0
STA 10
LDA i
NUM ROTATE
BSE i
ROL
STC p+2
ADD 1H+2
ROTATE
BSE 11
STA 11
LDA i
-400
ADM
10
LDA 10
AZE
JMP 1J
ADD 1L
STA 10
JMP 3H
JMP 7
[MULTIPLE DEFINITION
#1J LDA
1R+6
STH i 1
LDA i
LETTER
STH i 1
LDA 10
STA i 1
LDA
1L
STA i 1
JMP 1J-3
[IGNORE ILLEGAL =
#1X JMP 3G
JMP 1A-3
[TEXT
#1F JMP 3J [TEXT COUNT
JMP 1M [;
JMP 1K [EOL
JMP 1N [77
JMP 3F [ASSIGN
JMP 1F
[;
#1M XSK i 13
JMP p+2 [NO ASSIGN
JMP 3F [ASSIGN
JMP 3G [FIND EOL
JMP 1A-3
[TEXT EOL
#1K SET i 12
JMP 1F+1
JMP 3A [CHECK MS
XSK i 13
JMP 3J+11
JMP 1F+4 [ASSIGN
[TEXT 77
#1N XSK i 13
JMP 1G
JMP 3F [ASSIGN 
[77
#1G JMP 9M
JMP 9N
LDA
1P
SAE 5
JMP 1H
LDA i
-1
ADD 5
STC 4N
WRC i 7E
3|7D+34
[CLEAR AND WRITE BINARY
SET i 5
1377
CLR
STA i 5
XSK 5
JMP p-2
#1U LDA i
3|7D+40
STA
1S
STC p+2
WRI i 7E
ZERO TO BINARY
LDA i
1
ADD p-3
SAE i
3|7D+50
JMP 1U+4
CHK i 7E
#1S BINARY
AZE
JMP 1U
ADD 1S-6
ADM
1S
SAE i
3|7D+50
JMP 1S-1
JMP 1T
JMP 20
[LIST PRESET
[WORKING AREA
#9B LDA
6H
STC 9J
LDA
6H+1
STC 9J+1
JMP 9A+3
[FILE
#9A RDC i 7E
7D+30
CLR
STC 9M+1
ADD 1377
BSE i
6000
STC 1T+1
ADD 1376
STA
3L-7
BSE i
i    [RDC i u
STC 1L+11
LDA i
NOP
STC 1A-11
JMP 1Y [PASS I
$1376
RDC 7B
7A
$2642
[MNEMONICS
#6A "TS;
"MS;
"SD;
"KX;
"LR;
"RR;
"RS;
"LS;
"PS;
"RO;
0   [UNDEFINED
0
0
"PM;
"TM; [MAG TAPE TWO=740
"AL;
"AS;
"AA;
"MA;
"ML;
"LM;
"HL;
"HS;
"DS;
"ES;
"OS;
"LB;
"EB;
"OB;
0
#6C "CD;
"DA;
"CS;
"PJ;
[SUBSTITUTE MNEMONICS
"TH;
"AZ;
"IE;
"RC;
"RA;
"AR;
"PN;
"MC;
"TK;
"SS;
"NP;
"EA;
"OA;
"EL;
"ZI;
"FO;
"ZZ;
"CR;
"GR;
"ER;
"BM;
"CW;
"GW;
"IW;
"KC;
"DK;
"WR;
"WL;
[CODES
#6G ADD
STC
JMP
HLT
ZTA
ENI
CLR
ATR
RTA
NOP
COM
KST
SNS
PIN
AZE
APO
LZE
IBZ
OVF
ZZZ
RDC
RCG
RDE
MTB
WRC
WCG
WRI
CHK
KBD
RSW
#8Z LSW
7A=350
7B=0
7D=300
7E=0
6B=2000 [SYMBOL ASSIGNMENTS
6D=2400 [MARK REGISTERS
6E=2432 [ERRORS
6F=2352 [MEMORY ALLOCATION
6H=2371 [PARTIAL NUMBERS
9J=771
[CVAPR13