Directory of image this file is from
This file as a plain text file

*20
	SEGMNT 0
	NOLIST
/DIFCON52
/
/SYNC INTO INPUT 1 AND IS PRECS PULSE
/CS IS DELIVERED 200 TIME PERIODS LATER
/BY CLOSURE OF K0
/US IS DELIVERED 400 TIME PERIODS AFTER
/SYNC (PRECS PULSE)
/CS AND US TERMINATE TOGETHER 50 TIME PERIODS
/AFTER ONSET OF US
/
/K5 IS SET DURING THE ODD AVERAGES
/
/FIVE ELECTRODES ARE SUPPORTED WITH TWO 
/AMPLITUDES OF DISCRIMINATIONS
/
/EXTERNAL SENSE LINES ARE USED INPUT DATA
/EXT SENSE LINE 13 BEING GROUNDED ALLOWS
/DATA TO BE COLLECTED IN LDF4 -7
/IF ITS HIGH, DATA IS NOT COLLECTED
/0 & 1  E 1
/2 & 3 E2
/4 & 5 E3
/6 & 7 E4
/10 &11 E5
/RPD INTO A/D10
/14 PRECS CS SKIP
/11 PRECS TIMER
/13 CS US TIMER
/1 IS COMMITTED TO PDP INT
/USES A FIXED TIME OF 10MSEC/BIN
/  SET AT TIMSET - ADDRESS 2330
/ MSEC IN OCTAL -1 IS CORRECT SETTING
/ FIXED BIN SIZE OF 256 BINS(10)
	LIM=10
	AVGPTR=12
	TIME=20
	SBINS=21
	TPEBLK=22
	SAMN=23
	N=24
	WRTBLK=25
	INTAC=26
	LIST
	*1
	PMODE
	JMP INT+2
	LMODE
	*41
	JMP INT
	*170
INT,	NOP
	PDP
	3026		/DCA INTAC
	7300
	6135
	6141
	APO I
	JMP SYNC
	CLR
	LDA I
	4100
	SAE I
CS,	0
	JMP US
	FIELD 1
        LDF 4
	SAM 10		/RPD
	STA I 4
FACTOR,	0
	STA I
SAVAC,	0
	QAC
	LAM I 5
	LDA
	SAVAC
	LAM I 6
CONT,	SET 2
	DWELL
	XSK I 7
	XSK I 15	/END OF RUNTIME
	JMP .+2
	JMP ENDBLK
	IOB 
        6001
	XSK I 11
	JMP SMPL
	CLR
	STC INST
	RTA
	BSE I
        0040
	ATR		/KEEP K6 SET,SET K0
	SET I 14
	1777		/SHOW CS TIME
	LDF 5
	LDA
	ONE
	ADM 6
	LDA
	ONE
	ADM 7
SMPL,  SXL 12		/IF 12 HIGH GET DATA
	JMP .		/WAIT FOR CLOCK
S1,	SXL 0
	JMP E1
	SAM 7 		/KILL 18 USEC
ROT1,	ROL 12		/AND 4 MORE
S2,	SXL 2
	JMP E2
	SAM 7
ROT2,	ROL 12
S3,	SXL 4
	JMP E3
	SAM 7
ROT3,	ROL 12
S4,	SXL 6
	JMP E4
	SAM 7
ROT4,	ROL 12
S5,	SXL 10
	JMP E5
	SAM 7
ROT5,	ROL 12
	LDA
	ONE
	SXL 13
	STC INST
	XSK I 2		/END OF SAMPLING?
	JMP S1
	JMP .		/YES, WAIT FOR CLOCK TICK
/
ONE,	1
/
E1,	SXL 1
	JMP LG1
	LDA
	ONE
	LDF 7
	ADM 4
	JMP S2
LG1,	LDA
	ONE
	LDF 7
	ADM 5
	JMP S2
/
E2,     SXL 3
	JMP LG2
	LDA
	ONE
	LDF 7
	ADM 6
	JMP S3
LG2,	LDA
	ONE
	LDF 7
	ADM 7
	JMP S3
/
E3,	SXL 5
	JMP LG3
	LDA
	ONE
	LDF 6
	ADM 4
	JMP S4
LG3,	LDA
	ONE
	LDF 6
	ADM 5
	JMP S4
/
E4,	SXL 7
	JMP LG4
	LDA
	ONE
	LDF 6
	ADM 6
	JMP S5
