Directory of image this file is from
This file as a plain text file

*20
/THIS PROGRAM IS A DATA ACQUISITION TOOL
/TWO SENSE SWITCHES ARE USED, SN0 IS DE-
/PRESSED AFTER THE TAPE ON UNIT ONE IS 
/CHANGED TO INDICATE COMPLETION.  SN5
/IS DEPRESSED IF AVERAGES AND SPIKE HISTOGRAMS
/ARE NOT TO BE COLLECTED AND STORED
/ANALOG KNOB 0 ALLOWS ONE TO MOVE THE AVERAGE UP AND DOWN ON THE SCOPE.
/STARTING ADDRESS OF THE PROGRAM IS
/           00300 IN LINC
/AND IS STORED UNDER DATACOL.
/ALL ENTRIES ARE IN OCTAL - THIS IS NOT
/CHECKED. MINIMUM BIN TIME IS ONE MSEC
/     SYNC PULSE GOES INTO INPUT 1
/     DATA IS SAMPLED AT A/D CHANNEL 10
/     SPIKES GO TO INPUT 3
/IF N SAMPLES ARE TAKEN AND ARE TO BE
/AVERAGED, THE N SAMPLES
/ARE WRITTEN TO TAPE IN CONSECUTIVE
/BLOCKS. BLOCK N+1 RECEIVES THE AVERAGE
/BLOCK N+2 RECEIVES THE SPIKE POST STIMULUS HIST.
/THE PROGRAM SKIPS TAPE BLOCKS 270 THRU
/467 AS THAT IS THE ASSEMBLERS AREA OF TAPE WITH ITS INDEX.
/THIS PROGRAM HANDLES ONLY 256 BINS (400 OCTAL)
/THIS CONTINUES SUCCESIVELY UNTIL THE
/TAPE IS FULL OR THE COMPUTER IS STOPPED
/WHEN THE TAPE IS FULL, A "T" IS TYPED
/AND THE BELL RINGS. CHANGE TAPE AND 
/DEPRESS SN0. THE BLOCK NUMBER BEING WRITTEN IS 
/DISPLAYED IN THE UPPER LEFT OF THE SCOPE
/
/
/NOTE TO NATICK
/INDEX REGISTER "AVGPTR" AND TAPE BLOCK
/WORD POINTER "WRTBLK" SHOULD BE DECREMENTED IF YOU
/WISH TO DELETE A PARTICULAR INDIVIDUAL WAVEFORM
/I HAVENT DETERMINED HOW TO SUBTRACT THAT WAVEFORM FROM THE AVERAGE THO.
	SEGMNT 0
	*0
	0
	PMODE
	LINC
	LMODE
	JMP INT
	*20
TIME,	-1
SBINS,	-200
TPEBLK,	0
SAMN,	0
	*40
	0
INT,	NOP
	FIELD 0
	LDF 3
	PDP
	7300
	6135
	6141
	APO I
	JMP SYNC
	SAM 10		/CLOCK INT
	STA I 17
	FIELD 1
	LDF 4
FACTOR,	SCR 0
	STA I
SAVAC,	0
	QAC
	LDF 6
	LAM 17		/ADD LOW ORDER BITS
	LDF 4
	LDA
	SAVAC
	LAM 17		/ADD HI ORDER BITS
CONT,	NOP
	FIELD 0
	LDF 3
	XSK I 15
	JMP .+2
	JMP ENDBLK
	IOB
	6001		/ION
	JMP .
ENDBLK,	LDA
	WRTBLK
	ADA I
	-4265		/18 SETS OF 8 SAMPLES PLUS AVG AND INT
	AZE
	JMP BLKOK
	JMP BLKSET
BLKOK,	LDA
	WRTBLK
	BCL I
	7000
	BSE I
	1001
	STA
	14
	XSK 14
	JMP MORE
	JMP HELP
BLKSET,	LDA I
	4470		/SKIP PAST DIAL INDEX
	STA
	WRTBLK
	JMP BLKOK
MORE,	LDA I
	0060
	ESF		/IO PRESET
	NOP             /LDA
	NOP             /TEN
	NOP             /AXO  NO PAUSE ON TAPE
	STD
	JMP .-1
	WRI U		/TAPE WRITE 
WRTBLK,	0
	AVGPTR=12
	SNS 5		/OPTION NOT TO AVERAGE
	XSK I AVGPTR
	JMP CLKSET
	JMP AVG
