Directory of image this file is from
This file as a plain text file

[THE NEVER-ENDING SEARCH FOR PERFECT, AMICABLE, AND SOCIABLE NUMBERS
[WRITTEN BY PETER K. AND WESLEY A. CLARK, AND NICELY, TOO.
[AUGUST 24, 1970.
$20
JMP 6N
[SET PRINT INDIC OFF
#1J CLR
STA i
#2J [PRINT INDIC
JMP 4T
[RC+1 TO RC
#3J SET i 15
#6P -1  [ROOT LENGTH
SET i 17
1K
CLR
LDA i
1
LAM i 17
STC 1776
XSK i 15
JMP p-3
ADD 1776
APO i
JMP p+5
LDA i
-1
ADM
6P
[CEAR ALL BUT RC
#4J SET i 15
-100
SET i 16
2K
CLR
STA i 16
XSK i 15
JMP p-2
[RL TO WL
LDA
6P
STC 3P
[RC TO WC
SET i 16
1K
SET i 17
2K
JMP 1T
[SET STEP COUNTER
SET i 4
-400
[1 TO DA
#5J SET i 17
4K
JMP 1Z
LDA i
1
STC 4K+1
[1 TO TD
SET i 17
3K
JMP 1Z
LDA i
1
STC 3K+1
[GO AWAY IF KEY HIT
#6J KST [KEY HIT
JMP 6L [NO
KBD [YES
WCG [WRITE ALL ON BLOCKS 0-3
3000
JMP 4T [CAR RET
JMP 4T
JMP 4T
LDAi
3522 [RIGHT ARROW
JMP 3T+3
JMP 3U [PRINT WC,RC
HLT [ALL DONE
[RE-ENTRY POINT
#6N LDAi
3522 [RIGHT ARROW
JMP 3T+3
JMP 3U [PRINT WC,RC
JMP 4T [CAR RET
JMP 4T
RCG [READ ALL
3000
JMP 6J [CONTINUE
[TD+1 TO TD
#6L SET i 17
3K
JMP 1N
[PARITY TEST
LDA
3K+1
ROR 1
APO
JMP p+6
LDA
2K+1
ROR 1
APO
JMP 6J
[MAIN DIVISION
JMP 7H
JMP 1D
[DOES TD EXCEED LQ?
SET i 16
3K
SET i 17
8K
JMP 1G
APO
JMP 7J
[IS REMAINDER?
SET i 17
5K
JMP 2P
CLR
BSE i 17
XSK i 15
JMP p-2
SAE i
0
JMP 6J
[TD+DA TO DA
SET i 16
3K
SET i 17
4K
JMP 1A
JMP 4P [LENGTHEN?
[DOES TD=LQ?
SET i 16
3K
SET i 17
8K
JMP 1E
APO i
JMP 7J
[LQ+DA TO DA
SET i 16
8K
SET i 17
4K
JMP 1A
JMP 4P [ LENGTHEN?
JMP 6J
[IS PRINT INDIC ON?
#7J LDA
2J
APO i
JMP 9J
JMP 1W
JMP 4T
JMP 9J
[PRINT WC
#1W LDA
0
STC 2W
JMP 1H
#1Q JMP 3H
JMP 5H
JMP 3H
JMP 3H
SET i 16
5K
SET i 17
3K
JMP 1A
JMP 4P [LENGTHEN?
SET i 16
3K
SET i 17
2K
JMP 1G
APO i
JMP 1Q
#2Q JMP 5H
SET i 17
6K
JMP 1Z
LDA i
12
STC 6K+1
JMP 1D
SET i 16
8K
SET i 17
3K
JMP 1T
LDA
3K+1
ROR 1
APO
JMP 3Q
JMP 7H
JMP 1D
LDA
8K+1
JMP 3T
SET i 16
5K
SET i 17
2K
JMP 1T
JMP 2Q
#3Q LDA
2K+1
JMP 3T
#2W
[DA TO WC
#9J SET i 16
4K
SET i 17
2K
JMP 1T
[DOES WC=RC?
SET i 16
2K
SET i 17
1K
JMP 1E
APO i
JMP 8J
[IS WC<RC?
SET i 16
1K
SET i 17
2K
JMP 1G
APO
JMP 3J
[INDEX THE STEP COUNTER
#8W XSK i 4
JMP 5J
JMP 3U
JMP 3J
[IS THE PRINT INDICATOR ON?
#8J LDA
2J
APO
JMP 1J
COM
STC 2J
JMP 4J
[X TO Y
#1T LDA
0
STC 2T
JMP 2P
LDA i 16
STA i 17
XSK i 15
JMP p-3
#2T
[Y+1 TO Y
#1N LDA
0
STC 2N
JMP 2P
CLR
LDA i
1
LAM i 17
STC 1777
XSK i 15
JMP p-3
ADD 1777
#2N
[X+Y TO Y
#1A LDA
0
STC 2A
JMP 2P
CLR
LDA i 16
LAM i 17
XSK i 15
JMP p-3
STA i
#3A
#2A
[SET UP LENGTH CTR
#2P SET i 15
#3P -1
JMP 0
[-X TO Y
#1C LDA
0
STC 2C
JMP 2P
LDA i 16
COM
STA i 17
XSK i 15
JMP p-4
LDA
17
ADD 3P
STC 17
JMP 1N
#2C
[DOES X=Y
#1E LDA
0
STC 2E
JMP 2P
LDA i 16
SAE i 17
JMP p+5
XSK i 15
JMP p-4
CLR
JMP p+3
CLR
COM
#2E
[X>Y?
#1G LDA
0
STC 2G
JMP 2P
LDA
17
STC 3G
SET i 17
9K
JMP 1C
SET i 17
9K
SET i 16
#3G
JMP 1A
#2G
[0 TO Y
#1Z LDA
0
STC 2Z
JMP 2P
CLR
STA i 17
XSK i 15
JMP p-2
#2Z
[1 TO TD
#1H LDA
0
STC 2H
SET i 17
3K
JMP 1Z
LDA i
1
STC 3K+1
#2H
[TWICE TD TO TD
#3H LDA
0
STC 4H
SET i 17
3K
CLR
JMP 1F
JMP 4P
#4H
[ADJUST LENGTH
#4P SET 1
0
APO i
JMP 1
LDA i
-1
ADM
3P
SAE i
-11
JMP 1
HLT
[TD TO LA
#5H LDA
0
STC 6H
SET i 16
3K
SET i 17
5K
JMP 1T
#6H
[WC TO LA, TD TO LD
#7H LDA
0
STC 8H
SET i 16
2K
SET i 17
5K
JMP 1T
SET i 16
3K
SET i 17
6K
JMP 1T
#8H
[SHIFT Y LEFT 1
#1F LDA
0
STC 2F
JMP 2P
LDA i 17
ROL i 1
STA 17
XSK i 15
JMP p-4
#2F
[DIVIDE
#1D LDA
0
STC 6D
[LD>LA?
SET i 16
6K
SET i 17
5K
JMP 1G
APO i
JMP p+5
SET i 17
8K
JMP 1Z
JMP 6D
[NORMALIZE LA AND LD
SET i 14
0
LDA
3P
COM
ADA i
5K
STC p+2
LDA
0
ROL 1
APO
JMP p+11
SET i 17
5K
CLR
JMP 1F
XSK i 14
ROL 1
APO i
JMP p-7
SET i 13
0
LDA
3P
COM
ADA i
6K
STC p+2
LDA
0
ROL 1
APO
JMP p+11
SET i 17
6K
CLR
JMP 1F
XSK i 13
ROL 1
APO i
JMP p-7
[SET THE DIVIDE COUNTER
LDA
13
ADA i
1
COM
ADD 14
STC 12
[-LD TO LC
SET i 16
6K
SET i 17
7K
JMP 1C
[0 TO LQ
CLR
SET i 17
8K
JMP 1Z
[LC+LA TO LA
#2D SET i 16
7K
SET i 17
5K
JMP 1A
[SHIFT LQ LEFT 1
#3D SET i 17
8K
JMP 1F
XSK i 12
JMP p+2
JMP 4D
[SHIFT LA LEFT 1
SET i 17
5K
CLR
JMP 1F
LDA
8K+1
ROR 1
APO
JMP 2D
[LD+LA TO LA
SET i 16
6K
SET i 17
5K
JMP 1A
JMP 3D
#4D LDA
3A
APO i
JMP 5D
[LD+LA TO LA
SET i 16
6K
SET i 17
5K
JMP 1A
[SHIFT LA RIGHT BETA TIMES
#5D LDA
13
COM
STC 13
LDA
3P
COM
ADA i
5K
STC 17
JMP 2P
CLR
#8D LDA 17
ROR i 1
STA 17
XSK i 15
JMP p+2
JMP 7D
LDA i
-1
ADM
17
JMP 8D
#7D XSK i 13
JMP 5D+4
#6D
[TELETYPE
#3T ROL 1
ADA i
3540
SET 2
0
[CLASSIC VS MICRO FIX
MSC 2
SKP 17
JMP p+5
[MICRO
SCR 1
OPR 42
JMP p-1
JMP 2
[CLASSIC
ATR
SET i 3
-435
XSK i 3
JMP p-1
SCR 1
AZE
JMP p-7
JMP 2
[CARR RET AND LINE FEED
#4T LDA
0
STC 5T
LDA i
3432
JMP 3T+3
LDA i
3424
JMP 3T+3
#5T
[THE ABOVE TELETYPE ROUTINE WAS KINDLY SUPPLIED BY MAURICE L. PEPPER JR.
#3U LDA
0
STC 3W
JMP 1W
LDA i
3530
JMP 3T+3
SET i 16
1K
SET i 17
2K
JMP 1T
JMP 1W
JMP 4T
JMP 4T
#3W
1K=1400-1
2K=1410-1
3K=1420-1
4K=1430-1
5K=1440-1
6K=1450-1
7K=1460-1
8K=1470-1
9K=1500-1
[THIS PROGRAM, CUDDLY 9, PRINTS OUT CHAINS OF NUMBERS WITH THEIR ROOTS ON ONE OF FOUR CONDITIONS-
[CONDITION #1- A GIVEN ROOT NUMBER IS A PERFECT NUMBER.
[CONDITION #2- THE ROOT NUMBER AND THE NUMBER FOLLOWING IT ARE BOTH AMICABLE NUMBERS.
[CONDITION #3- THE CHAIN OF A GIVEN NUMBER REVERTS TO THAT NUMBER AFTER THREE OR MORE LINKS IN THE CHAIN MAKING EACH NUMBER IN THE GROUP A SOCIABLE NUMBER.
[THIS IS CUDDLY16