LG4,	LDA
	ONE
	LDF 6
	ADM 7
	JMP S5
/
E5,	SXL 11
	JMP LG5
	LDA
	ONE
	LDF 5
	ADM 4
	JMP ROT5+1
LG5,	LDA
	ONE
	LDF 5
	ADM 5
	JMP ROT5+1
/
ENDBLK,	SET I 1
	5173
MORE,	LDA I
	0060
	STA
	CS
	LDA I 
INST,	0		/IF =1 RESPONSE BIG,DONT SHOCK
	AZE
	JMP .+5
	RTA
	BSE I
	0060		/KEEP K6 AND K0,SET K1
	ATR
	SET I 13
	-63		/END OF CS TIME SET US (K1) AND CS(K0) FOR 50 BINS
US,	XSK I 13
	JMP ASTART-3	/KEEP RELAYS SET
	RTA
	BCL I
	0060
	ATR		/CLEAR K0 AND K1
TRT,    XSK I AVGPTR
	JMP CLKSET
	JMP AVG
/
SYNC,	ROL 10
        APO I
        JMP TRY3
POINT,  IOB
	6234		/RIB
	ROL 2
	BCL I
	7770
	BSE I
	LDF 0
	STC RESTDF
	LDA
	ONE
	LDF 4
	ADM 7
RESTDF,	0		/RESTORE DF WHERE INTERRUPTED
	LDA
	40
	ADA I
	6000
	STC .+4
	ADD INTAC
	IOB 
	6001
	0		/BACK TO INTERUPPTED POINT
TRY3,	ROL 2
	APO 
	JMP POINT	/EVENT 3 IS US
        SET I 17
TABLE,	3777
	SET 15
BINS,	SBINS
	SET 4
	TABLE
	SET I 5
DELBIN,	2377
	SET I 6
DLBIN2,	2777
	SET I 7
DLBIN3,	3377
	SET I 11
	-200		/PRECS TIMER
	SET I 14
	1		/SHOW CS
	SET I 2
DWELL,	-113		/-75 FOR SAMPLE PERIODS OF SXL
	CLR
	STC INST	/SET INSTRUMENTAL POINTER
	LDA
	WRTBLK
	ADA I 
	1
	STA
	WRTBLK
	LDA
	TIME
	IOB
	6133		/PRESET TIMER
	LDA I
	4100		/1KC AND PRESET
	STA
	CS		/SHOW SYNC
	IOB
	6132		/CLLR
	IOB
	6135		/CLSA POSSIBLE FLAG
	LDA I
	317		/ENABLE CLOCK
	IOB
	6134		/SET CLOCK INT
	IOB
	6001
	JMP .		/WAIT FOR CLOCK
ASTART,	LDA I  
        4000
	BSE 
	TPEBLK
	STA 
	WRTBLK		/INITIALIZE WRTBLK
	STA
	AVGBLK
	CLR
	ATR		/CLEAR RELAYS
	LDA I
	60
	ESF		/IO PRESET
	CLR
	IOB
	6132		/CLLR TO STOP CLOCK
AVGSET, SET I AVGPTR
	3777
	LDF 3
	CLR
	STA I AVGPTR
	LDF 4
	STA AVGPTR
	LDF 5
	STA AVGPTR
	LDF 6
	STA AVGPTR
	LDF 7
	STA AVGPTR
	XSK AVGPTR
	JMP AVGSET+2
	SET I AVGPTR
	-400
	SET I 13
	2177
	CLR
	LDF 2
	STA I 13
	XSK I AVGPTR
	JMP .-2
	CLR
	SET AVGPTR
	SAMN		/N FOR AVERAGE
	RTA
	BCO I
	0001
	ATR		/FLIP K6
CLKSET,	LDA
	TIME
	IOB
	6133		/CLAB, PRESET NUMBER
	CLR
	IOB
	6132      /CLLR TO STOP CLOCK
	LDA I
	60
	IOB
	6134		/CLEN 
	IOB
	6135		/CLSA TO CLEAR CLOCK
	IOB
	6001
	LIF 1
	JMP DISPLA	/WAIT FOR SYNC ---
/CUT IN HERE FOR TTY SERVICE BEFORE IOB AND 6001
/
/
AVG,	STD
	JMP .-1
	LDA I 
	60
	ESF
	SET I 17
	3777
	CLR
	SET 14
	SBINS
	SNS I 0
	JMP RESET	/SUPPRESS TAPE
	FIELD 1
	LDF 7
	JMP WRTSET
	LDF 6
	JMP WRTSET
	LDF 5
	JMP WRTSET
	LDF 4
	JMP WRTSET
	JMP RESET
