file CSGDATA

File CSGDATA
Directory of image this file is from
This file as a plain text file
*20
	LIF 0
	HOP START
	*400
	CLEAN
	AXO
	ESF
	IOB
	PMODE
	IOF
	LMODE
	LDA I
	701
	STC 16
	LDA I
	7300
	STC 17
	JMP 16
	SEGMNT 0
	PMODE
	*20
K7100,	7100
K260,	260
K100,	100
NTIME,	0
K6100,	6100
K320,	320
K300,	300
K60,	60
	*41
	LMODE
	PDP
	PMODE
CLK,	CLA CLL
	RMF
	CLSK
	JMP NOTCLK
	CLSA
	LINC
	LMODE
	APO I
	JMP CH1
	XSK I 2
	JMP SING
	JMP OFF
	PMODE
NOTCLK,	LINC
	LMODE
	LDA
	40
	ADA I
	6000
	STC .+1
	0
	*200
START,	CLR
	ESF
	STC 4
	SET I 13
	CHART-1
	SET I 3
	CHART
	SNS I 1
	JMP OFF
	LSW
	AZE I
	JMP OFF
	COM
	STC 2		/NO. OF TRIALS
	LDA I
	6000
	STC .+2
	RDC 
FBLK,	0
	LDA
	3377
	SAE I
	7777
	SKP
	JMP .+6
	LDA I
	1
	ADM
	FBLK
	JMP FBLK-1
SING,	CLR
	STC AORB
	STC 5		/STIM NO.
	LDA I
	2525
	STC RYR1
	LDA I
	LDF 3
	STC FLD1
	LDF 3
	LDA I
	7253
	STC RYR2
	ATR
	SET I 17
	3777
	SET I 15
	-12
	CLR
	STA I 17
	XSK 17
	JMP .-2
	PDP
	PMODE
	CLA
	CLEN
	CLAB
	CLLR
	TAD K100
	CLLR
	CLSA
	CLA
	TAD K60		/INPUT 1 ENABLE
	CLEN		/FLAG 1 ENABLE
	CLA
	TAD K300	/CLOCK STOPPED
	CLLR		/MODE THREE
	LINC
	LMODE
	LDA I
	3777
	STC S12
	LDA I
	20		/RELAY 1
	ATR
	JMP DISA
CH1,	CLR
	XSK I 5		/STIM NO.
	LDA I
	3777
	SRO I
RYR1,	2525
	JMP .+3
	LDA I
	2777
	STC S12
	SRO I
RYR2,	7253
	JMP .+5
	LDA I
	1
	ADM
	FLD1
FLD1,	LDF 3
	SET I 16
	-1000
	SET I 14
	-20
	SAM 10
	XSK I 14
	JMP .-1
A,	SCR 2
	STA I 17
	XSK I 16
	JMP .-10
	XSK I 15
	JMP DISA
	RSW
	AZE I
	JMP OFF
	COM
	ADA I
	1
	STC NTIME
	PDP
	PMODE
	CLA
	CLEN
	CLAB
	CLLR
	TAD K100
	CLLR
	CLSA
	CLA
	TAD NTIME
	CLAB
	CLA
	TAD K320
	CLEN
	CLA
	TAD K6100
	CLLR
	LINC
	LMODE
	LDA I
	60
	ATR		/RELAY 0
	SET I 15
	-12
	SET I 17
	3777
	LDA I
	7253
	STC RYR3
	CLR
	LDF 1
	STA I 17
	XSK 17
	JMP .-2
	LDA I
	LDF 3
	STC FLD2
B,	SET I 16
	-1000
	SET I 14
	3777
	SRO I
RYR3,	7253
	JMP .+5
	LDA I
	1
	ADM
	.+1
FLD2,	LDF 3
	LDA I 17
	PDP
	PMODE
	SPA
	JMP NEG
	MQL
	DVI
	12
	CLA
	MQA
	JMP POS
NEG,	CMA
	MQL
	DVI
	12
	CLA
	MQA
	CMA