SYNC,	ROL 12
	APO I	        /EVENT NOT 3
	JMP .+7
	FIELD 1
	LDF 5
	LDA I
	10
	ADM 17		/BUMP SPIKE COUNT
	FIELD 0
	LDF 3
	JMP ASTART-7
	SET I 17
	3777		/TABLE-1
	SET 15
BINS,	SBINS
	LDA
	WRTBLK
	ADA I
	1
	STA
	WRTBLK		/BUMP WRITE BLOCK
	LDA I
	4100		/1KC AND PRESET
	IOB
	6132		/CLLR
	IOB
	6135		/CLSA CLEAR POSSIBLE FLAG
	LDA I
	303		/CLOCK OR EVENT 3
	IOB
	6134		/SET CLOCK FOR INT
	IOB
	6001
	JMP .		/WAIT FOR CLOCK
ASTART,	LDA I
	4000
	BSE 
	TPEBLK
	STA
	WRTBLK		/INIT WRITE BLOCK
        LDA I
	60
	ESF
	NOP             /      LDA I
        NOP             /TEN,	10
	NOP             /AXO NO PAUSE
	CLR
	IOB
	6132		/CLLR STOP CLOCK
AVGSET,	NOP
	FIELD 1
	LDF 4
	SET I AVGPTR
	3777
	CLR
	STA I AVGPTR
	LDF 5
	STA AVGPTR
	LDF 4
	XSK AVGPTR
	JMP .-5
	FIELD 0
	LDF 3
	SET AVGPTR
	SAMN
	STA I
MIN,	0
CLKSET,	LDA
	TIME
	IOB
	6133		/CLAB
	CLR
	IOB
	6132		/CLLR STOP CLOCK
	LDA I
	60
	IOB
	6134		/CLEN
	IOB
	6135		/CLSA TO CLEAR CLOCK
	IOB 
	6001		/ION
	LIF 1
	JMP DISPLA
HELP,	LDA I
	324
	IOB
	6046
	IOB
	6041
	JMP .-2
	LDA I 
	207
	IOB
	6046
	SNS 0
	JMP .-1
AAHERE,	CLR
	IOB
	6046		/TLS
	JMP QAINIT
	COMNT
	ANSWER
	JMP QARFSH
	JMP QAINIT
	QEST1
	ANSWER
	JMP QARFSH	/GET TIME,BINS,TAPEBLOCK, AND N FOR AVG
	SET I 14
	ANSWER
	CLR
	STA I 
TEMP,	0
	JMP FETCH	/GET TIME
	LDA
	TEMP
	ROR 3
	COM
	ADA I
	1
	STC TIME
	STC TEMP
	LDH I 14
	JMP FETCH 	/GET BINS
	LDA 
	TEMP
	ROR 3
	COM
	STC SBINS
	STC TEMP
	LDH I 14
	JMP FETCH	/GET TAPE BLOCK
	LDA
	TEMP
	ROR 3
	STC TPEBLK
	STC TEMP
	LDH I 14
	JMP FETCH 	/GET N FOR AVG
	LDA
	TEMP
	ROR 3
	N=24
	STA
	N
	COM		/SET NEG
	STC SAMN
	JMP QAINIT
	COACH
	ANSWER
	JMP QARFSH
	JMP GETFTR	/GET DIVIDE FACTOR FOR AVERAGE
ANSWER,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
FETCH,	SET I 13
	-3
	LDH I 14
	BCL I
	7770
	ADD TEMP
	ROL 3
	STC TEMP
	XSK I 13
	SKP
	JMP 0
	DJR
	JMP FETCH+2
QEST1,	TEXT ZFTIME IN MSEC<3
FNUMBER OF BINS<3
FSTART TAPE BLOCK<3
FN FOR AVE<3\Z
COACH,  TEXT ZFDATA IS COLLECTED
FON TAPE 1
FDEPRESS LF TO START<1\Z
/
COMNT,	TEXT ZFALL ANSWERS IN OCTAL
FRESTART BY I/O PRESET
FLEFT SWITCHES TO 00300
FDEPRESS LS,  NOW-L/F<1\Z
/
/SCALE FACTOR SUBROUTINE TO SET FACTOR
/
	CNTR=11
