Directory of image this file is from
This file as a plain text file

[DECFPD
[DECIMAL TO FLOATING
[POINT CONVERSION
[DOUBLE PRECISION
[USES FLOD 1A,1M,1D,1J,1I,1X,1R,1N,1Q,1H
[JMP 1P
[ADDR INPUT STRING,I,E,F FORMAT,ENDS IN 77
[ADDR FP OUTPUT
[XR 1,2,3,4
[JAN 7|14|69
#1P CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC 3Z+2
ADD 2
ADAi
-4000
STC 4 [INPUT STRING
ADD 3
STC 3Z [OUTPUT ADDR
STC 2T+1 [NO E YET
#2P STC 3F [NO . YET
STC 2A+24 [E+
STC 2N   [INITIAL 0
STC 2N+1
STC 2N+2
#2A LDH i4  [INPUT NEXT CHAR
SHD i  [-
1700
JMP 2Y
SHD i  [+,SIGNS SET
2000
JMP 2A
SHD i  [.
6400
JMP 2R
SHD i  [END OF #
7700
JMP 2T
SHD i [BLANK
1400
JMP 2A
SAE i  [E
0030
JMP 2F [DIGIT
LDA i
EXP SIGN [2A+24
STC 2T+7 [MOVE SIGN
COM [SET FLAG
STC 2T+1
SET i1
2N  [MOVE OUT MAN
SET i 2
2M
JMP 2S
CLR
JMP 2P
#2R CLR [DEC PLACE ENCOUNTERED
COM 
STC 3F
SET i1
2C [MOVE 10 TO 2Q
SET i2
2Q
JMP 2S
JMP 2A
[MOVE ROUTINE
#2S LDA 1
STA 2
LDA i1
STA i2
LDA i1
STA i2
JMP 0
[NEGATIVE SIGN
#2Y CLR
COM
STC 2A+24
JMP 2A
[DIGIT,EVALUATE #
#2F STC 2L+1
STC 2L
[FLOAT DIGIT
JMP 1I
2L
2L
SROi
#3F DEC PT FLAG
JMP 2G [-0,YES
[MUL BY 10, +0 N0
JMP 1M
2N
2C
2N
[ADD NEW DIGIT
JMP 1A
2N
2L
2N
JMP 2A
[AFTER DEC PT,DIV BY POWERS OF 10
#2G JMP 1D
2L
2Q
2L
[INCREAS POWER OF 10
JMP 1M
2Q
2C
2Q
JMP 2G-5
[WRAP UP
#2T SROi
E FLAG
JMP 2U [-0,E
LDA  [+0,NO E
2A+24
STC p+2
SRO i
SIGN MAN
JMP p+2 [-
JMP p+10 [+
LDA
2N+1
COM 
STC 2N+1
ADD 2N+2
COM
STC 2N+2
SET i1
2N [MOVE RESULT TO OUTPUT AREA
SET i2
#3Z 0
JMP 2S
JMP RETURN
[FIX EXPONENT
#2U JMP 1J
2N
2L
LDA 
2L
AZE i
APO 
HLT [EXPONENT OVER OR UNDER FLOW
[10 TO THE |EXP|
#4H CLR
SET i1
2C [MOVE 10 TO 2N
SET i 2
2N
JMP 2S
SET i1
2C+3 [MOVE 1 TO 2Q
SET i 2
2Q
JMP 2S
#4I CLR
ADD 2L+1 [FIXED PT EXP
AZE i
JMP 4M
SCR i 1
STC 2L+1
LZE i
JMP p+5
JMP 1M
2Q
2N
2Q
JMP 1M
2N
2N
2N
JMP 4I
#4M ADD 2A+24  [EXP SIGN
APO i
JMP p+5
JMP 1D
2C+3
2Q
2Q
[10 TO EXP * |MAN|
JMP 1M
2Q
2M
2N
JMP 2T+6
#2L 0
0
0
#2C 4 [CONSTANT 10
2400
0000
1 [CONSTANT 1
2000
0
#2M 0
0
0
#2N 0
0
0
#2Q 0
0
0
[END DECFPD