/
WRTSET,	LDA
	0
	STC WRET
	SET I 17
	4000
	JMP SET1
	JMP WRITE
	SET I 17
	5000
	JMP SET1
	JMP WRITE
	SET I 17
	6000
	JMP SET1
	JMP WRITE
	SET I 17
	7000
	JMP SET1
	JMP WRITE
	LDA I
WRET,	0
	STC 0
	JMP 0
/
SET1,	LDA
	0
	STC RET4
	LDA
	AVGBLK
	BCL I
	7000
	BSE
	17
	STC AVGBLK
	LDA I
RET4,	0
	STC 0
	JMP 0
/
WRITE,	LDA 
	0
	STC RET
	LDA
	AVGBLK
	ADA I
	1
	STA
	AVGBLK
	STD
	JMP .-1
	WRI U
AVGBLK,	0
	LDA I
RET,	0
	STC 0
	JMP 0
/
RESET,	SET I 17
	3777
	SET 15
	SAMN
	LDA I 
	60
	ESF		/IO PRESET TO STOP TAPE
	JMP AVGSET
/
/
/DISPLAY PROGRAM FOR DATA COLLECTION
/
	SEGMNT 1
	*20
DISPLA,	CLR
	LDF 0
	JMP .+1		/ENABLE INTERUPT
	LDA
	SBINS!2000
	STA I
DBINS,	0
	SET I 17
	WRTABL-1
	SET I 16
	-3		/DISPLAY TRIAL NUMBER
	LDA
	WRTBLK!2000
	ROL 3
	STC TEMWRT
UNPACK,	LDA I
TEMWRT,	0
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17	/GET HALF CHAR
	LDA I 3		/GET OTHER HALF
	STA I 17
	XSK I 16
	JMP UNPACK
DISGO,	SET I 17
	WRTABL-1
	SET I 1
	10
	SET I 16
	-6
	SET 3
	DBINS
	LDA I 
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS TRIAL NUMBER
	LDF 0
	SET I 17
	BLKTBL-1
	SET I 16
	-3		/DIS BLOCK NUMBER
	LDA
	AVGBLK!2000
	ROL 3
	STC TEMWRT
BKPACK,	LDA 
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA 
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP BKPACK
DISBK,	SET I 17
	BLKTBL-1
	SET I 1
	600
	SET I 16
	-6
	SET 3
	DBINS
	LDA I
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS BLOCK NUMB
	CLR
	RSW
	BCL I
	7770
	BSE I 
	0640
	STA
	IELD
IELD,	0	/SET DF SELECTED BY RITE SWTCHS
	SNS I 1		/SMALLEST
	JMP .+5
	SET I 2
K3777,	3777
	SAM 1
	JMP DISLOP
	SET I 2
KBMP2,	2377
	SNS I 2
	JMP .+3
	SAM 2
	JMP DISLOP
	SET I 2
KBMP3,	2777
	SNS I 3
	JMP .+3
	SAM 3
	JMP DISLOP
	SET I 2
KBMP4,	3377
	SNS I 4
	JMP .+3
	SAM 4
	JMP DISLOP
	JMP DISGO
/
/
/DISPLAY SUBROUTINE
DISLOP,	STA I
DTEM,	0
	LDA
	0
	STC DRET
	SET 3
	DBINS
	XSK I 2
	LDA
	DTEM
	ADA 2
	DIS 2
	XSK I 3
	JMP .-6
	LDA I
DRET,	0
	STC 0
	JMP 0
/
/
PATERN,	4136
	3641
	2101
	0177
	4523
	2151
	4122
	2651
	2414
	0477
	5172
	0651
	1506
	4225
	4443
	6050
	5126
	2651
	5120
WRTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	00
	0
	0
	0
	0
	LIST
	0
	0
	0
	0
BLKTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
AAHERE,	CLR		/STARTING POINT FOR PROGRAM
	IOB
	6046
	LDF 0
	JMP QAINIT
	COMNT
	ANSWER
	JMP QARFSH
	JMP QAINIT
	QEST1
	ANSWER
	JMP QARFSH	/GET TAPEBLOCK AND N FOR AVG
	LDA I
