Directory of image this file is from
This file as a plain text file

*20
/MAIN PROGRAM TO DO THE STUFF
/DESCRIBED IN INPUT ROUTINE
	SEGMNT 6
	*20
	CLR
	IOB
	TLS
	LDA I
	300		/LARGE PRINT
	ESF		/FAST SAM
	IOB
	CLLR
	IOB
	CLSA
	LDA
	1765		/SCALE DATA N
	BSE I
	SCR
	STC MSCL
	SET 13
	1763		/AV-N TRIALS
	LDA
	1764
	BSE I
	7000
	STC BLK		/FIRST BLK
NDSP,	CLR
	SET I 17
	TX4-1!4000
	SXL 13
	JMP .+3
	JMP DSP
	JMP NDSP
/CLEAR FIELDS OF 3400-3777
	LDA I
	LDF 0
	STC .+6
	SET I 16
	-6
	SET I 17
	3377
	CLR
	LDF 0
	STA I 17
	XSK 17
	JMP .-2
	LDA I
	1
	ADM
	.-7
	XSK I 16
	JMP .-11
	SET I 10
	3777
	JMP EV
/SET UP CLOCK
	PDP
	PMODE
	CLA
	CLEN
	CLAB
	CLLR
	CLSA
	CLA
	TAD K100
	CLLR		/CLEARS CLOCK
	CLA
	TAD NTIME
	CLAB
	CLA
	TAD K304	/OF INTERRUPT
	CLEN		/CH 2 ENABLE
	CLA
	TAD K1100
	CLLR
	JMP .+5
K100,	100
NTIME,	-50
K304,	304
K1100,	1100
	LINC
	LMODE
/SET UP TO SAMPLE SENSE LINES
CHB,	SET 11
	1761
	XSK I 10
	NOP
	LDA
	10
	SAE I
	3400
	JMP .+4
	SET I 10
	3777
	JMP CHB
	CLR
	IOB
	CLSK
	JMP .-2
	IOB
	CLSA
	ROL 10
	APO
	JMP RSP
	SXL I 12
	JMP RSP
/SAMPLE, WIPING OUT PREVIOUS CONTENTS
	LDA I
	1
	LDF 0
	SXL I 0
	STA 10
	LDF 1
	SXL I 1
	STA 10
	LDF 2
	SXL I 2
	STA 10
	LDF 3
	SXL I 3
	STA 10
	LDF 4
	SXL I 4
	STA 10
	LDF 5
	SXL I 5
	STA 10
	XSK I 11
	SKP
	JMP CHB
/SAMPLE,  ADDING BITS TO FIELD CONTENTS
WAIT,	CLR
	IOB
	CLSK
	JMP .-2
	IOB
	CLSA
	ROL 10
	APO
	JMP RSP
	SXL I 12
	JMP RSP
	LDA I
	1
	LDF 0
	SXL I 0
	ADA 10
	LDF 1
	SXL I 1
	ADA 10
	LDF 2
	SXL I 2
	ADA 10
	LDF 3
	SXL I 3
	ADA 10
	LDF 4
	SXL I 4
	ADA 10
	LDF 5
	SXL I 5
	ADA 10
	XSK I 11
	JMP WAIT
	JMP CHB
/RESPONSE OCCURED
RSP,	LDA I
	100
	STA 10		/IND RSP ON 5
	LDA 
	1762
	AZE I
	JMP NSPL
	SET 12
	1762		/BINS PAST EVENT
CHB2,	SET 11
	1761		/TIME/BIN
	XSK I 10
	NOP
	LDA
	10
	SAE I
	3400
	JMP .+4
	SET I 10
	3777
	JMP CHB2
	CLR
	IOB
	CLSK
	JMP .-2
	IOB
	CLSA
	ROL 10
	APO
	JMP RSP
	LDA I
	1
	LDF 0
	SXL I 0
	STA 10
	LDF 1
	SXL I 1
	STA 10
	LDF 2
	SXL I 2
	STA 10
	LDF 3
	SXL I 3
	STA 10
	LDF 4
	SXL I 4
	STA 10
	LDF 5
	SXL I 5
	STA 10
	XSK I 11
	JMP .+4
	XSK I 12
	JMP CHB2
	JMP NSPL
WAIT2,	CLR
	IOB
	CLSK
	JMP .-2
	IOB
	CLSA
	ROL 10
	APO
	JMP RSP
	LDA I
	1
	LDF 0
	SXL I 1
	ADA 10
	LDF 1
	SXL I 1
	ADA 10
	LDF 2
	SXL I 2
	ADA 10
	LDF 3
	SXL I 3
	ADA 10
	LDF 4
	SXL I 4
	ADA 10
	LDF 5
	SXL I 5
	ADA 10
	XSK I 11
	JMP WAIT2
	XSK I 12
	JMP CHB2
/SAMPLING DONE, MOVE DATA
NSPL,	CLR
	JMP EV
	SET I 7
	1765		/EPOCH FETCH
	SET I 6
	-6		/CHANNELS
	LDA I
	LDF 0
	STC DF
	LDA I 7
	SAE I
	1
	JMP .+3
	LDA I
	-0
	SAE I
	2
	JMP .+3
	LDA I
	-1000
	SAE I
	3
	JMP .+3
	LDA I
	-400
	ADA
	10
	ADA I
	-1777
	APO I
	JMP .+3
	ADA I
	-400
	ADA I
	1777
	BSE I
	2000
	STC 9
	SET I 8
	3377