GETFTR,	CLR
	STC CNTR
	LDA
	N
	ROR I 1
	LZE
	JMP .+3
	XSK I CNTR	/BUMP CNTR,LINK=0
	JMP .-4		/SHIFT AGAIN
	LDA
	FACTOR		/LINK=1
	BSE
	CNTR
	STA
	FACTOR
	JMP ASTART
/
/
AVG,	NOP
	FIELD 1
	LDF 4
	SET I 17
	3777		/AVGTBL-1
	CLR
	STA I
SUM,	0
	SET 14
	SBINS
	JMP WRITE
	FIELD 1
	LDF 5
	JMP WRITE
	FIELD 1
	LDF 4
	JMP RESET
WRITE,	LDA
	0
	STC RET
	LDA
	WRTBLK
	ADA I
	1
	STA
	WRTBLK
	STA
	AVGBLK
	STD
	JMP .-1
WRTAVG,	WRI U
AVGBLK,	0
	LDA I
RET,	0
	STC 0
	JMP 0
	JMP 0		/RETURN
RESET,  SET I 17
	3777		/ZERO STUFF
	CLR
	JMP .+6
	LDF 5
	STA 17
	LDF 4
	XSK 17
	JMP .-5
	STA
	MIN
	SET 15
	SAMN
	FIELD 0
	LDF 3
	JMP AVGSET
/QANDA SUBROUTINE FOR THE
/PDP-12
	NOLIST
/REMOVE *1000 BELOW IF
/INSERTING SOURCE DIRECTLY
/INTO YOUR PROGRAM SOURCE
*1000 /REMOVE,IF DESIRED
/
/TO HERE TO INITIALIZE THE ROUTINE
/
QAINIT,	LDA I		/SAVE JMP RETURN
	2
	ADD 0
	STA I
QAB,	0		/JMP 	+3
	ADD QAL+3
	STC 1		/PTR TO FIRST PARAM
	LDA 1		/GET FIRST PARAM
	ADD QAQ+1	/PTR TO HALFWORD-1
	STC QAG-3
	LDA I 1
	STC QARFSH-1
	STC 6		/XR6 USED AS A SWITCH. =0 IF NO ANSWER FIELD, =1777 IF YES
QACA,	SET 3	/XR3 TO PTR TO ANSWERS
	QARFSH-1
	SET 4		/XR4 TO PTR TO QUESTIONS
	QAG-3
			/TO HERE IF FIRST TIME THROUGH OR FOLLOWING A CR
	SET 1
	4
	JMP QAT
	NOP		/F
	LDH I 4		/H. BUMP PTR IF H OR F
QAD,	JMP QAO
	JMP .+6		/74
	JMP QAE		/34
	SAE I		/CR?
	43
	JMP QAD		/NO
	JMP QACA+4 /EXAMINE NEXT CHAR
			/INITIALIZE ANSWER BUFR
	STH 3		/74 TO ANSWERS
	LDH I 4		/NEXT HALFWORD
	ADA I
	-60
	COM
	STC 6
	STH I 3		/0 IN AC
	XSK I 6
	JMP .-2
	LDH I 3		/BUMP PTR TO ANSWERS
	JMP QAD
			/ANSWER BUFR IS INITIATED
QAE,	STH 3
	SET I 4		/XR4 TO PTR TO LAST TYPED CHAR IN ANSWER BUFR
	0
			/----RE-ENTER HERE TO REFRESH----
QARFSH,	LDA I		/INITIAL Y POSITION
277
	STC QAH-1
	SET I 3		/XR3 TO PTR TO HALFWORD QUESTIONS-1
	0
	SET 5		/XR5 TO PTR TO LAST DISPLAYED CHAR IN ANSWER BUFR
	QARFSH-1
QAG,	SET 1
	3
	JMP QAT
	JMP .+7		/F
	LDH I 3		/H. BUMP PTR
	LDA I		/NEITHER. ASSUME HALF SIZE
	BCL I
	STC QAM+2	/SET INSTR TO CLEAR FF FOR HALF SIZE
	ADD QAW		/NOP IN AC
	JMP QAM
	LDH I 3		/BUMP PTR
	LDA I
	BSE I
	STC QAM+2	/SET INSTR TO SET FF FOR FULL SIZE
	ADD QAW+1	/ADD 9U IN AC