TIMSET,	-11
	STA 
	TIME!2000	/SET TIME TO 10 MSEC PER BIN
	LDA I
	-400
	STA
	SBINS!2000	/SET BINS TO 256
	SET I 14
	ANSWER
	CLR
	STA I
TEMP,	0
	JMP FETCH
	JMP RTEMP	/GET TAPEBLOCK
	COM
	STA
	TPEBLK!2000
	CLR
	STC TEMP
	LDH I 14
	JMP FETCH	/GET N FOR AVG
	JMP RTEMP
	STA
	SAMN!2000
	COM
	STA
	N!2000
	CLR
	JMP QAINIT
	COACH
	ANSWER
	JMP QARFSH
PATCH,	JMP GETFTR
ANSWER,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
FETCH,	SET I 13
	-3
	LDH I 14
	BCL I
	7770
	ADD TEMP
	ROL 3
	STC TEMP
	XSK I 13
	SKP
	JMP 0
	DJR
	JMP FETCH+2
QEST1,	TEXT ZFSTART TAPE BLOCK<3
FN FOR AVG<3\Z
COACH,	TEXT ZFDATA ARE COLLECTED
FON TAPE 1
FLEFT SWITCHES 
FMUST BE 0001
FDEPRESS LF TO START<1\Z
COMNT,  TEXT ZFALL ANSWERS IN OCTAL
FRESTART BY I/O PRESET
FAND SETTING THE
FLEFT SWITCHES TO 2313
FDEPRESS LS, NOW - L/F<1\Z
/
/
/SCALE FACTOR SUBROUTINE TO SET FACTOR
	CNTR=11
GETFTR,	CLR
	STC CNTR
	LDA
	N!2000
	ROR I 1
	LZE 
	JMP .+3
	XSK I CNTR	/BMP CNTR, LINK=0
	JMP .-4
	LDA I
	SCR 0
	BSE
	CNTR
	STA
	FACTOR!2000
	LDF 3
	LIF 2
AATCH,	JMP HEADER
/
RTEMP,	LDA
	TEMP
	ROR 3
	COM
	JMP 0
	SEGMNT 2
	*1200
/
/TYPE OUT ROUTINE
/
TYPER,	CLR
	IOB
	6046		/TLS
	JMP CRLF
	LDF 2
	SET I 1
TSTRT,	2177
	SET I 2
	2477		/PRE AND PRE-CS TABLE
	SET I 3
	-50		/NUMBER OF DIFFERENCES
	SET I 4
	2203
	SET I 5
	-4
	JMP DIFF	/ELEC 1
	SET I 1
	2207
	SET I 4
	2213
	JMP DIFF	/ELEC 2
	SET I 1
	2217
	SET I 4
	2223
	
        JMP DIFF	/ELEC 3
	SET I 1
	2227
	SET I 4
	2233
	JMP DIFF	/ELEC 4
	SET I 1
        2237
	SET I 4
	2243		/ELEC 5
	JMP DIFF
TBSET,	SET I 1
        2477		/START OF P,P-C TABLE
	SET I 5		/NUM OF LINES
	-5
WDSET,	SET I 2
	-10		/NUM OF WORDS/LINE
CHRSET,	SET I 3
	-5		/NUM OF CHARS B4 3 BLANKS
	LDA I 1
	JMP MINUS	/TEST +-
	JMP PRINT	
	XSK I 2
	JMP CHRSET
	JMP CRLF
	XSK I 5		/END OF LINES
	JMP WDSET	/NO
	JMP CRLF
	SET I 1
	2177
	SET I 2
	-400
	CLR
	STA I 1
	XSK I 2
	JMP .-2
	LIF 0
	SET I 1
	5173
	JMP TRT		/
/
/
DIFF,	LDA I 1
	STA I 2		/MOVE PRECS
	COM
	ADA I 4		/CS-PRECS
	STA I 2		/INTERLACE
	DJR
	XSK I 5
	JMP DIFF
	SET I 5
	-4
	JMP 0
/
/ 
CRLF,	LDA 
	0
	STC RET9
	LDA I
	215
	JMP TYPEIT
	LDA I
	212
	JMP TYPEIT
	SET I 17
	0000
	XSK I 17
	JMP .-1
	LDA I
RET9,	0
	STC 0
	JMP 0