DF,	LDF 0
	LDA I 9
MSCL,	SCR 0
	ADA I 8
	FLO I
	JMP DFLO
	XSK 8
	JMP .-6
	LDA I
	1
	ADM
	DF
	XSK I 6
	JMP NSPL+11
	JMP EV
/STORE DATA ON TAPE
	XSK I 13
	JMP NSTR
STR,	SET 13
	1763
	JMP NOTAPE	/TAKE OUT LATER
	SET I 6
	-5
	LDA I
	LDF 0
	STC .+1
	LDF 0
	WRI I 10
BLK,	0
	LDA I
	1
	ADM
	BLK
	LDA I
	1
	ADM
	BLK-2
	XSK I 6
	JMP BLK-2
	LDA
	BLK
	STC .+3
	LDF 5
	WRC 10
	0
	LDA I
	1
	ADM
	BLK
NOTAPE,	CLR		/TAKE OUT LATER
	JMP EV
/DISPLAY ROUTINE FOR DATA
NSTR,	CLR
	RSW
	STA
	DRSW
	ROL 3
	COM
	STC 7
	LDA I
	XSK I 7
	STC DXSK
	RSW
	BCL I
	7770
	SAE I
	7
	JMP .+5
	LDA I
	NOP
	STA
	DXSK
	SAE I
	0
	SKP
	JMP NDSP
	RSW
	BCL I
	0077
	SAE I
	0
	SKP
	JMP NDSP
	SET I 9
	-7
DSET,	SAM 0
	SET I 6
	-7
	RSW
	SAE I
DRSW,	0
	JMP NSTR
	LDA I
	SAM 0
	STC DAD
	LDA I
	ROL-1
	STC DROL
	LDA I
	LDF-1
	STC DDF
	LDA I
	SNS-1
	STC DSS
DINC,	PDP
	PMODE
	ISZ DAD
	ISZ DROL
	ISZ DSS
	ISZ DDF
	LINC
	LMODE
	XSK I 6
	SKP
	JMP DSET
	SET I 9
	3377
	RSW
DROL,	0
	APO I
	JMP DINC
DAD,	SAM 0
	STC DV
	LDA I
	-0
DSS,	SNS 0
	JMP .+3
	LDA I
	377
	STC 1
DDF,	LDF 0
	LDA I 9
	ADA I
DV,	0
	DIS I 1
	XSK 9
	JMP .-5
	KST
	SKP
	JMP DKEY
	JMP EV
DXSK,	XSK I 7
	JMP DINC
	JMP NDSP
DKEY,	SET 2
	0
	IOB
	KRB
	SAE I
	304		/D
	SKP
	JMP LOADER
	SAE I
	303		/C
	SKP
	JMP INP
	JMP 2
INP,	CLR
LOADER,	LDF 2
	LDA I
	703
	STC 2016
	LDA I
	7300
	STC 2017
	LDF 3
	LIF 2
	JMP 16
/ROUTINE TO TEST FOR SPURIOUS EVENT
EV,	SET 3
	0
	SET I 17
	TX5-1!4000
	CLR
	IOB
	CLSA
	ROL 10
	APO I
	JMP .+3
	JMP DSP
	JMP EV+2
	SXL 12
	JMP .+3
	JMP DSP
	JMP EV+2
	JMP 3
/ROUTINE TO DISPLAY OVERFLOW
DFLO,	SET 3
	0
	SET I 17
	TX6-1!4000
	JMP DSP
	JMP 3
/ROUTINE TO DISPLAY CHARACTERS
DSP,	CLR
	LDA I
	207
	IOB
	TLS		/RING BELL
	SET 2
	0
	SET I 16
	0
	LDA
	17
	STC .+2
	SET I 17
	0
	SET I 1
	300
	LDH I 17
	SAE I
	52		/*
	SKP
	JMP .-10
	ROL 1
	ADA I
	PATRN-1
	STC 15
	LDA I
	300
	DSC I 15
	DSC I 15
	LDA I
	10
	ADM
	1
	XSK I 16
	JMP .-22
	JMP 2
/TEXT FOR WORD DISPLAYS
TX4,	TEXT "ENABLE OFF*"
TX5,	TEXT "EVENT*"
TX6,	TEXT "OVERFLOW*"
/SYMBOL TABLE
	CLA=7200
	CLSK=6131
	CLLR=6132
	CLAB=6133
	CLEN=6134
	CLSA=6135
	KRB=6036
	TLS=6046
	TAD=1000
	ISZ=2000
	LINC=6141
/PATTERN WORDS FOR CHAR DISPL.
PATRN,	4522		/AT SIGN
       	1645
   	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	7700		/[
	0041
	1020		/\
	0204
	4100		/]
	0077
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6060		/"
	0
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0526
	5000		/APOSTROPHY
	60
	0000		/(
	4136
	3641		/)
	0000
	2050		/*
	50
	404		/+
	437
	0500		/,
	0006
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	4201		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?
PATEND,	2055
/END OF PATRNS TABLE
/CONSTANTS FOR TROUBLESHOOTING
	*3761
	-10		/ONE MS BINS
	-128	/SAMPLE PAST EVNT 128 BN
	-4		/AVE 4 TRLS
	0		/FIRST TBLK
	0		/SCALE DATA N
	3		/THIRD EPOCH
	3
	3
	3
	3
	3
/END OF CONSTANTS
	SEGMNT 2
	*20
	LDF 7
	LIF 6
	JMP 20