QAM,	STC QAP+3
	MSC I 4		/EAD CONTROL REGISTER
	BSE I		/THIS INSTR CHANGES. EITHER BSE & OR BCL &
	200
	MSC 4		/AC TO CONTROL REGISTER
	SET I 1		/XR1 TO INITIAL X POSITION
	100
	LDA I		/Y COORDINATE MULTIPLE
	-40
	ADM I		/Y COORDINATE
	0
QAH,	LDH I 3
	JMP QAO+1
	JMP QAZ		/74 BUMP PTR TO NEXT CHAR, PUT 40 IN AC
	JMP QAJ		/34
	SHD I		/NEITHER
	4300
	JMP QAG		/CR. MOVE X AND Y COORDINATE
	JMP QAP		/ISPLAY CHAR
	JMP QAH		/PICK UP NEXT CHAR
	JMP QAP		/TO HERE IF DISPLAYING ANSWER BUFR
	SRO I	/SWITCH TO DISPLAY CURSOR. EITHER 0000 OR 7777
	0		/IFXR4=XR5, THEN SWITCH=7777
	JMP QAF
			/QUESTION MODE
QAI,	LDH I 5
	JMP QAO+1
	JMP QAH		/74
	JMP QAH		/34
	JMP QAI-4	/NEITHER. DISPLAY IT
QAJ,	JMP GETKBD	/TO HERE IF DISPLAYED BUFFER
	AZE I
	JMP QAB	/NOTHING TYPED . EXIT
	SET I 2
	QAY
	SHD 2		/LF?
	JMP QAK+4	/YES. EXIT
	SHD I 2		/CR?
	JMP QAN
	XSK 6		/IS THERE AN ANSWER FIELD?
	JMP QARFSH
	SHD I 2		/<?
	JMP QAL
	SHD I 2		/>?
	JMP QAK
	SHD I 2		/ALT?
	JMP QACA /REINITIALIZE
	SHD I 2		/BACK SLASH?
	JMP QARFSH	/IGNORE
	SHD I 2		/RUBOUT?
	JMP QAL		/IGNORE
	SHD I 2		/TAB?
	JMP QARFSH	/IGNORE
	STC .+5		/ACCEPTABLE CHAR
	JMP QAO		/TEST NEXT CHAR
	JMP QAQ		/74 BACK PTR UP BY 1
	JMP QAQ		/34 ^
	LDA I		/OK. STORE IT
	0
	STH 4
	JMP QARFSH	/REDISPLAY
QAL,	LDH 4		/TO HERE IF RUBBOUT OR <
	JMP QAO+1
	JMP QARFSH	/74 IGNORE
	-6002
	LDH 2		/TEST THE CHAR
	SAE I		/RUBOUT?
	37
	JMP QAQ		/NO. BACK PTR UP BY 1
	SET 5
	4
	SET 3
	4
	JMP .+2
	LDH I 5		/BUMP PTR
	LDH I 3		/GET NEXT CHAR
	JMP QAO+1
	NOP		/IF 74 OR 34, REPLACE CURRENT CHAR WITH 0
	CLR
	STH 5
	AZE		/WAS IT 74 OR 34?
	JMP .-7		/NO. CONTINUE
	JMP QAQ		/BACK PTR UP BY 1
			/TO HERE IF CR
QAN,	XSK 6	
	JMP QAK+4	/EXIT ROUTINE IF NO ANSWER FIELD
	JMP QAO
	JMP QARFSH	/74 MOVE PTR TO NEXT QUESTION FIELD
	JMP QAE+1	/34 END OF BUFR. MOVE PTR TO FIRST QUESTION FIELD
	JMP QAN+2
	
QAO,	LDH I 4		/S\R
	SHD I		/	+1 74 BEGIN FIELD
	7400		/	+2 34 END BUFR
	JMP 0		/	+3 NEITHER 74 NOR 34
	SAE I
	34
	XSK I 0
	XSK I 0
	JMP 0
			/S\R TO DISP LINC CHAR IN AC
QAP,	ROL 1		/MULT BY 2 FOR INDEX TO ADDRESS OF TABLE
	ADD QAX+4
	STC 2		/ADDRESS OF CHAR TO DISP IN XR2
	ADD QAU		/THIS INSTR CHANGES. EITHER OP OR ADD 9U
	ADD QAU
	ADD 1		/ADD 4 TO XR1 TO SPACE CHAR
	STC 1
	ADD 5		/GET ADDRESS OF ANSWER BUFR
	COM
	ADD 4
	AZE
	CLR
	STC QAI-2	/SWITCH=0 OR 7777
	ADD QAH-1	/Y COORDINATE IN AC
	DSC 2
	DSC I 2		/DISPLAY CHAR
	JMP 0