/
PRINT,	LDA 
	0
	STC RET6
	CLR
	LDA
	MINUS+1
	ROL 3
	STA
	MINUS+1
	BCL I
	7770
	ADA I
	260
	JMP TYPEIT
	XSK I 3
	JMP PRINT+3
	SET I 4
	-3
BLANK,	LDA I 
	240
	JMP TYPEIT
	XSK I 4
	JMP BLANK
	LDA I
RET6,	0
	STC 0
	JMP 0
/
TYPEIT,	STA I
	0
	LDA
	0
	STC RET8
	LDA
	TYPEIT+1
	NOLIST
	IOB
	6041
	JMP .-2
	IOB 
        6046
	LDA I
RET8,	0
	STC 0
	JMP 0
/
/
MINUS,	STA I
	0
	LDA
	0   
        STC RET10
	LDA
	MINUS+1
	APO I
	JMP T100+4
	COM
	STA
	MINUS+1
	LDA I
	255		/NUMBER WAS NEGATIVE
	JMP TYPEIT
T100,	XSK I 3
	JMP TOUT
	JMP CRLF
	JMP TOUT
	LDA I
	240
	JMP T100-1	/NUMBER WAS PLUS TYPE A SPACE
TOUT,	LDA I
RET10,	0
	STC 0
EOP,	JMP 0
/
HEADER,	CLR
	SNS I 5		/SUPPRESS HEADER
	JMP START
	IOB
	6046
	JMP CRLF
	JMP SPACE
	JMP SPACE
	JMP SPACE
	SET I 1
	PTAB-1
	SET I 2
	-7
	LDA I 1
	JMP TYPEIT
	XSK I 2
	JMP .-3
	SET I 2
	-21
	JMP SPACE
	XSK I 2
	JMP .-2
	SET I 2
	-5
	LDA I 1
	JMP TYPEIT
	XSK I 2		/UNITS
	JMP .-3
	SET I 2
	-21
	JMP SPACE
	XSK I 2
	JMP .-2
	SET I 2
	-10
	LDA I 1
	JMP TYPEIT
	XSK I 2
	JMP .-3
	JMP CRLF
	JMP CRLF
	SET I 2
	-4
	SET I 3
	-20
	SET I 1
	CRTAB-1
	LDA I 1
	JMP TYPEIT
	XSK I 3		/
	JMP .-3
	XSK I 2
	JMP .-11
	JMP CRLF
	JMP CRLF
START,  LIF 0
	JMP ASTART
/
/
CRTAB,	320
	322
	305
	303
	323
	240
	240
	303
	323
	255
	320
	322
	305
	240
	240
	240
/
SPACE,	LDA
	0
	STC SPRET
	LDA I
	240
	JMP TYPEIT
	LDA I
SPRET,	0
	STC 0
	JMP 0
/
PTAB,	314
	301
	322
	307
	305
	323
	324		/LARGEST
	325
	316
	311
	324
	323		/UNITS
	323
	315
	301
	314
	314
	305
	323
	324		/SMALLEST
/END OF TYPEING
	NOLIST
	SEGMNT 1
/QANDA SUBROUTINE FOR THE
/PDP-12
/REMOVE *1000 BELOW IF
/INSERTING SOURCE DIRECTLY
/INTO YOUR PROGRAM SOURCE
 *1000/REMOVE,IF DESIRED
/
/TO HERE TO INITIALIZE THE ROUTINE
/
QAINIT,	LDA I		/SAVE JMP RETURN
	2
	ADD 0
	STA I
QAB,	0		/JMP 	+3
	ADD QAL+3
	STC 1		/PTR TO FIRST PARAM
	LDA 1		/GET FIRST PARAM
	ADD QAQ+1	/PTR TO HALFWORD-1
	STC QAG-3
	LDA I 1
	STC QARFSH-1
	STC 6		/XR6 USED AS A SWITCH. =0 IF NO ANSWER FIELD, =1777 IF YES
QACA,	SET 3	/XR3 TO PTR TO ANSWERS
	QARFSH-1
	SET 4		/XR4 TO PTR TO QUESTIONS
	QAG-3
			/TO HERE IF FIRST TIME THROUGH OR FOLLOWING A CR
	SET 1
	4
	JMP QAT
	NOP		/F
	LDH I 4		/H. BUMP PTR IF H OR F