POS,	LINC
	LMODE
	LDF 1
	ADM I 14
	XSK I 16
	JMP FLD2
	XSK I 15
	JMP B
INTR,	CLR
	STC INT
	LDF 1
	SAM 0
	ADA I
	1000
	SCR 1
	ADA I
	2000
	STC 17
	SAM 1
	ADA I
	1000
	SCR 1
	ADA I
	2000
	STC 16
	LDA 17
	COM
	STC .+3
	LDA I 17
	ADA I
	0
AA,	SCR 3
	ADM
	INT
	LDA
	17
	SAE
	16
	JMP AA-3
	LDA I
INT,	0
	STA I 13
	XSK I 3
	SET I 17
	3777
	SET I 16
	-400
	SET I 15
	2777
COL,	LDA I 17
	SCR 1
	STC .+4
	LDA I 17
	SCR 1
	ADA I
	0
	STA I 15
	XSK I 16
	JMP COL
	LDA
	4
	XSK I 4
	STA
	3377
	STA
	2777
	SNS 5
	JMP DISB
	LDA
	FBLK
	STC .+2
	WRC 
	6000
	LDA I
	1
	ADM
	FBLK
	SAE I
	6777
	SKP
	HLT
DISB,	CLR
	LDA I
	3777
	STC S12
	LDF 1
	LDA I
	1
	STC AORB
	SNS I 1
	JMP DTAPE
	SNS I 2
	JMP IBLK
	SNS I 4
	JMP CBLK
	SNS I 0
	JMP DCHART
	SET I 11
	TRL-1
	SET I 6
	-6
	SET I 1
	40
DTRL,	LDA I 11
	ROL 1
	ADA I
	PATRN
	STC 7
	LDA I
	320
	DSC 7
	DSC I 7
	LDA I
	2
	ADM
	1
	XSK I 6
	JMP DTRL
	SET I 6
	-2
	LDA
	3377
	ROL 6
	STC .+2
ULPK,	LDA I
	0
	ROL 3
	STA
	.-3
	BCL I
	7770
	BSE I
	60
	ROL 1
	ADA I
	PATRN
	STC 7
	LDA I
	320
	DSC 7
	DSC I 7
	LDA I
	2
	ADM
	1
	XSK I 6
	JMP ULPK
DISA,	CLR
	IOB
	PMODE
	ION
	LMODE
	SNS 3
	JMP .+5
	LDA
	FBLK
	SNS I 3
	JMP .-1
	CLR
	SAM 0
	ADA I
	1000
	SCR 1
	STC CUR1
	SAM 1
	ADA I
	1000
	SCR 1
	STC CUR2
	SAM 4
	SCR 1
	STC CUR1Y
	SAM 5
	SCR 1
	STC CUR2Y
	SAM 2
	SCR 1
	STC Y
	SET I 11
	CTIME+5
	SET I 7
	-3
	LDA
	CUR1
	COM
	ADA
	CUR2
	APO
	JMP NOD
	ROL 3
	STC .+2
UNPC,	LDA I
	0
	ROL 3
	STA
	.-3
	BCL I
	7770
	BSE I
	60
	STA I 11
	XSK I 7
	JMP UNPC
	LDA
	CTIME+10
	STA
	CTIME+11
	LDA
	CTIME+7
	STA
	CTIME+10
	LDA I
	56
	STA
	CTIME+7
	SET I 11
	CTIME-1
	SET I 1
	500
	SET I 6
	-20
DTIME,	LDA I 11
	ROL 1
	ADA I
	PATRN
	STC 7
	LDA I
	-320
	DSC 7
	DSC I 7
	LDA I
	2
	ADM
	1
	XSK I 6
	JMP DTIME
NOD,	SET I 12
S12,	0
	SET I 16
	-1000
	SET I 10
	1777
E,	LDA I 12
	ADA I
Y,	0
	DIS I 10
	LDA I
CUR1Y,	0
	STC CURY
	LDA I
CUR1,	0
	SAE
	10
	SKP
	JMP CURA
	LDA I
CUR2,	0
	SAE
	10
	JMP NOCUR
	LDA I