QAQ,	LDA I		/BACK UP PTR BY 1
	-4000
	ADM
	4
	JMP QARFSH	/REDISPLAY
			/
QAT,	LDH I 1		/S\R
	SHD I		/	+1 F
	0600		/	+2 H
	JMP 0		/	+3 NEITHER
	SAE I
	10
	XSK I 0
	XSK I 0
	JMP 0
			/
QAZ,	LDH I 3
	LDA I
	40
	JMP QAI-4
			/TO HERE IF >
QAK,	LDH I 4
	AZE I		/IS CURRENT CHAR BLANK?
	JMP QAQ		/YES. IGNORE
	JMP QAX		/MOVE DOT FORWARD
			/TO HERE TO EXIT WITH SKIP
	LDA I
	1
	ADM
	QAB
	JMP QAB
			/CHARACTER PATTERNS
QAV,	0101		/KBD 0, ILLEGAL. USED AS MARKER
	0101
	4477		/1:A
	7744
	5177		/2:B
	2651
	4136		/3:C
	2241
	4177		/4:D
	3641
	4577		/5:E
	4145
	4477		/6:F
	4044
	4136		/7:G
	2645
	1077		/10:H
	7710
	7741		/11:I
	0041
	4142		/12:J
	4076
	1077		/13:K
	4324
	0177		/14:L
	0301
	3077		/15:M
	7730	
	3077		/16:N
	7706	
	4177		/17:O
	7741
	4477		/20:P
	3044
	4276		/21:Q
	0376
	4477		/22:R
	3146
	5121		/23:S
	4651
	4040		/24:T
	4077
	0177		/25:U
	7701	
	0176		/26:V
	7402
	0677		/27:W
	7701
	1463		/30:X
	6314
	0770		/31:Y
	7007
	4543		/32:Z
	6151
	4177		/33:/
	0000
			/34:BACKSLASH IGNORED ON INPUT
	0		/NOT USED
	0		/NOT USED
	0000		/35:]
	7741
			/CODES 36:ALT, 37:RUBOUT NOT DISPLAYED
QAY,	4543		/LF,CR
	7476		/<,>
	3634		/ALT, BACKSLASH
	3747		/RUBOUT, TAB
	0000		/40:SPACE
	0000
	7500		/41:X!
	0000
	7000		/42:"
	0070
			/CODES 43:, 44:, 45:LF NOT DISPLAYED
QAX,	JMP QAO+1
	JMP QAQ
	JMP QAQ
	JMP QARFSH
	QAV
	0		/NOT USED
	5166		/46: &
	0526
			/CODE 47:TAB NOT DISPLAYED
	0		/NOT USED
	0		/NOT USED
	3600		/50:(
	0041
	4100		/51:)
	0036
	2050		/52:*
	0050
	0404		/53:+
	0437
	0500		/54:,
	0006
	0404		/55:-
	0404
	0001		/56:.
	0000
	0601		/57:\
	4030
	4536	/60:0
	3651
	2101		/61:1
	0177
	4523		/62:2
	2151
	4122		/63:3
	2651
	2414		/64:4
	0477
	5172		/65:5
	0651
	1506		/66:6
	4225
	4443		/67:7
	6050
	5126	/70:8
	2651
	5122		/71:9
	3651
	2200		/72::
	0000
	4601		/73:;
	0000
			/CODE 74:<NOT DISPLAYED
QAU,	2		/CONSTANT
	0	/NOT USED
	1212		/75:=
	1212
			/CODE 76:> NOT DISPLAYED
QAW,	NOP
	ADD QAU
	4020		/77:?
	2055
/
QAF,	DSC I
	6000
	JMP QAI
/
			/END Q+A
/
/
/
/
/KEYBOARD INPUT ROUTINE
/
QAKRB=6036	/PDP-8 IOT KBD
QATSF=6041	/TSF
QATLS=6046	/TLS
/
GETKBD,	LDA
	0
	STC QAEXIT+6	/SAVE RETURN
	ADD 1		/SAVE XRS 1 AND 2
	STC QAEXIT+3
	ADD 2
	STC QAEXIT+5
	STC QAEXIT+1
	KST	/WAS SOMETHING TYPED?
	JMP 0		/NO: EXIT
	IOB
	QAKRB	/GET TTY CHAR, CLEAR FLAG
	STA I		/SAVE IT
