Directory of image this file is from
This file as a plain text file

[INITIALIZE READING ERROR FILE AND INPUT
LDA
0
STC 8A[SAVE RETURN
UMB 0
LDA
3753
ADAi
24
SAE
3770
JMP p+5
LDA
3771
AZEi
JMP 9Z-1
LDA
3752  [U|FB2[SYSTEM FILE]
BCLi
2777
ROL 6
[SOURCE CODE UNIT
ADAi
700
STC 3C-1
ADA
3755  [U|FB2[SYSTEM FILE]
BCLi
2777
ROL6
[SYSTEM FILE UNIT
ADAi
700
STA  [SET SYSTEM FILE READS
3A-1
STC 1C-1
LDA
3753
UMB 2
ADAi
6024
STA
3A
STC 1C
RDC
#3A 0
SETi10
2777
SETi11
5B-1
JMP 1B
STAi11
[TEST FOR EOF
JMP 1A
JMP 9Z
ADAi
6|3B[JUMP TABLE
STC p+1
0[JUMP
#1A SAEi
7777
XSKi0
JMP 0
#1B SET 5
0
LDA
10
SAEi
3377
JMP 1C+3
SETi10
3000
LDA
1C
ADAi
1
STC 1C
RDC
#1C 0 [ERROR FILE
LDA 10
JMP 5
LDAi10
JMP 5
[END OF ERROR FILE
UMB 2
#9Z LDAi
p+6013
STA
8J+2
STA
8J+7
STC 2N+5
SETi3
8E-4000
LDAi
7S
JMP 5N-3
LMB 0
#8A 0[RETURN
#5B 0[TYPE
0[LINE NUMBER
0[INPUT POINTER
0[CURRENT STATEMENT--BLOCK
0[CURRENT STATEMENT--WORD
0[DIAGRAM POINTER
JMP 5S  [ERROR FILE OVERFLOW
#3B JMP 2A
JMP 5S[INVALID
JMP 5S[INVALID
JMP 5S[INVALID
JMP 5S[INVALID
JMP 2A  [5  MISSING FOR VARIABLE
JMP 2A  [6  >3777 BASIC-L STATEMENTS
JMP 2A  [7  INTERNAL SIZE CONSTRAINT VIOLATION
JMP 2E  [10 MULTIPLE LABEL DEFINITION
JMP 2A-4  [11 NO DIGIT AFTER E
JMP 2A  [12 COMPILER LOGIC FAILTURE
JMP 2A  [13 NEED LETTER
JMP 2A  [14 EOF SOURCE CODE
JMP 2A  [15 EOF TARGET CODE FILE
JMP 2A  [16 MANUAL TERMINATION OF COMPILE
JMP 5S[UNASSIGNED
JMP 2B
JMP 2E
JMP 2B
JMP 2B
[$2A-4
SET i 7
-4  [ERR RECORD LENGTH
JMP 5A+2
JMP p+2
#2A JMP 5A
JMP 5D
JMP 5M
#2B STA i 11  [INDEX 11
JMP 5E
JMP 5M
#2E JMP 1B
STAi11
JMP 5G  [LINE #
JMP 5E+2
JMP 5M
[LOAD PARAMETERS
#5A SETi7
-5
SET 4
0
JMP 1B
STAi11
XSKi7
JMP p-3
LDA
5B+3
ADAi
7000
SAE
3C
APOi
JMP 4
STC 3C
[READ INPUT
RDC
#3C 0
JMP 4
[INPUT LINE TO TELETYPE
#5D LDA
0
STC 5E-1
ADD 5B+4
ADA
8C[DISPLACEMENT FOR INPUT
STC 12
ADD 8C
ADD 5B+2  [INPUT PTR
STC 5B+2
JMP 5G[LINE NUMBER
LDH 12  [LOAD FIRST CHAR
JMP 5E-7  [HANDLE 1ST CHAR
LDA
12
AZE
JMP p+14
ADD 3C
ADAi
1
STC 3C
SETi12
3377
SETi4
p+2
JMP 3C-1
LDA
12
SAE
5B+2
JMP p+4
LDAi
76
STHi3
LDHi12
SHDi
1200
JMP 5E-2
STHi3
JMP 5D+15
STHi3
0[RETURN
#5E SET i 3
8E-4000
LDA
0
STC 5G-1
JMP 1B
STA 11
LDH
5B+1
STHi3
LDH
5B+4001
SHDi
1200
JMP p+4
STHi3
LDAi
12
STHi3
0[RETURN
[OUTPUT LINE NUMBER
#5G LDA
0
STC 5M-3
SETi3
8E-4000
SETi2
-4
LDA
5B+1
ROL 3
STA
5B+1
BCLi
7770
STHi3
XSKi2
JMP 5G+7
LDAi
14
STHi3
0[RETURN
[OUTPUT ERROR MESSAGE
SETi3
8E-4000
#5M LDA
5B
AZEi
JMP 5N[DIAGRAM LOOKUP
ADAi
8D-1
STC p+2
LDA
0[LOAD ERROR MESSAGE ADDRESS
STC 5P
JMP 5Q
JMP 5U
#5N CLR
STC 2
LDA
5B+5[RELATIVE TO 0 BEGINNING
COM
APOi
XSKi2
ADAi
3
APO
JMP p-4
ADAi
-3
COM
ROR 1
ADD 2
ROL 1
ADAi
8B-1
STC p+2
LDA
0[LOAD ERROR MESSAGE ADDRESS
AZEi
JMP 5R[DIAGRAM ERROR
JMP 5N-3
#5Q LDA
0
STC 5R-1
LDAi
#5P 0[ERROR MESSAGE ADDRESS
STC 5
LDH 5
COM
STC 6[COUNTER
LDHi5
STHi3
XSKi6
JMP p-3
LDAi
77
STHi3
0[RETURN
#5R LDA i
9W[DIAGRAM ERROR
JMP 5N-3
#5S LDA
9X[ERROR FILE ERROR
JMP 5N-3
#5U LSW
BCLi
3777
AZEi
JMP 8F[TELETYPE
JMP 8G[SCOPE
#8F JMP 3W
SETi3
8E-4000
LDHi3
SHDi
7600
JMP 8H
SHDi
1200
JMP 8I
SHDi
7700
JMP 8J
JMP 3V
JMP 8F+3
#8H JMP 3W
LDHi3
SAEi
12
JMP p-3
JMP 8F+3
#8I JMP 3W
JMP 8F+3
#8J JMP 3W
KST
JMP 3A+3
KBD
SHDi
1300
JMP 9Z
JMP 3A+3
[SCOPE DISPLAY
#2F HORIZ ERROR
#2G VERT
#8G LDAi
141
STC 2G
SETi2
#2I 8E-4000
LDA
2G
STAi
#2J XXX[VERT
SETi1
0
#2L LDHi2
SHDi
1200
JMP 2M-7
SHDi
7600
JMP 2M
SHDi
7700
JMP 2N
ROL 1
ADAi
6A
STC 3
ADD 2J
DSC 3
DSCi3
LDAi
4
ADD 1
STA
1
SAEi
740
JMP 2L
LDAi
-100
ADM
2J
JMP 2J+1
[DISPLAY ARROW
7720
0020
#2M LDAi
2M-2
STC 3
ADD 1
STA 
2F
ADAi
-24
STC 1
ADD 2J
ADAi
-40
DSC 3
DSCi3
LDA 
2F
STC 1
JMP 2L
#2N KST
JMP 2I-1
KBD
SHDi
1200
JMP 3A+3
SHDi
4700
JMP 8F
SHDi
1300
JMP 9Z
SAEi
45
JMP 2I-1
LDAi
JMP 3A+3
STA
8J+2
STA
8J+7
STC 2N+5
JMP 23
[OUTPUT ON TELETYPE
[ACC=LINC CHARACTER
#3V ROR 1
ADAi
3Y[CODE TABLE
STC 1
ADD 0
STC 3W-1
LDH 1
ADAi
1640
ROL 1
[B11=0
[B8-B10=1
[B1-B7=ASCII CODE
[B0=0
JMP 3X
LDAi
1
ADM
3Z[CCP
0[RETURN
[CR-LF
#3W LDA
0
STC 3X-1
STA
3Z[CCP
LDAi
3432[CR
JMP 3X
LDAi
3424[LF
JMP 3X
0[RETURN
#3X SET 4
0
STC p+5
MSC 4
APOi
JMP p+7
LDAi
0[ASCII CODE
ROR 1
OPR 42
JMP p-1
JMP 4
LDA
3X+7
ATR
SETi1
-435
XSKi1
JMP p-1
SCR 1
AZE
JMP p-7
JMP 4
#3Z 0[CCP
[ERROR MESSAGE TABLE
#8D 0[UNASSIGNED
0[UNASSIGNED
0[UNASSIGNED
0[UNASSIGNED
7E  [5
7F  [6
7G  [7
7B  [10
7J  [11
7K  [12
7D  [13
7L  [14
7M  [15
7N  [16
0[UNASSIGNED
7A  [20
7D
7C
[TELETYPE CHAR CODE
[INDEXED BY LINC CODE
#3Y 2021  [0  1
2223  [2  3
2425  [4  5
2627  [6  7
3031  [8  9
1010  [EOL  DEL
0006  [SP i
0715  [p  -
1374  [+  |
0340  [#  CASE
4142  [A  B
4344  [C  D
4546  [E  F
4750  [G  H
5152  [I  J
5354  [K  L
5556  [M  N
5760  [O  P
6162  [Q  R
6364  [S  T
6566  [U  V
6770  [W  X
7172  [Y  Z
1177  [META  _
3735  [?  =
0514  [u  ,
1604  [.  $
7340  [[  _
7633  ["  ;
3436  [<  >
7512  []  *
3277  [:  _
[
[LOOKUP ERROR MESSAGE FROM ERROR DIAGRAMS
[
#8B 0[4A
9A[JMP 7F
9A[3A
0
0
0[JMP 7B
0
0[JMP 7D
0[4B
9B[JMP 7G
9B[4C
0
0
0
0
0
0
0
0
0[JMP 6Z
0
0
0
0[JMP 9A
0
0[JMP 9B
0
0[JMP 7M
0
0[JMP 7L
0
0
0
0
0
0[JMP 7B
0
0[JMP 9C
0
0[JMP 7B
0
0[JMP 7E
9B[3L
0
9C
0
0
0[JMP 7C
9D[3M
0[JMP 8D
9A
0[JMP 8E
0
0[JMP 8E
0[4O
7H[JMP 8R
0[4N
0
9E[3I
0[JMP 8D
9F
7O[JMP 7O
9G
0[JMP 7P
9H
0
0[4M
0
9I[4K
0[JMP 8J
9H[4L
0
0[5I
0[JMP 7C
9D[3J
0[JMP 8D
9F
7I[JMP 8K
0
7I[JMP 8K
0[5C
0
9E[5E
0[JMP 9D
9J
0[JMP 7H
9K
9L[JMP 8M
9L
0[JMP 7I
9K
9N[JMP 8N
0
0[JMP 8L
0[5H
0[JMP 7I
9K
0[JMP 6J
0[3K
0[JMP 7N
9F
0
0
0[JMP 7C
9D[4D
0
9F
0
9J
0[JMP 7H
9K[4E
0[JMP 7C
9O[4F
0[JMP 7I
9K[4G
0
9P[4H
0[JMP 7I
9K[4I
9Q[JMP 7J
9Q
9A[JMP 7K
9A[4J
9A[JMP 7K
9A[3B
0
0
0
0[5A
0
9K[5B
0
0
0
0[3C
0[JMP 8B
0
0
0
0
0[5D
0[JMP 7I
9R
7Q[JMP 8C
9S[3D
0[JMP 8D
9F[5F
0
0
0[JMP 8E
0[5G
0
9E
0
0
0
9I
0
9E
0
9S[3E
9T[JMP 8A
0
9T[JMP 8A
9U[5K
0[JMP 7C
0[3H
0[JMP 9O
0
0[JMP 9N
0
7R[JMP 9M
0
0[JMP 9O
0
0[JMP 9L
9V[3F
0
[GRID PATTERNS
#6A 4136
3641
2101
0177
4523
2151
4122
2651
2414
0477
#6C 5172
0651
1506
4225
4443
6050
5126
2651
5122 [9
3651
4020
2055
4020 [DEL
2055
0000
0000
0101
0126
3700
3424
0404
0404
0404
0437
0000
0077
3614
1436
4020 [CASE
2055
4477
7744
#6B 5177
2651
4136
2241
4177
3641
4577
4145
4477
4044
#6G 4136
2645
1077
7710
7741
0041
4142
4076
1077
4324
#6L 0177
0301
3077
7730
3077
7706
4177
7741
4477
3044
#6Q 4276
0376
4477
3146
5121
4651
4040
4077
0177
7701
#6V 0176
7402
0677
7701
1463
6314
0770
7007
4543 [Z
6151
0404 [META
0404
2504
0416
4020 [?
2055 [CASE,SPACE
#6F 1212
1212
0107
0107
0500
0006
0001
0000
4577
7745
4177
0000
0101 [_
0101 [CASE,CASE
0070 ["
0070 [CASE,A
0700 [;
0700 [CASE,B
2410 [<
0042 [CASE,C
4200 [>
1024 [CASE,D
0000 []
7741 [CASE,E
2050 [*
0050 [CASE,F
2200 [:
0000 [CASE,G
#8C 3400[INPUT DISPLACEMENT
#8E 0[OUTPUT BUFFER
[LAST 13 TRIPLETS CANNOT BE REACHED BY DIAGRAM FAILURE
[
[ERROR MESSAGE
[
[DIAGRAM ERRORS
$2000
#9A "#INVALID LABEL NAME;
#9B "-INVALID KEYWORD;
#9C "iNEED CONSTANT;
#9D "|NEED COMMA OR EOL;
#9E "|INVALID SUBSCRIPT;
#9F "BINVALID VARIABLE NAME;
#9G "-NEED LEFT PAREN;
#9H "|INVALID DIMENSION;
#9I "FNEED COMMA OR RIGHT PAREN;
#9J "-NEED EQUAL SIGN;
#9K "JINVALID ARITHMETIC EXPRESSION;
#9L "7NEED TO;
#9N "9NEED STEP;
#9O "8NEED EOL;
#9P "HINVALID RELATIONAL OPERATOR;
#9Q "9NEED THEN;
#9R "MINVALID PARENTHESIZED EXPRESSION;
#9S "+NEED RIGHT PAREN;
#9T "+NUMBER TOO LARGE;
#9U "HNEED DIGIT OR DECIMAL POINT;
#9V "#INVALID PRINT LIST;
#9W "HDIAGRAM ERROR-PLEASE REPORT;
#9X "KERROR FILE ERROR-PLEASE REPORT;
[CODE ERRORS
#7A "-UNDEFINED LABEL;
#7B "ADOUBLY DEFINED LABEL;
#7C "MLABEL DEFINED BUT NOT REFERENCED;
#7D " NEED LETTER ;
#7E  "AMISSING FOR VARIABLE;
#7F "+PROGRAM TOO LONG;
#7G "NINTERNAL SIZE CONSTRAINT OVERFLOW;
#7H "EINVALID FOR-NEXT NESTING;
#7I "#TOO MANY FOR LOOPS;
#7J "ANO DIGIT FOLLOWING E;
#7K "QCOMPILER LOGIC FAILURE-PLEASE REPORT;
#7L "-EOF SOURCE CODE;
#7M "AEOF TARGET CODE FILE;
#7N "KCOMPILATION TERMINATED BY USER;
#7O "GVARIABLE DIMENSIONED TWICE;
#7Q "BUNMATCHED PARENTHESES;
#7R "#NO " TO TERMINATE TEXT;
#7S "3EOC;
$3752
350
704
$3755
730
$3770
730