CUR2Y,	0
	STC CURY
CURA,	SET I 11
	-6
	LDA 12
	ADA
	Y
	DIS 10
	DIS 10
	LDA I
CURY,	0
	ADA I
	2
	DIS 10
	XSK I 11
	JMP .-4
NOCUR,	CLR
	XSK I 16
	JMP E
	LDA I
AORB,	0
	AZE
	JMP DISB
	SET I 11
	RES-1
	SET I 6
	-11
	SET I 1
	40
RDIS,	LDA I 11
	ROL 1
	ADA I
	PATRN
	STC 7
	LDA I
	320
	DSC 7
	DSC I 7
	LDA I
	2
	ADM
	1
	XSK I 6
	JMP RDIS
	SET I 6
	-2
	LDA
	5
	ROL 6
	STC .+2
UMPC,	LDA I
	0
	ROL 3
	STA
	.-3
	BCL I
	7770
	BSE I
	60
	ROL 1
	ADA I
	PATRN
	STC 7
	LDA I
	320
	DSC 7
	DSC I 7
	LDA I
	2
	ADM
	1
	XSK I 6
	JMP UMPC
	JMP DISA
DCHART,	CLR
	IOB
	PMODE
	ION
	LMODE
	SET I 1
	40
	LDA I
	350
	DIS 1
	ADA I
	-1
	SAE I
	-251
	JMP .-5
	LDA I
	-250
	DIS I 1
	LDA
	1
	SAE I
	740
	JMP .-7
	LDA
	3
	SAE I
	CHART
	SKP
	JMP DISB
	SAM 6
	ADA I
	1000
	COM
	STC P6
	LDA I
	CHART
	STC CH
	LDA I
	50
	STC 1
	LDA I
	106
	ADA I
	PATRN
	STC 7
	LDA
CH,	CHART
	ADA I
P6,	0
	DSC 7
	DSC I 7
	LDA I
	20
	ADM
	1
	LDA I
	1
	ADM
	CH
	SAE
	3
	SKP
	JMP DISB
	LDA I
	124
	ADA I
	PATRN
	STC 7
	JMP CH-1
DTAPE,	CLR
	LDF 1
	LSW
	SAE I
	7777
	SKP
	JMP 0
	STC .-3
	LSW
	BCL I
	7000
	BSE I
	6000
	STA
	BLK
	STC .+2
	RDC 
	6000
	SET I 17
	3777
	SET I 16
	-400
	SET I 15
	3000
EXP,	LDA 15
	STA I 17
	LDA 15
	SCR 1
	STC .+4
	LDA I 15
	SCR 1
	ADA I
	0
	STA I 17
	XSK I 16
	JMP EXP
	LDA
	3377
	STA
	2777
	STC 4
	JMP OFF
CBLK,	CLR
	LSW
	SAE I
	7777
	SKP
	JMP 0
	STC .-3
	LDA I
	7777
	STA
	3377
	SNS 1
	JMP 0
	WRC 
BLK,	6000
	JMP DISB
IBLK,	CLR
	LSW
	SAE I
	7777
	SKP
	JMP 0
	STC .-3
	JMP INTR
OFF,	CLR
	ATR
	PDP
	PMODE
	CLA
	CLEN
	CLAB
	CLLR
	TAD K100
	CLLR
	CLSA
	CLA
	LINC
	LMODE
	JMP DISB
CTIME,	24
	11
	15
	5
	75
	40
	0
	56
	0
	0
	40
	15
	23
	5
	3
	40
	40
	40
RES,	22
	5
	23
	20
	17
	16
	23
	5
	40
	40
	40
	40
TRL,	24
	22
	11
	1
	14
	40
	40
	40
	40
