Directory of image this file is from
This file as a plain text file

[PROGRAM TO GENERATE
[A FUNCTION OF 512
[POINTS IN FLOATING
[POINT-DOUBLE
[PRECISION FORM
[+ WRT ON TAP
[STARTING ON BLK NO GIVEN BY THE RSW
[RANGE OF THE ABC
[-400 TO 377
[THE DATA FOR THE
[ORDIN. MUST BE
[GIVEN AS INTEGERS
[RANG OF THE ORD -377 TQ 377
[X ENDS DAT ENT + DIS R
[DR DIS RE
[DI DIS IM
[EOL STP DIS R OR I
[DIS PRO MUST BE IN BLKS 30-32,UNIT 1
[SEN SW 0 CV FROM DEG TO RAD
[SEN SW 1 CV DAT TO LN DAT
[SEN SW 3 DIV R BY 100
[USES FLOD-1R AND LOGTD
[ARITH SUB ON TP BLKS 50-51,UNIT 1
[
[
[CLR PAGS 1,2,3,4
$20
UMB 6 [DIS PRO
RDC u
4|30
RDC u
6|31
RDC u
7|32
UMB 5 [ARITH SUBR
RDCu
4|50
RDC u
5|51
CLR
SET i5
3777
UMB 1
STAi5
XSK 5
JMP p-2
UMB 2
STA i5
XSK 5
JMP p-2
UMB 3
STA i 5
XSK 5
JMP p-2
UMB 4
STA i5
XSK 5
JMP p-2
#2K CLR
STC 4
[RESET INI LIN
#2M LDA i
-10   [NUM OF AD TO CLR FOR DIS
STC 2L+4
LDA i
3D+13 [1ST LINDAT COD AD -1
STC 2L+6
JMP 2L
LDA i
3D+37 [2ND LIN
STC 2L+6
JMP 2L
LDA i
-12     [NUM OF AD TO CLR FOR DIS
STC 2L+4
LDA i
3D+53 [3RD LIN
STC 2L +6
JMP 2L
LDA i
3D+71 [4TH LIN
STC 2L+6
JMP 2L
JMP 2B
[CLR DAT COD AD FOR
[DIS
#2L CLR
ADD 0
STC p+11  [RETURN
SET i 17
XXXX   [NUM AD
SET i16
XXXX   [AD -1
CLR
STA i16
XSK i 17
JMP p-3
RETURN
[DIS STRING OF CHAR
[INIT AD OF DIS
[PLAY COD MUST BE
[IN 2X.
[NUM OF CHAR TODIS
[IN 2X+3.
[INIT HOR POS IN 2X
[10
[VERT POS IN 2X+11
#2A CLR  [DIS STRING OF CHA
ADD 0
STC 2A+25
SET 3
2X
SET 2
2X+3
SET 1
2X+10
LDA
2X+11
DSC i3
DSC i3
XSKi2
JMP p+2
JMP p+6
LDA i
4
ADM
1
JMP p-13
RETURN
[SET CURRENT PAR
#2B CLR
STC 10   [NUM OF SIGN CHA
ADD4
ADA i
3A
STA
2G+1
ADA i
4
STA
2G+4
ADA i
4
STA
2X+1   [AD DAT STRG
ADA i
4
STA 
2G+7
ADA i
4
STA
2G+13
#2G LDA
XXXX
STC 2X  [INI AD DIS COD-1
LDA
XXXX
STC 6   [INI AD DAT COD -1
LDA
XXXX
COM
STC 2X+3[NUM OF DIS CHA
LDA
XXXX
STA
2X+4
COM
STC 5   [MIN NUM DA DIG
#2C JMP 2A  [DIS LIN
XSK 5   [ALLDIG
JMP p+2
JMP 2D  [YES
KST
JMP p-5
KBD     [ENTER DAT
STA
2X+12   [TEM
SAE i
12      [EOL
JMP p+2 [NO
JMP 2E
LDA
5       [1ST DIG
ADD 2X+4
AZE
JMP 2F  [NO 1ST DIG
CLR
STC 2X+2[CLR DAT STOR
LDA     [YES
2X+12
SAE i
53      [X,END DAT ENT
JMP p+2 [NO
JMP 2O  [YES
LDA
2X+12
SAE i
20      [+
JMP p+13[NO
LDA     [1ST SIGN
10
AZE
JMP 2M  [NO 
SET i 10[YES,NUM OF SIGNS
1
LDA i
NOP
STC 2Z
JMP 2H  [DONT INDEX NUM DA DIG
SAE i
17      [-
JMP p+13[NO
LDA     [1ST SIGN
10
AZE
JMP 2M  [NO
SET i 10[YES,NUM OF SIGNS
1
LDA i
COM
STC 2Z  [COM DA
JMP 2H
LDA    [SIGN
10
AZE
JMP 2F [YES SIGN
LDA i
NOP
STC 2Z  [NOP
JMP 2F
[TEM
#2F CLR
ADD 2X+12[DIG L.O.E. 7
ADAi
-11
APO i
JMP 2M   [G.T. 7
LDA i5  [INDEX5
[STORE DIGIT
LDA
2X+2
ADA
2X+12
ROL 3
STC 2X+2
#2H CLR
ADA i
1
STC p+11
LDA     [LO DIG COD FOR DIS
2X+12
ROL 1
ADA i
3E      [1ST DIG AD TABL COD
STA
p+5
ADM i
1
STC p+5
LDA
XXXX
STA i 6[1ST HALF COD
LDA
XXXX
STA i6[2ND
JMP 2C
[
[ALL DIG ENTERED
#2D KST
JMP 2C
KBD
SAE i
12      [EOL
JMP p+2  [NO
JMP 2D+13[YES
SAE i
13      [DELETE
JMP 2C  [NO
JMP 2M  [YES
LDA     [CANC LST ROT + INTROD SIGN
2X+2
ROR 3
#2Z XXXX    [COM OR NOP
SET 1
2X+1    [AD DAT STR
STA 1
JMP 2I  [INDEX LIN COUN 4
[ 
#2E LDA    [1ST DIG
5
ADD 2X+4
AZE
JMP 2D+13 [NO 1ST
JMP 2C  [YES
#2I XSK i4  [INDEX 4
CLR
ADD 4   [REG 4 EQ. 4
SAE i
4
JMP 2B  [NO,STILL LIN TO DIS
[CHECK IF INIX IS IN 
[RANGE.
#2P CLR
ADD 3A+10
AZE i
JMP p+3  [INIX=0
APO
JMP p+6  [INIX L.T. 0
ADA i    [INIX G.T. 0
-400
APO i
JMP 2K  [INIX G.T. 377
JMP p+13
ADA i
401
APO
JMP 2K  [INI X L.T. -400
CLR     [SET AD ON UMB - 1
ADD 3A+10
ROL 1
ADA i
3777
JMP p+6
CLR
ADD 3A+10
ROL 1
ADAi
1777
STA     [INI AD FOR RE ON UMB - 1
17
ADAi
1
STC 16  [INI AD FOR IM ON UMB - 1
LDA     [CORRECT I 17 HAS 1777
17
SAE i
1777
JMPp+4
LDA i
3777
STC 17
CLR
ADD 3A+11
COM
ADD 3A+10
ADA i
-1
[FINX G.T. INIX
AZE
JMP p+2
JMP 2K
APO
JMP p+2 
JMP 2K
STC 15  [MIN FINX-INIX+1
ADD 3A+12 [R
STA
3C+1
APO i
JMP p+4
LDA i
7777
JMP p+2
CLR
STC  3C
ADD 3A+13
STA
3C+3
APO i
JMP p+4
LDA i
7777
JMP p+2
CLR
STC 3C+2
UMB 0
LMB 5
JMP 1I  [FLOAT RE
3C+2000
2X+2000
SNS 3
JMP p+6 [NO
LMB 5   [YES,R|100
JMP 1D
2X+2000
3B+2003
2X+2000
SNS 1
JMP p+5 [NO
LMB5 [YES, LN
JMP 1L
2X+2000
2X+2000
LMB 5
JMP 1I  [FLT IM
3C+2002
2X+2003
SNS 0   [CV DEG TO RAD
JMP 2Q  [NO
LMB 5
JMP 1M  [YES
2X+2003
3B+2000
2X+2003
[
[LO UP PAG W. FLT DA
#2Q UMB 2
LDA
2X
STA i17
LDA
2X+3
STA i16
UMB 3
LDA
2X+1
STA 17
LDA
2X+4
STA 16
UMB 4
LDA
2X+2
STA 17
LDA
2X+5
STA 16
LDA i17
LDA i16
XSK i15
JMP 2Q
JMP 2K   [NEW R AND I VAL
#2O LDA
4
AZE [1ST LIN
JMP 2M  [NO,DIS LIN AGAIN
#2J SET i17 [ENTER BLK NO
-14
SET i16
-4
LDA i
2R+2
STA
2J+14
STC 2J+22
RSW
STC 2J+20
LDA
2R+2 [SUBJECT TO CHANG
BCL i
0777
ADAi
X    [BLK NO
STA
2R+2 [SUBJECT TO CHSNG
LDA 
p-4
ADA i
1
STC p-7
XSK i17
JMP p+2
JMP 2R
XSK i16
JMP p+2
JMP p+5
ADD 2J+14
ADA i
2
JMP p+6
ADD 2J+14
ADA i
3
SET i16
-4
STA
2J+14
STC 2J+22
JMP 2J+13
[LO TP W FLT DA
#2R UMB 2
WRC
4200
WRC
5201
WRC
6202
WRC
7203
UMB 3
WRC
4204
WRC
5205
WRC
6206
WRC
7207
UMB 4
WRC
4210
WRC
5211
WRC
6212
WRC
7213
#2U KBD i [ENT COD
SAE i
27 [D
JMP 2U [INVAL COD
LDA i
UMB 2
UMB 6
STA
6A  [UMB N
STA
6L
ADA i
1
STA
6A+3 [UMB N+1
STA
6L+3
ADD p-5
STA
6A+6 [UMB N+2
STA
6L+6
KBD i
SAE i
45 [R
JMP p+2
JMP 2V [DIS R
SAE i
34 [I
JMP p-7  [INV COD
LDA i [DIS I
-1
JMP p+2
#2V CLR
LMB 6
JMP 20
JMP 2U
#3D 7741[I
0041
3077[N
7706
7741[I
0041
0000[SPACE
0000
1463[X
6314
0000[SPC
0000
XXXX[IST DIG
XXXX
XXXX[2ND
XXXX
XXXX[3RD
XXXX
XXXX[4TH
XXXX
4477[F
4044
7741[I
0041
3077[N
7706
0000[SPC
0000
1463[X
6314
0000[SPC
0000
XXXX[1ST DIG
XXXX
XXXX[2ND
XXXX
XXXX[3RD
XXXX
XXXX[4TH
XXXX
4477[R
3146
0000[SPC
0000
X[1ST DIG
X
X[2ND
X
X[3RD
X
X[4TH
X
X[5TH
X
7741[I
0041
0000[SPC
0000
X[1ST DIG
X
X[2ND
X
X[3TH
X
X[4YH
X
X[5TH
X
[XXXXXXXXXXXXXXXXX
#3E 4136[0
3641
2101[1
0177
4523[2
2151
4122[3
2651
2414[4
0477
5172[5
0651
1506[6
4225
4443[7
6050
#2X XXXX     [FP R
X[TEM AD DA STR
X[TEM INTEG DA
X        [FP I-TEM NUM DIS CHA
X[MIN NUMDA DIG
X[
X[
X[
74 [INI HOR POS
0 [VRT POS
X[TEM DAT STR
X [NO USED
X [NO USED
0404[-
0404
0404[+
0437
[INI AD DIS COD -1
#3A 3D-1[1ST LIN
3D+23[2ND
3D+47[3RD
3D+65[4TH
[INI AD DAT COD - 1
3D+13[1ST LIN 
3D+37[2ND
3D+53[3RD
3D+71[4TH
X[INI X
X[FIN X
X[R
X[I
[NUM DIS CHA
12[1ST LIN
12[2ND
6[3RD
6[4TH
[NUM DAT DIG
3[1ST
3[2ND
3[3RD
3[4TH
#3B -5     [RAD PER DEG
2167
3200
7      [CONST 100
2000
0000
#3C X     [R FOR FP CV
X
X     [I FR FP CV
X
[XXXXXXXXXXXXXXXXXX
[AUGUST 2 ,1971
[XXXXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXXXX
1I=36 [AD IN ARITH PRO
1L=750
1M=101
1D=247
6A=2034  [AD IN DIS PRO
6L=2154
[XXXXXXXXXXXXXXXXXX