Directory of image this file is from
This file as a plain text file

*20
	CLR
	PDP	/PROGRAM FOR LINC
	PMODE	/START 20
	JMP I P200
P200,	200
	*4400
	LMODE
	CLR	/PROGRAM TO RETURN
	LDA I	/TO DIAL WITH A
	701	/LINC START 400
	STC 16
	LDA I
	7300
	STC 17
	JMP 16
	PMODE
	*200
START,	CLA CLL
	DCA PTR	/CLEAR STORAGE REGISTR
	TAD N4A
	DCA N4B	/RESET COUNTER FOR ISZ
	TLS
	KCC	/SET AND CLEAR FLAGS
	TAD CR
	TYPO
	TAD LF	/CR-LF
	TYPO
IN,	KSF
	JMP .-1	/WAIT FOR TTY INPUT
	KRB
	TLS	/ECHO INPUT
	DCA TEMP
	TAD TEMP
	AND P770
	TAD N260/OCTAL NUMBER?
	SNA
	JMP .+5
	CLA	/NO, PRINT "?"
	TAD QUE	/AND RESTART
	TYPO
	JMP START
	TAD PTR	/YES, INCORPORATE
	CLL RTL	/INTO PACKING REGISTER
	RAL
	TAD TEMP
	TAD N260
	DCA PTR
	ISZ N4B	/FOUR NUMBERS INPUT?
	JMP IN	/NO, TAKE MORE INPUT
	TAD N4A
	DCA N4B	/YES, RESET COUNTER,
	TAD SL	/AND PRINT SLASH
	TYPO
	TAD I PTR/BRING IN CONTENTS
	RAL	/OF SELECTED LOCATION
	DCA PTR	/AND STORE
OUT,	TAD PTR
	RTL	/UNPACK AND PRINT
	RAL	/CONTENTS OF PTR
	DCA PTR
	TAD PTR
	AND P7
	TAD P260
	TYPO
	ISZ N4B
	JMP OUT
	JMP START
	TYPO=JMS .
	0	/SUBROUTINE TO TYPE
	TSF	/AND CLEAR ACC
	JMP .-1
	TLS
	CLA
	JMP I .-5
N4A,	-4	/CONSTANT TABLE
N4B,	0
CR,	215
LF,	212
QUE,	277
SL,	257
PTR,	0
TEMP,	0
P260,	260
N260,	-260
P770,	770
P7,	7
/
/
/DATE: OCTOBER 17, 1971
/PROGRAMMER:  DANIEL GRAY
/TITLE:  COUGHUP
/DESCRIPTION:  ACCEPTS TTY INPUT
/		OF FOUR OCTAL NUMBERS
/		AND INTERPRETS THESE
/		AS A CORE LOCATION.
/		PROGRAM THEN TYPES A
/		SLASH AND TYPES, IN
/		OCTAL, THE CONTENTS
/		OF THAT LOCATION.
/
/