[BASIC
[1|22|69
[
[BASIC TRANSLATOR
$1
HLT
4|2H-6  [CONTAB  PTR
0
2S    [UTIL STACK
0
0   [$6
3000  [OUTPUT
1S    [LINKSTACK
3000-4  [SYMTAB POINTER
0  [12
4|2777  [TO FORCE 1ST BLOCK IN
$20
[## SCAN ##
[
[START LINE
#1B UMB 3X  [DIAGRAM PAGE
LDA
 1Q     [HEAD
STC 12
ADD 2W  [=1
ADM
2L  [LINE #
APO
JMP 2E+6  [>3777
COM
JMP 1M  [OUT -LN#
JMP 1K  [ALIGN INPUT PTR TO FIRST OF NEW LINE
LDA
6R+1  [CFP SOURCE FILE
STC 2L+1
ADD 13
STC 2L+2
ADD 4
STC 2L+3
ADD 10
STC 2L+4
KST
JMP p+5  [DONT TERMINATE COMPILE
KBD i
SHD i
1200  [EOL
JMP 2E+16  [TERMINATE COMPILATION
[
[ START TRYING A PATH
#1C JMP 1K  [INCHAR
UMB 3X  [DIAGRAM PAGE
LDA 12  [PATTERN
APO
 JMP 1D [TERMINAL SYMBOL
AZEi
 JMP 1E [NULL PATH
[ NON-TERMINAL SYMBOL  --  PUSH STACK
LDAi
#2V  -1     [CONSTANT
ADM
 10     [STACK POINTER
SAEi
2200  [STACK LIMIT
AZEi    [SKIP
JMP 2E+7  [OVERFLOW THE LINKAGE STACK
LDAi
#1X  -0     [ +=CAN BACKUP
BCLi
 3777
ADD 12  [DIAGRAM POINTER
UMB 3Y  [P2
STA 10
UMB 3X  [P1
LDA 12  [REFERENCED DIAGRAM
STC 12
STC 1X  [ BACKUP POSSIBLE
JMP 1C+1
[ TERMINAL SYMBOL
#1D COM
SAEi
#1W         [CLASS
 JMP 1G-1
COM
STC 1X  [NO BACKUP
ADD 1D
STC 1K  [AS A NOP
[ TRAVERSE PATH
#1E LDAi12
APOi
 JMP 8H [HIERARCHY MANIPULATION
ROL 1
APO i
JMP 1A  [PAGE 1 ACTION
ROR 1
STC p+1
        [ACTION JUMP
[ REENTRY AFTER ACTION
#1F UMB 1
LDAi12  [NEXT NODE
JMP 1I  [CLEAR SIGN
ADD 12
AZE
 JMP 1C
[ DIAGRAM EXIT
UMB 3Y  [P2
LDA 10  [TOP OF STACK
BSE     [OR WITH BACKUP
 1X
JMP 1H
UMB 3X  [DIAGRAM PAGE
JMP 1E
[ TRY NEXT PATH
XSKi12
#1G UMB 1   [NULL PATH FAILURE REENTRY
LDAi12
XSKi12
APOi
 JMP 1C+1
[ NO MORE PATHS -- TRY BACKUP
LDA
 1X
APO
JMP 2E  [ERR: TERM SYMBOL PASSED
UMB 3Y  [STACK PAGE,P2
LDA 10  [STACK
JMP 1H
JMP 1G-1
[ SAVE BKT, POP STACK, CLEAR SIGN
#1H STC 1X  [SAVE BACKUP
UMB 3Y  [STACK PAGE,P2
LDA 10  [STACK TOP
AZEi
JMP 2E+5  [ERR:EMPTY STACK
XSKi10
#1I BCLi    [CLEAR SIGN
 4000
STC 12
JMP 0
[ENTRY TO PAGE 1 ACTION
#1A ADD 1I+1  [=4000
ROR 1
STC p+2
LMB 3X  [P1
0  [ACTION JMP
[END SCAN#6
[1|11|69
[OUTPUT CODE SYLLABLE
[   CLR RETURN
LDA
 2T
#1M SET 17
 0
JMP 1P  [OUTPUT
[  INCREMENT SYLLABLE COUNT
CLR
LDAi
 1
ADA i
#2N 0       [WORD COUNT
ROL i 4
ROR 4
STC 2N  [WD COUNT MOD 256
LAM i
#1N 0       [BLOCK COUNT
CLR
JMP 17   [RETURN
[BASIC ACTIONS
[
[SKIP TO NEXT LINE
#7B JMP 1K+1
SAEi
 35     [EOL
JMP 7B
JMP 1K+1
[END OF LINE
#7C LDA
 13     [INPUT POINTER
STC 2U
JMP 1B
[
#7D JMP 2B  [TERMINATE
[
[6Q-1=DIGIT PART OF ID
[ACC=LETTER
0  [WORK LOC
#6Q ADA i
32  [LENGTH OF T22
ADA i
32  [LENGTH OF T21
ADA i
32  [LENGTH T12
ADA i
2600-24
STC 5
UMB 3Y  [P2
LDA
6Q-1
ADA i
ROL
STA
p+5
ADA i
40
STC p+7
LDA 5
0  [ROL
APO i
XSK i 0
BSE i
4000
0  [ROR
STA 5  [SET TABLE
JMP 0  [RETURN VIA 0
[
#7E LDA i
25  [END OPERATOR
JMP 1M
JMP 7B  [TO EOL
[
[
[TAG->SYMTAB,SET
#7F UMB 3Z  [P3
JMP 9Y  [READ LETTER
STC 2I
LDH
0|2I  [DIGIT
STC 6Q-1
LDH
4|2I  [LETTER
JMP 6Q+6  [TEST DEFINED BIT
JMP 2E+10  [1  RETURN-DUPLICATE
[NOW DEFINE A SYMBOL TABLE ENTRY
JMP 9Z  [0 RETURN
[XR11 PTS TO ENTRY
SET 1
11
LDA
2I
STA 1  [SET LABEL IN SYMTAB
JMP 9J  [CALC INDEX
STA i 1  [SET INDEX
[COMPLETE SYMTAB ENTRY
LDA
1N
STA i 1  [BLOCK
LDA
2N  [WORD
STA i 1
1Z
[
[
[KEYWORD LOOKUP
#7G SET i 14
 2Q     [KEYWORD TABLE
UMB 3X  [KEYWORD PAGE
LDA 14
STC 6   [LENGTH OF TABLE
JMP 9Y  [2ND LETTER
UMB 3X  [KEYWORD PAGE
SAE i 14
JMP p+21
LDA i 14  [CODES
APO i
JMP 7G+5  [TRY AGAIN
STH
4|p+11  [CONSTRUCT CLASS
[CODEWORD STRUCTURE
[B6-B11  RIGHT TO LEFT SCAN WITH
[0 MEANS SKIP CHAR
[1 MEANS STOP SKIPPING CHAR
[B0-B5 ARE LOW ORDER 6 BITS OF CLASS
SCR 6
STC p+2
[
SRO i
0
JMP p+3
JMP 1K+1  [SKIP KEYWORD CHAR
JMP p-4
[
LDA i
0100
JMP 9I  [INSERT FLAG
1Z
[
XSK i 14
XSKi6
JMP 7G+7
JMP 2E  [ILLEGAL KEYWORD
[OUTPUT <--
#7H JMP 9F  [POP ]
LDAi
 7
JMP 9X  [1M,1Z
[POP RPAREN
#7I JMP 9F
1Z
[READ "THEN"
#7J JMP 9Y
SAEi
 "TH;
JMP 2E  [INCORRECT THEN
JMP 9Y-5  [2 LETTERS
SAEi
 "EN;
JMP 2E  [INCORRECT "THEN"
1Z
[READ TAG AND OUTPUT
#7K UMB 3Z  [P3
JMP 9Y
STC 2I
LDH
0|2I  [DIGIT
STC 6Q-1
LDH
4|2I  [LETTER
JMP 6Q+2  [T21 TEST
NOP  [1RETURN
LDA  [0 RETURN
2I
JMP 9J  [CALC INDEX
BSE i
2000  [RP CODE
#9X JMP 1M
1Z
[
[READ VARIABLE
#8D UMB 3Z  [P3
LDH 13
STH
 2I
JMP 1K+1
SHDi
 600
JMP p+4
LDAi
12  [CODED BLANK
JMP p+6
LDAi
 NOP
STC 1K
UMB 3Z  [P3
LDH 13
STH
 4|2I
1Z
[VAR -> SYMTAB, OUT
#8E LDH
4|2I  [DIGIT
STC 6Q-1
LDH
0|2I
JMP 6Q+4  [TEST T12
JMP 8E+23  [1 RETURN
JMP 9Z  [0 RETURN
LDA
2I  [VAR
STA 1  [SET SYMBOL
LDA i
1
ADM
6R+25  [LAST VAR USED
STA i 1
[8E+20
BSE i
1000
JMP 9X
[
JMP 9H  [SEARCH SYMTAB
LDA i 1  [INDEX
JMP 8E+20
[
[
[HIERARCHY STACK MANIPULATIONS
#8H STA
 2T
SCR 6
STC p+5
UMB 3Y  [STACK PAGE,P2
LDH 4    [TOP
COM
ADAi
         [TEMP
APOi
 JMP p+5
[  POP STACK
LDHi4
JMP 1M
LDHi4    [REALIGN
JMP 8H+4
JMP 9E+1
1Z
[
[STACK LAST VARIABLE READ
#8K LDA i
1
ADM i
1345  [LAST FOR LAB USED
JMP 9E  [PUSH STACK
ADA i
-1412
APO i
JMP 2E  [TOO MANY FOR LOOPS
LDA
2I  [LAST VAR RECOGNIZED
ROL 6  [ROL TO CORRECT FOR HIERARCHY
JMP 9E  [PUSH STACK
JMP 8E  [OUTPUT VAR
[FOR STMNT 1 CON
#8L LDA i
31  [STACK 1.
JMP 9X  [1M,1Z
[READ "TO" AND OUTPUT LINK OP
#8M JMP 9Y  [READ LETTER
SAE i
"TO;
JMP 2E  [INCORRECT "TO"
1Z
[READ "STEP"
#8N JMP 9Y
SAE i
"ST;
JMP 2E  [INCORRECT "STEP"
JMP 9Y-5  [2 LETTERS
SAE i
"EP;
JMP 2E  [INCORRECT "STEP"
1Z
[NEXT
#8R JMP 9F  [POP LAST FOR VAR
ROL 6
SAE
2I  [LAST VAR READ
JMP 2E  [INCORRECT FOR NESTING
LDA i
32  [INCR
JMP 1M  [OUTPUT
LDA i
36  [COMPARE OP
JMP 1M  [OUTPUT
JMP 9F  [POP FOR LABEL
JMP 7F+2  [DEFINE LABEL
[OUTPUT OP 33  FOR FOR
#6J LDA i
33
JMP 1M
LDA
8K+3  [FOR LABEL
JMP 7K+2  [OUTPUT LABEL
[GOSUB
#9A LDA i
17  [GOSUB OP
JMP 9X  [1M,1Z
[RETURN
#9B LDA i
34  [RETURN OP
JMP 9X  [1M,1Z
[RESTORE
#9C LDA i
16  [RESTORE OP
JMP 9X  [1M,1Z
[FOR STATEMENT
#9D LDA i
37
JMP 9X  [1M,1Z
[PUSH STACK
#9E STC 2T
LDAi
 -1
ADM
 4
SAEi
 2R
AZEi    [SKIP
JMP 2E+7  [ERR:OVERFLOW STACK
LDAi
#2T         [ITEM PUSHED
UMB 3Y  [STACK PAGE,P2
STA 4
JMP 0
[POP STACK
#9F UMB 3Y  [STACK PAGE,P2
LDA 4
AZEi
JMP 2E+5  [ERR:STACK EMPTY
XSKi4
JMP 0
[
[SYMTAB BUFFER SEARCH
[ACC=ADDRESS OF 1ST
[ENTRY:[0]+1=NOT FOUND RETURN
#7Y STA  [SET PTR
1
BCL i
0377  [LEN|BUF
ADD p+6  [=-4
STC p+11  [SEARCH LIMIT
ADD 0
STC 2I+3  [LINK
JMP p+3
[
LDA i
-4  [-LEN 1 ENTRY
ADM
1
SAE i
0  [LIMIT
JMP p+6  [JMP=>NOT EOB
[EOB
LDA i  [NOT FOUND
1
ADM  [STEP TO NF EXIT
2I+3  [FOUND EXIT
JMP 2I+3
[
LDA i
#2I 0  [SEARCH GOAL
SAE 1
JMP 7Y+11
JMP  [FOUND RETURN
[
[OBTAIN A SYMBOL TABLE ENTRY
#9Z LDA
0
STC 9Z+66  [LINK
LDA i
4  [ENTRY LENGTH
ADM
11  [SYMTAB PTR
SET i 1
[9Z+10=STATE PTR
7W
ADA 1  [-BUF LIM
APO
JMP 9Z+54  [CLEAR ENTRY,EXIT
LDA i 1
STC 11  [NEXT ADDR
STC 9H+7  [BLOCK ON TAPE INDICATOR
ADD 7Y+1  [=1
ADM
9H-1  [CFP
ADA i 1  [QN|0
STC p+15  [QN|BN
[9Z+24
UMB 3W  [P0
LDA
6N+2000  [UNIT [FD3]
ADA i
WRC i
STA
p+5
BCO i
i+0007  [CONSTRUCT MTB
STC p+15  [MTB
UMB 3Y  [P2
0  [WRC i
0  [QN|BN
LDA 1  [QN|0
ROR 1
ADA i
400-4
STC 9H+15  [BUF START [BIC]
ADD 9H-1  [CFP
STC 9H+34  [BIC
LDA i 1
STC 9Z+10  [STATE PTR CHANGE
0  [MTB
0
[9Z+54
CLR
SET 1
11
UMB 3Y  [P2
STA 1
STA i 1
STA i 1
STA i 1
[9Z+64
SET 1
11  [SYMTAB PTR
JMP  [RETURN
[I|O STATES
[
#7W -3374  [-BUF LIM
3400  [NXT BUF ADDR
6|0  [QN|0
7X  [NEXT STATE PTR
[
[
#7X  -3774  [-BUF LIM
3000  [NEXT BUF ADDR
7|0  [QN|0
7X  [NEXT STATE PTR
[
0  [-FB2+12[FD3]
0  [CFP
[SEARCH SYMTAB
[FOR C[2I]
#9H SET 5
0  [LINK
LDA
11  [SYMTAB PTR
JMP 7Y  [SEARCH CUR BLOCK
JMP 7Z+5  [FOUND
SRO i
[9H+7=BLOCK ON TAPE FLAG
7777  [0=>BLOCK ON TAPE
JMP 2E+12  [NOT FOUND
SRO i  [CONTAB SWITCH
[9H+12
0  [7777=>NO BLOCK 2
JMP p+5
LDA i
[9H+15=BUF START ADDR[BIC]
3774
JMP 7Y  [SEARCH BIC
JMP 7Z  [FOUND
LDA
9H-1  [CFP
STC p+2
[9H+23
LDA i
2000  [BN
ADD 9H-2  [-FB2+12[FD3]
APO
JMP 2E+12  [EOF,NOT FOUND
LDA
p-5  [BN
COM
ADA i
[9H+34
2000  [BIC
AZE i
JMP p+21  [SKIP BLOCK
UMB 3W  [P0
LDA
6N+2000  [UNIT[FD3]
ADA i
RDC
STC p+11  [RDC
LDA
9H+15  [BUF START ADDR
BCL i
0377
ROL 1
ADD 9H+24  [BN
STC p+3
[
UMB 3Y  [P2
0  [RDC
0  [QN|BN
LDA i
-1
ADM
9H+24  [BN
JMP 9H+25
[UPDATE BIC
#7Z LDA
7Z-6  [LAST QN|BN READ
BCL i
7000  [ISOLATE BN READ
STC 9H+34  [BIC
[
ADD 1  [PTR TO ENTRY
JMP 5  [RETURN
[
[INSERT FLAG INTO INPUT
#9I STC 1W
SET 17
 0
ADD 1K-1
STC 1K
ADAi
 -4000
ADM
 13     [INPUT POINTER
CLR
JMP 17
[CALC LABEL INDEX
[ACC=LABEL
#9J ADA i
-24
AZE i
CLR
STH
4|p+15  [D2
BCL i 
0077
[*32 [B8]
ROR 2
STA i
0
ROR 1
STA i
0
ROR 2
ADD p-2
ADD p-6
ADA i
0  [D2
[TIMES 3
STA i
0
ROL 1
ADD p-2
JMP 0  [RETURN
[
[READ LETTERS
LDA     [$9Y-5
 1W     [CLASS
SAEi
 7
JMP 2E+13  [ERR:NOT LETTER
#9Y LDA
 0
STC 9Y+22
UMB 3Z  [P3
LDH 13
STHi
 
JMP 1K+1
SAEi
 7      [LETTER
JMP 2E+13  [ERR:NOT LETTER
UMB 3Z  [P3
LDH 13
ADD 9Y+6
STC p+3
JMP 1K+1
LDAi
 
0    [$9Y+22
[
[END BASACT
#2W 1
[ERROR
#2U
[INPUT CONSTANT
#8A LMB 3X  [P1
JMP 1V
STA i 2  [EXP
UMB 3X  [P1
LDA
2005
STC 5
UMB 3Z  [P3
[CONTAB LOOKUP
XSKi5
NOP
SET 3
 5
LDA i
-1
ADM
2  [2 NOW PTS 1 LOWER TAN CONSTANT
ADD 8Z-10  [=5
STC 5 [SAVE INDEX ADDRESS-1
JMP 8Z+16
#8Z SET 1
 2
SET i 6
 -5   [WORDS|CONSTANT
LDAi1
SAEi3
 JMP p+5
XSKi6
 JMP p-4
LDAi3 [VAR #
JMP 8E+20  [BSE i 1000,1M,1X
LDA
 6
COM
ADM
 3
SAEi
 4|2H [CONTAB HI
 JMP 8Z [NEXT
[ADD TO CONTAB
SET 1
5
LDA i
1
ADM
6R+25  [LVU
STA i 1  [SET INDEX IN TABLE
BSE i
1000  [RUN PROCESSOR CODE
JMP 1M [OUTPUT
LDA i
-6  [WORDS|CONSTANT +INDEX
ADM
2  [UPDATE TABLE PTR
BCL i
5777
AZE
1Z
[EMPTY CONTAB
LMB 3X  [P1
JMP 6P  [EMPTY CONTAB ROUTINE
1Z
[
[READ
#7L LDA i
30  [READ OP CODE
JMP 7M+2
[INPUT
#7M LDA i
26  [INPUT OP CODE
STA i
#7A 0
1Z
[
#7N LDA
7A
JMP 1M
JMP 7H+1  [ASSIGNMENT OP
[
[
[INCHAR
JMP 0
#1K NOP  [SWITCH
LDA
0
STC 1K+22
ADD 1K-1  [=6000
STC 1K    [JMP 0
JMP 1J    [INCHAR|SPACE
SHD i
1400  [SPACE
JMP 1K+6
ROR 1 [ADDR CLASSTAB
ADA i
1L    [CLASSTAB
STC 1
UMB 3X  [P1
LDH 1 [CLASS
STA
1W
JMP   [EXIT
[
[UNPUT BUF P3,2400-2777
[INPUT CHAR OR SPACE
#1J UMB 3Z  [P3
SET 1
0  [LINK
LDH i 13  [INPUT
LDA i
-3000
ADD 13
AZE i
JMP p+3  [EOB
[1J+11
LDH 13  [LOAD CHAR
JMP 1  [RETURN
[
[INPUT A NEW BLOCK
7U=1750
[7U=FD #1
[
LDA i
1
ADD 7U+1  [CFP
STC 7U+1
ADD 7U+2  [U|FB2
BCL i
7000  [REMOVE UNIT
COM
ADD 7U+1  [CFP
APO i
JMP 2E+14  [ERR:EOF SOURCE CODE
[2E IS ERROR CLASS JMP LIST
LDA i
5|0  [Q5
ADD 7U+1  [CFP
STC p+10  [SET QN|BN
ADD 6L  [UNIT[FD1]
ADD p+5  [=RDC
STC p+4
LDA i
JMP p+2
STC p-5
[
RDC
0  [QN|BN
[
[UMB=3 FOR READ
SET i 13
2400
[
JMP 1J+11
[
[
[OUTPUT WD IN ACC
[OUT BUF P3,3000-3777
#1P UMB 3Z  [P3
STA 7  [OUTPUT
XSK i 7  [FIND NEXT
JMP 0  [RETURN
SET 1
0  [LINK
[
7V=1756
[7V=FD # 3
[
[
[THE NEXT COMMAND IS REPLACED BY A JUMP DYNAMICALLY
LDA
6N  [U[FD3]
ADM
4X  [=WRI i
STC 4X+2
ADD 6N  [U|FD3]
ADM
4X+11  [=CHK
ADD 4X+4  [=i
STC 4X+4
LDA i
JMP p+2
STC p-14
[
LDA i
1
ADD 7V+1  [CFP
STC 7V+1
ADD 7V+2
BCL i
7000  [REMOVE UNIT
COM
ADD 7V+1  [CFP
APO i
JMP 2E+15  [ERR:EOF TARGET CODE FILE
LDA
7V+1  [CFP
SRO i
5252
JMP p+7  [2ND BLOCK
[
BSE i
6|0  [QN=6
STA
4X+1  [WRI i
STC 4X+5  [CHK i
JMP p-25  [NEXT BLOCK
[
BSE i
7|0  [QN=7
STA
4X+3  [WRI i
STC 4X+12  [CHK
[
UMB 3Z  [P3
#4X WRI i
0  [6|BN
WRI i
0  [7|BN
i
0  [6|BN
SAE i
7777
JMP 4X  [WRITE AGAIN
[4X+11
CHK
0  [7|BN
SAE i
7777
JMP 4X+2  [WRITE AGAIN
JMP 1  [DONE,RETURN
[
[
[
[TERMINATE
#2B LDA i
25
JMP 1P  [OUTPUT END CODE
[OUTPUT PARTIAL OUTPUT BUFFER
LDA 
7  [OUTPUT PTR
BCL i
7377
AZE
JMP 1P+4  [OUTPUT BOTH
APO
JMP p+13
LDA i
JMP 4X-1
STC 4X-7
LDA 
1P+21  [=JMP TO ELIMINATE UNIT AND COMMAND INIT
STC 1P+6
LDA i
WRC
ADD 6N  [U[FD3]
STC 4X
LDA i
JMP 1
STC 4X+2
JMP 1P+4  [OUTPUT LAST BUFFER
[
LMB 3X  [P1
JMP 6P  [EMPTY CONTAB
[EMPTY SYMTAB
JMP 9Z
CLR
COM
UMB 3Y  [P2
STA 11
ADD p+1
STC 11  [FORCE EOB
JMP 9Z  [OUTPUT LAST BLOCK
LDA i
6V  [RBN TRAN PROG
ADD 6R+3  [FB1[SYSTEM FILE]
STC p+5
ADD 6M  [U[FD2]
ADD p+2  [=RDC
STC p+1
RDC
0  [U|BN
JMP 20
[BEGIN TRANSITION PROG
[ADDRESS CONSTANTS
[ADCONS
1S=2437  [ST10 ORIGIN
1Y=JMP 1G [PATH CONDITIONAL FAIL
1Z=JMP 1F [PATH RETURN
2R=2000  [ST4 LO
8X=1777  [LEN FP #
8W=1765  [LVI
8Y=1776  [-#WDS|DATA BLOCK
2S=2177  [ST4 HI
2G=2000  [CONTAB LO LIM  P3
2H=2377  [CONTAB HI LIM P3
3W=0  [SCAN PAGE
3X=1  [DIAG PAGE
3Y=2  [SYMTAB PG
3Z=3
1Q=3110  [ADDRESS OF ADDR OF NODE 1
6R=1750  [START OF SYSTEM CONSTANT AREA
2Q=3040  [ADDRESS OF LENGTH OF KEYWORD TABLE
6P=22  [ADDR OF CONTAB EMPTY ROUTINE IN P1
1L=3000  [CLASS TABLE
[
[FILE STRUCTURE DEFINITION FOR BASICP
6S=0  [RBN COMPILER
6T=14  [RBN DIAGRAM ERROR PROCESSOR
6U=24  [RBN ERROR FILE
6V=34  [RBN TRAN PROG
6W=50  [RBN RUN PROC
6X=62  [RBN OBJECT TIME ERROR PROCESSOR
6Y=72  [RBN SYSTEM FUNCTIONS
[
[
[LOAD ERROR PROCESSOR
#2A LDA
0
STC 6R+23  [ERROR CODE
UMB 3X  [P1
RDC  [THIS COMMAND INIT IN P2
QN|BN
LMB 3X  [P1
JMP 1  [ENTER ERROR PROCESSOR
0  [TERMINAL JMP SET BY ERROR PROCESSOR
[UMB 1 SET BY ERROR PROCESSOR
RDC  [RESTORE COMPILER
QN|BN
JMP p-3
[
[P0 INIT
[EX AFTER P1 INIT
[SKIP HEADER
#2C JMP 1K+1
JMP 1K+1
JMP 1K+1
JMP 1K+1
[
JMP 1K+1
[OP REQUIRED FOR LABEL ALIGNMENT
LDA i
21  [PR CR-LF
JMP 1P  [OUTPUT
JMP 1B
[
[PAGE 0 LINK ROUTINE
#2X STA
p+13  [SAVE ACC
LDA
0  [LINK IN P1
STC 1
XSK i 0
ADD 0
STC p+10
UMB 3X  [P1
LDA 1  [LOAD DEST JMP
STC p+3
LDA i
0
0  [DESIRED JMP
LMB 3X  [P1
JMP  [RETURN
[
[
#6L 0  [U[FD1]
#6M 0  [U[FD2]
#6N 0  [U[FD3]
#6O 0  [U[FD4]
[
$1723
#2L 0  [LINE #
0  [CFP AT START OF CURRENT STATEMENT
0  [INPUT PTR MOD 400 AT START OF CUR. STMNT.
0  [ST4 PTR AT START OF CUR. STMNT.
0  [ST10 PTR AT START OF CUR. STMNT.
$1730
#2E JMP 2A  [0
JMP 2A  [1
JMP 2A  [2
JMP 2A  [3
JMP 2A  [4
JMP 2A  [5
JMP 2A  [6
JMP 2A  [7
[
JMP 2A  [10
JMP 2A  [11
JMP 2A  [12
JMP 2A  [13
JMP 2A  [14
JMP 2A  [15
JMP 2A  [16
JMP 2A  [17
[
[
[1750 BEGINS SYSTEM CONSTANT AREA
[
[END OF CURRENT MANUSCRIPT