CHART,	0
/SNS 0 AVERAGED WAVEFORM OR ITS INTEGRAL
/SNS 1 DISPLAY LSW TAPE BLOCK
/SNS 2 INTEGRATE LSW BLOCK
/SNS 3 ????
/SNS 4 CLEAR LSW BLOCK
/SNS 5 WRITE AVERAGED WAVEFORM ON TAPE.
/
/RSW NUMBER OF SECONDS OF TETANIZATION
/LSW NUMBER OF TETANIZATIONS.
/
/POT 0 HORIZ FOR LEFT CURSOR
/POT 1 HORIZ FOR RIGHT CURSOR
/POT 4 VERT FOR LEFT CURSOR
/POT 5 VERT FOR RIGHT CURSOR
/POT 2 VERT FOR VAVEFORM DISPLAY
/POT 6 VERT FOR INTEGRAL CHART DISPLAY
/
/CLOCK CH 1-ONE SEC PULSES IN SYNC WITH
/           STIMULUS.
/A/D CH 10-RESPONSE INPUT.
/RELAY 0-TURNS ON TETANIZATION 
	PMODE
	*1600
/ADD PATRN TABLE HERE
/PATTERN WORDS FOR CHAR DISPL.
PATRN,	4522		/AT SIGN
       	1645
   	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	7700		/[
	0041
	1020		/\
	0204
	4100		/]
	0077
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6060		/"
	0
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0526
	5000		/APOSTROPHY
	60
	0000		/(
	4136
	3641		/)
	0000
	2050		/*
	50
	404		/+
	437
	0500		/,
	0006
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	4201		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?
PATEND,	2055
/END OF PATRNS TABLE
/EAE INSTRUCYION TABLE
	CLA=7601
	SCL=7403
	MUY=7405
	DVI=7407
	NMI=7411
	SHL=7413
	ASR=7415
	LSR=7417
	MQL=7421
	SCA=7441
	MQA=7501
	CLA=7601
	CAM=7621
	HOP=6000
	STOP=0000
	SKIP=467
	SUB=4000
	MASK=0
	CLEAN=11
	ZERO=0
	ONE=1
	TWO=2
	THREE=3
	FOUR=4
	FIVE=5
	SIX=6
	SEV=7
	TEN=10
	ELV=11
	TWELV=12
	THRTN=13
	FORTN=14
	FIFTN=15
	SIXTN=16
	SEVTN=17
/
/
/INSTRUCTIONS FOR OPERATING CSGDATA
/AS FOLLOWS:
/
/LEFT SWITCHES SELECT NUMBER OF TRIALS
/RIGHT SWITCHES SELECT DURATION OF 
/		TETANIZATION
/POT 0 HORIZ FOR CURSOR ONE
/POT 4 VERT  "     "     "
/POT 1 HORIZ "     "    TWO
/POT 5 VERT  "     "     "
/POT 2 VERT FOR RESPONSE DISPLAY
/POT 6 VERT FOR RESPONSE INTEGRALS
/
/POINT "A" IN PROGRAM IS AT CORE
/	LOCATION 343.  THIS IS THE
/	SCALING FACTOR BEFORE STORING
/	EACH SAMPLE FROM AD 10
/POINT "AA" IN PROGRAM IS AT CORE
/	LOCATION 517.  THIS IS THE
/	SCALING FACTOR FOR EACH POINT
/	DURING INTEGRATION.
/USE START LS400 TO KEEP TEMPORARY
/       CHANGES.
/
/
/
/SENSE SW 0 LOOK AT INTEGRAL TABLE
/         1 LOOK AT BLOCK IN LFT SWTCHS
/         2 INTEGRATE THAT BLOCK
/	  3 LOOK AT CURRENT BLOCK NUMBER
/	  4 CLEAR THAT BLOCK
/	  5 ENABLE WRITE ON TAPE
/
/CLOCK CHANNEL ONE IS ONE HZ SIGNAL
/	FROM DIGITIMER
/ANALOGUE INPUT 10 IS RESPONSE CHANNEL
/RELAY 0 ON DURING TETANIZATION
/RELAY 1 ON ENABLES STIMULUS 
/
/
/START BY LEFT  SW 0701
/	  RIGHT SW 0000
/	  I/O PRESET
/	  START 20
/
Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with. I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation.

PDP-8 Home Page PDP-8 Site Map PDP-8 Site Search