QAD,	JMP QAO
	JMP .+6		/74
	JMP QAE		/34
	SAE I		/CR?
	43
	JMP QAD		/NO
	JMP QACA+4 /EXAMINE NEXT CHAR
			/INITIALIZE ANSWER BUFR
	STH 3		/74 TO ANSWERS
	LDH I 4		/NEXT HALFWORD
	ADA I
	-60
	COM
	STC 6
	STH I 3		/0 IN AC
	XSK I 6
	JMP .-2
	LDH I 3		/BUMP PTR TO ANSWERS
	JMP QAD
			/ANSWER BUFR IS INITIATED
QAE,	STH 3
	SET I 4		/XR4 TO PTR TO LAST TYPED CHAR IN ANSWER BUFR
	0
			/----RE-ENTER HERE TO REFRESH----
QARFSH,	LDA I		/INITIAL Y POSITION
277
	STC QAH-1
	SET I 3		/XR3 TO PTR TO HALFWORD QUESTIONS-1
	0
	SET 5		/XR5 TO PTR TO LAST DISPLAYED CHAR IN ANSWER BUFR
	QARFSH-1
QAG,	SET 1
	3
	JMP QAT
	JMP .+7		/F
	LDH I 3		/H. BUMP PTR
	LDA I		/NEITHER. ASSUME HALF SIZE
	BCL I
	STC QAM+2	/SET INSTR TO CLEAR FF FOR HALF SIZE
	ADD QAW		/NOP IN AC
	JMP QAM
	LDH I 3		/BUMP PTR
	LDA I
	BSE I
	STC QAM+2	/SET INSTR TO SET FF FOR FULL SIZE
	ADD QAW+1	/ADD 9U IN AC
QAM,	STC QAP+3
	MSC I 4		/EAD CONTROL REGISTER
	BSE I		/THIS INSTR CHANGES. EITHER BSE & OR BCL &
	200
	MSC 4		/AC TO CONTROL REGISTER
	SET I 1		/XR1 TO INITIAL X POSITION
	100
	LDA I		/Y COORDINATE MULTIPLE
	-40
	ADM I		/Y COORDINATE
	0
QAH,	LDH I 3
	JMP QAO+1
	JMP QAZ		/74 BUMP PTR TO NEXT CHAR, PUT 40 IN AC
	JMP QAJ		/34
	SHD I		/NEITHER
	4300
	JMP QAG		/CR. MOVE X AND Y COORDINATE
	JMP QAP		/ISPLAY CHAR
	JMP QAH		/PICK UP NEXT CHAR
	JMP QAP		/TO HERE IF DISPLAYING ANSWER BUFR
	SRO I	/SWITCH TO DISPLAY CURSOR. EITHER 0000 OR 7777
	0		/IFXR4=XR5, THEN SWITCH=7777
	JMP QAF
			/QUESTION MODE
QAI,	LDH I 5
	JMP QAO+1
	JMP QAH		/74
	JMP QAH		/34
	JMP QAI-4	/NEITHER. DISPLAY IT
QAJ,	JMP GETKBD	/TO HERE IF DISPLAYED BUFFER
	AZE I
	JMP QAB	/NOTHING TYPED . EXIT
	SET I 2
	QAY
	SHD 2		/LF?
	JMP QAK+4	/YES. EXIT
	SHD I 2		/CR?
	JMP QAN
	XSK 6		/IS THERE AN ANSWER FIELD?
	JMP QARFSH
	SHD I 2		/<?
	JMP QAL
	SHD I 2		/>?
	JMP QAK
	SHD I 2		/ALT?
	JMP QACA /REINITIALIZE
	SHD I 2		/BACK SLASH?
	JMP QARFSH	/IGNORE
	SHD I 2		/RUBOUT?
	JMP QAL		/IGNORE
	SHD I 2		/TAB?
	JMP QARFSH	/IGNORE
	STC .+5		/ACCEPTABLE CHAR
	JMP QAO		/TEST NEXT CHAR
	JMP QAQ		/74 BACK PTR UP BY 1
	JMP QAQ		/34 ^
	LDA I		/OK. STORE IT
	0
	STH 4
	JMP QARFSH	/REDISPLAY
QAL,	LDH 4		/TO HERE IF RUBBOUT OR <
	JMP QAO+1
	JMP QARFSH	/74 IGNORE
	-6002
	LDH 2		/TEST THE CHAR
	SAE I		/RUBOUT?
	37
	JMP QAQ		/NO. BACK PTR UP BY 1
	SET 5
	4
	SET 3
	4
	JMP .+2
	LDH I 5		/BUMP PTR
	LDH I 3		/GET NEXT CHAR
	JMP QAO+1
	NOP		/IF 74 OR 34, REPLACE CURRENT CHAR WITH 0
	CLR
	STH 5
	AZE		/WAS IT 74 OR 34?
	JMP .-7		/NO. CONTINUE
	JMP QAQ		/BACK PTR UP BY 1
			/TO HERE IF CR
