[COSSIND
[COSINE OR SINE OF X
[CHEBYSHEV SERIES WITH FINITE NUMBER OF TERMS
[MOD ROUTINE BUILT-IN TO HANDLE ALL X
[
[CALL:
[JMP 1W OR 1Y
[ADDR X
[ADDR RESULT
[
[USES XR 1,2,3,4
[USES FLOD-1R
[NO DIVIDE NECESSARY
[
[2|PI
 -0
2427
3140
[CONSTANTS FOR APPROXIMATION
 7765
3407
2606
7772
5254
4505
7776
2016
3640
0001
5420
6610
[TEMPORARY STORAGE
 0
0
0
 0
0
0
[CONSTANT ONE
 1
2000
0000
[ENTER COS X
#1W CLR
ADD
JMP 1X-1
ADD 1R+1
STC p+132
[SET TABLE BEGIN
LDA i
p-33
STC p+73
[STORE OPERAND ADDR
ADD 3
STC p+110
ADD 2
STC p+2
[X*2|PI
JMP 1M
0 [ADDR X
p-46
p-30
[ABSOLUTE VALUE OF X
LDA
p-32+1
APO
COM
STC p-35+1
ADD p-36+2
APO
COM
STC p-41+2
[GET N AND T
[X=2*N+T   -1<T<1
JMP 1J
p-43
p-41
LDA
p-43+1
SRO
p-45+1
ADD 1Q+1 [=1
OVF i
CLR
STA
p-52+1
ROR 2
SCR 13
STC p+54
LDA
p-57
OVF i
ADD 1Q+1 [=1
STC p-62
OVF i
JMP 1H [OVERFLOW
JMP 1I
p-66
p-67
JMP 1S
p-74
p-72
p-76
[X**2
JMP 1M
p-100
p-101
p-102
[CLEAR STORE
CLR
STC p-101
STC p-102+1
STC p-103+2
SET i4
-4
[LOOP
[RESULT=RESULT+TERM
JMP 1A
p-107
 0 [ADDR TERM
p-111
[RESULT=RESULT*X**2
JMP 1M
p-113
p-117
p-115
LDA i
3
ADM
p-11
XSK i4
JMP p-13-2 [LOOP
[ADD LAST TERM
JMP 1A
p-125
p-123
 0 [ADDR RESULT
[NEGATE RESULT??
SRO i
 0
JMP p+2
JMP p+11
SET 3
p-6
LDA i3
COM
STA 3
LDA i3
COM
STA 3
 JMP [RETURN
[ENTER SIN
#1Y CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC p-5
ADD 3
STC p+6
ADD 2
STC p+3
[X= X- PI|2
JMP 1S
1Y+23
0 [ADDR X
0 [ADDR RESULT
SET 2
p-2
SET 3
p-4
CLR
JMP 1W+5
[PI|2  1Y+23
1
3110
1767
[END COSSIND
[MJM 4-14-70
[MJM 4-15-71