QATY,	0
	ADA I
	-237
	APO		/BETWEEN 200 AND 237?
	JMP QACNTR	/CONTROL CHAR. CHECK FOR CR,LF,TAB
/
	SET I 1		/NO
	QACHAR-1
	SET I 2
	-7
	LDA
	QATY
	SAE I 1
	JMP .+2
	JMP QAEXIT	/ILLEGAL CHAR. DONT ECHO
	XSK I 2	/CHECKED THEM ALL?
	JMP .-4
/
	ADA I
	-337
	APO		/BETWEEN 240 AND 337?
	JMP QALEGL	/YES. LEGAL CHAR
/
	SAE I 1		/NO. CHECK FURTHER.
	JMP .+7
	LDA I		/RUBOUT
	334
	JMP QATPE	/ECHO BACKSLASH
	LDA I
	37
	JMP QAEXIT+2	/LEGAL EXIT
/
	SAE I 1
	JMP QAEXIT	/ILLEGAL
			/ALT
	JMP QAEXIT+2	/EXIT, DONT ECHO
/
QALEGL,	LDA
	QATY
	JMP QATPE	/ECHO CHAR
	ADD QATY
	BCL I		/STRIP IT TO 6-BIT
	7700
	JMP QAEXIT+2
/TO HERE IF CONTROL CHAR
QACNTR,	SAE I
	7755
	JMP QACKLF
	LDA I		/CR
	43
	STC QAEXIT+1
	LDA I
	215
	JMP QATPE
	LDA I
	212
	JMP QATPE
	JMP QAEXIT
/
QACKLF,	SAE I
	7752
	JMP .+4
	LDA I		/LF
	45
	JMP QACNTR+5
	SAE I
	7751
	JMP QAEXIT	/ILLEGAL
	LDA I
	47
	JMP QAEXIT+2	/EXIT, DONT ECHO
/
QAEXIT,	LDA I	/GET 6-BIT ASCII
	0
	SET I 1		/RESTORE XRS
	0
	SET I 2
	0
	JMP		/EXIR S\R GETKBD
/S\R TO PRINT C(AC)
QATPE,	IOB
	QATLS	/PDP-8 IOT TLS
	LDA
	0
	STC .+4	/SAVE RETURN
	IOB
	QATSF	/WAIT FOR FLAG
	JMP .-2
	JMP 	/EXIT
/
QACHAR,	243	/HASH
	244	/DOLLAR SIGN
	245	/PER CENT
	247	/APOSTROPHE
	300	/AT SIGN
	336	/UP ARROW
	337	/BACK ARROW
	40	/RUBOUT
QAEND,  36	/ALT
/END OF S\R GETKBD
	LIST
	SEGMNT 1
	*20
DISPLA,	CLR
	LDF 0
	LDA 
	SBINS!2000
	STA I
DBINS,	0
	SET I 17
	WRTABL-1
	SET I 16
	-3
	LDA
	WRTBLK!2000
	ROL 3
	STC TEMWRT
UNPACK,	LDA I
TEMWRT,	0
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA 
	3
	LDA 3		/GET HALF CHAR
	STA I 17
	LDA I 3		/GET OTHER HALF
	STA I 17
	XSK I 16
	JMP UNPACK
DISGO,	SET I 17
	WRTABL-1
	SET I 1
	10
	SET I 16
	-6
	SET 3
	DBINS            / SBINS
	LDF 4
	SET I 2
	3777
	LDA I
	300
	DSC I 17	/DIS BLOCK NUMBER
	XSK I 16
	JMP .-3
DISLOP,	LDA I 2
	DIS 2
	LDF 5
	SAM 0
	ADA 2		/MOVEABLE DIS
	DIS 2
	LDF 4
	XSK I 3
	JMP DISLOP
	JMP DISGO
PATERN,	4136
	3641
	2101
	0177
	4523
	2151
	4122
	2651
	2414
	0477
	5172
	0651
	1506
	4225
	4443
	6050
	5126
	2651
	5120
WRTABL,	0
	SEGMNT 4
	*2000
AVGTBL,	0
	SEGMNT 3
	*2000
TABLE,	0