QAN,	XSK 6	
	JMP QAK+4	/EXIT ROUTINE IF NO ANSWER FIELD
	JMP QAO
	JMP QARFSH	/74 MOVE PTR TO NEXT QUESTION FIELD
	JMP QAE+1	/34 END OF BUFR. MOVE PTR TO FIRST QUESTION FIELD
	JMP QAN+2
	
QAO,	LDH I 4		/S\R
	SHD I		/	+1 74 BEGIN FIELD
	7400		/	+2 34 END BUFR
	JMP 0		/	+3 NEITHER 74 NOR 34
	SAE I
	34
	XSK I 0
	XSK I 0
	JMP 0
			/S\R TO DISP LINC CHAR IN AC
QAP,	ROL 1		/MULT BY 2 FOR INDEX TO ADDRESS OF TABLE
	ADD QAX+4
	STC 2		/ADDRESS OF CHAR TO DISP IN XR2
	ADD QAU		/THIS INSTR CHANGES. EITHER OP OR ADD 9U
	ADD QAU
	ADD 1		/ADD 4 TO XR1 TO SPACE CHAR
	STC 1
	ADD 5		/GET ADDRESS OF ANSWER BUFR
	COM
	ADD 4
	AZE
	CLR
	STC QAI-2	/SWITCH=0 OR 7777
	ADD QAH-1	/Y COORDINATE IN AC
	DSC 2
	DSC I 2		/DISPLAY CHAR
	JMP 0
QAQ,	LDA I		/BACK UP PTR BY 1
	-4000
	ADM
	4
	JMP QARFSH	/REDISPLAY
			/
QAT,	LDH I 1		/S\R
	SHD I		/	+1 F
	0600		/	+2 H
	JMP 0		/	+3 NEITHER
	SAE I
	10
	XSK I 0
	XSK I 0
	JMP 0
			/
QAZ,	LDH I 3
	LDA I
	40
	JMP QAI-4
			/TO HERE IF >
QAK,	LDH I 4
	AZE I		/IS CURRENT CHAR BLANK?
	JMP QAQ		/YES. IGNORE
	JMP QAX		/MOVE DOT FORWARD
			/TO HERE TO EXIT WITH SKIP
	LDA I
	1
	ADM
	QAB
	JMP QAB
			/CHARACTER PATTERNS
QAV,	0101		/KBD 0, ILLEGAL. USED AS MARKER
	0101
	4477		/1:A
	7744
	5177		/2:B
	2651
	4136		/3:C
	2241
	4177		/4:D
	3641
	4577		/5:E
	4145
	4477		/6:F
	4044
	4136		/7:G
	2645
	1077		/10:H
	7710
	7741		/11:I
	0041
	4142		/12:J
	4076
	1077		/13:K
	4324
	0177		/14:L
	0301
	3077		/15:M
	7730	
	3077		/16:N
	7706	
	4177		/17:O
	7741
	4477		/20:P
	3044
	4276		/21:Q
	0376
	4477		/22:R
	3146
	5121		/23:S
	4651
	4040		/24:T
	4077
	0177		/25:U
	7701	
	0176		/26:V
	7402
	0677		/27:W
	7701
	1463		/30:X
	6314
	0770		/31:Y
	7007
	4543		/32:Z
	6151
	4177		/33:/
	0000
			/34:BACKSLASH IGNORED ON INPUT
	0		/NOT USED
	0		/NOT USED
	0000		/35:]
	7741
			/CODES 36:ALT, 37:RUBOUT NOT DISPLAYED
QAY,	4543		/LF,CR
	7476		/<,>
	3634		/ALT, BACKSLASH
	3747		/RUBOUT, TAB
	0000		/40:SPACE
	0000
	7500		/41:X!
	0000
	7000		/42:"
	0070
			/CODES 43:, 44:, 45:LF NOT DISPLAYED
QAX,	JMP QAO+1
	JMP QAQ
	JMP QAQ
	JMP QARFSH
	QAV
	0		/NOT USED
	5166		/46: &
	0526
			/CODE 47:TAB NOT DISPLAYED
	0		/NOT USED
	0		/NOT USED
	3600		/50:(
	0041
	4100		/51:)
	0036
	2050		/52:*
	0050
	0404		/53:+
	0437
	0500		/54:,
	0006
	0404		/55:-
	0404
	0001		/56:.
	0000
	0601		/57:\
	4030
	4536	/60:0
	3651
	2101		/61:1
	0177
	4523		/62:2
	2151
	4122		/63:3
	2651
	2414		/64:4
	0477
	5172		/65:5
	0651
	1506		/66:6
	4225
	4443		/67:7
	6050
	5126	/70:8
	2651
	5122		/71:9
	3651
	2200		/72::
	0000
	4601		/73:;
	0000
			/CODE 74:<NOT DISPLAYED
QAU,	2		/CONSTANT
	0	/NOT USED
	1212		/75:=
	1212
			/CODE 76:> NOT DISPLAYED
QAW,	NOP
	ADD QAU
	4020		/77:?
	2055
/
QAF,	DSC I
	6000
	JMP QAI
/
			/END Q+A
/
/
/
/
/KEYBOARD INPUT ROUTINE
/
QAKRB=6036	/PDP-8 IOT KBD
QATSF=6041	/TSF
QATLS=6046	/TLS
/
GETKBD,	LDA
	0
	STC QAEXIT+6	/SAVE RETURN
	ADD 1		/SAVE XRS 1 AND 2
	STC QAEXIT+3
	ADD 2
	STC QAEXIT+5
	STC QAEXIT+1
	KST	/WAS SOMETHING TYPED?
	JMP 0		/NO: EXIT
	IOB
	QAKRB	/GET TTY CHAR, CLEAR FLAG
	STA I		/SAVE IT
QATY,	0
	ADA I
	-237
	APO		/BETWEEN 200 AND 237?
	JMP QACNTR	/CONTROL CHAR. CHECK FOR CR,LF,TAB
/
	SET I 1		/NO
	QACHAR-1
	SET I 2
	-7
	LDA
	QATY
	SAE I 1
	JMP .+2
	JMP QAEXIT	/ILLEGAL CHAR. DONT ECHO
	XSK I 2	/CHECKED THEM ALL?
	JMP .-4
/
	ADA I
	-337
	APO		/BETWEEN 240 AND 337?
	JMP QALEGL	/YES. LEGAL CHAR
/
	SAE I 1		/NO. CHECK FURTHER.
	JMP .+7
	LDA I		/RUBOUT
	334
	JMP QATPE	/ECHO BACKSLASH
	LDA I
	37
	JMP QAEXIT+2	/LEGAL EXIT
/
	SAE I 1
	JMP QAEXIT	/ILLEGAL
			/ALT
	JMP QAEXIT+2	/EXIT, DONT ECHO
/
QALEGL,	LDA
	QATY
	JMP QATPE	/ECHO CHAR
	ADD QATY
	BCL I		/STRIP IT TO 6-BIT
	7700
	JMP QAEXIT+2
/TO HERE IF CONTROL CHAR
QACNTR,	SAE I
	7755
	JMP QACKLF
	LDA I		/CR
	43
	STC QAEXIT+1
	LDA I
	215
	JMP QATPE
	LDA I
	212
	JMP QATPE
	JMP QAEXIT
/
QACKLF,	SAE I
	7752
	JMP .+4
	LDA I		/LF
	45
	JMP QACNTR+5
	SAE I
	7751
	JMP QAEXIT	/ILLEGAL
	LDA I
	47
	JMP QAEXIT+2	/EXIT, DONT ECHO
/
QAEXIT,	LDA I	/GET 6-BIT ASCII
	0
	SET I 1		/RESTORE XRS
	0
	SET I 2
	0
	JMP		/EXIR S\R GETKBD
/S\R TO PRINT C(AC)
QATPE,	IOB
	QATLS	/PDP-8 IOT TLS
	LDA
	0
	STC .+4	/SAVE RETURN
	IOB
	QATSF	/WAIT FOR FLAG
	JMP .-2
	JMP 	/EXIT
/
QACHAR,	243	/HASH
	244	/DOLLAR SIGN
	245	/PER CENT
	247	/APOSTROPHE
	300	/AT SIGN
	336	/UP ARROW
	337	/BACK ARROW
	40	/RUBOUT
/DIFCON