Directory of image this file is from
This file as a plain text file

[LAP5 FILE COMMANDS
[SM,SB,CM,CB,LI,PM
[BLOCKS 320-321, 323
[QUARTERS 0,1,3
$15
RCG 7E
7|7D
JMP 1N
JMP 3A
JMP 3A-1
JMP 3C
JMP 1A
JMP 3B
JMP 3D [PM
[TAPE CONTROL
#2M SET 2
1F
SET 5
2
SET i 6
1R  [BN
JMP 2C
15  [RDC i u
#1R 7A
JMP 2R [UP BN
JMP p+3 [ALL DONE
AZE  [7 DONE?
JMP 1R-1 [NO
LDA i [ALL OR 7 DONE
#2N MTB  [MTB u
JMP 2X [MOTION CHECK
[WRITE
SET 2
5
SET i 6
2B
JMP 2C
TAPE WR
#2B BN
JMP 2R [UP BN
JMP 1M [ALL DONE
AZE
JMP 2B-1
LDA i [ALL OR 7 DONE
#2A WRITE UNIT
JMP 2X
JMP 2M+2
[SET QUARTER
#2C CLR
ADA 6
BSE i
1000
STA 6
JMP 0
[UP BLOCK NUMBER
#2R LDA i
1001
LAM 6
BCL i
777
XSK i 2
XSK i 0
JMP 0
[CHECK N BLOCKS
#1M SET i 2
#1F -N BLOCKS
CHECK TAPE
FILE BN
AZE
JMP 2S
ADD p-3
ADD 1P
STC p-5
XSK i 2
JMP 1F+1
JMP 15
[CHECK FAIL
#2S LDA
1M+3
STC 2B
ADD 2
STA
1F
ADD 1R
AZE i
COM
BCL i
7000
STC 1R
JMP 2M+2
[MOTION CHECK
#2X SET 1
0
SHD
4|p+3
JMP 0
STC p+1
STOP TAPE
#1P 1   [CONSTANT
IBZ
JMP p-1
JMP 1
[NO 
MTB 7E
0
#1N CLR
SET i 1
340
DSC i
3077
DSC i
7706
SET i 1
364
DSC i
4177
DSC i
7741
KST
JMP 1N+1
JMP 15
[SAVE MANUSCRIPT
[LAST BN IN ACC
#1A ADA i
-7A-5000+2
COM  [CONSTANT
STC 1F
RDC i 7E
1|7D+21
RDC i 7E
3|7D+23
ADD 1P
STC 2Q
[CHECK PARTIAL SAVE
ADA
6E
AZE
JMP 2P
#2L LDA i
7B
JMP 1J+2 [FIX RDC UNIT
JMP 1S
JMP 1Z
JMP 1Y
JMP 1X
JMP p+4
JMP 1W
JMP 1L [REPLACE
JMP p+3
JMP 1V
JMP 1N
SET 4
2     [CONSTANT
JMP 1U
BSE i
#3E 0
JMP 1T
JMP 2M
[SAVE BINARY
#3C RDC i 7E
3|7D+30 [CV Q0
ADD 1410
ADA i
7D+40
STC 1R
ADD 1412
STC 3E
ADD 1411
AZE i
JMP 1N-2
STC 1F
ADA i
3
STC 2Q
ADA i
7E
JMP 2L+2
[COPY BINARY
ADD 3E-3 [2
[COPY MANUSCRIPT
#3A ADD 1P   [1
STC 2Q
JMP 1S
JMP 1Z
JMP 1N
JMP 1X
JMP 1N
JMP 1W
JMP p+2
JMP 1N
COM
STC 1F
LDA 2
BCL i
7000
STC 1R
LDA 2
BCL i
777
STC 3E
JMP 1J
LDA
6E+6
BCO i
10
STA
6E+6
JMP 2L+3
[PRINT MANUSCRIPT
#3D RDC i 7E
3|7D+35
LDA i
JMP 3F
STC 3F-4
LDA i
JMP 1002
STC 3F+6
[LIST-Q0
#3B ADD 1P   [1
STC 2Q
JMP 1S [FIX RCG
JMP 1Z [RCG INDEX
JMP 1N [NO INDEX
JMP 1X [NAME
JMP 1N [NO NAME
JMP 1W [ENTRY
JMP p+2
JMP 1N [NO ENTRY
RDC i 7E
2|7D+32
RDC 7E
1|7D+33
#3F LDA 2 [BN
STC 1377
ADD 2A
ADA i
-3   [UNIT
STC 1376
SET i 1
6E-1
SET i 2
9J-1
SET i 3
-6
LDA i 1
STA i 2
XSK i 3
JMP p-3
JMP 1001
[FILE SUBROUTINES
[CHECK MS OR BINARY PRESENT
#1W SET 5
2
LDA i 5
APO
XSK i 0
JMP 0
[CHECK BOUNDS
#1H LDA
6
ADD 1F
AZE i
COM
APO
XSK i 0
JMP 0
[FIX ADDRESS
#1K LDA
2
BSE i
7007
STC 2
XSK 2
JMP 0
JMP 1
[RCG AND CHECK INDEX
#1Z TAPE
1|7G
LDA
3000
SHD i
5700
XSK i 0
JMP 0
[MAKE INDEX
#1Y SET 1
0
SET i 2
2777
LDA i
5757
STA i 2
XSK 2
JMP p-2
JMP 1
[NAME SEARCH
#1X SET 1
0
SET i 2
3000
SET i 3
-4
SET i 4
6E+1
JMP 1K
LDA i 2
SAE i 4
JMP 1X+4
XSK i 3
JMP p-4
LDA i
#2Q 1 OR 3
ADM
2
XSK i 1
JMP 1
[REPLACE
#1L SET 3
0
SET i 1
234
SET i 4
3H-4000
LDH i 4
SHD i
1200
JMP 2K
ROL 1
ADA i
6A
STC 5
DSC 5
DSC i 5
LDA i
4
ADD 1
STC 1
JMP 1L+6
#2K KST
JMP 1L+2
KBD
SAE i
45    [R
JMP 15
SET 5
2
LDA i
5757
STA 5
STA i 5
JMP 3
[REPLACE TABLE
#3H 4530
4337
2426
3013
1200
[SLOT SEARCH
#1V SET i 4
6E+1
SET 1
0
SET i 2
3000
JMP 1K
SET 5
2
LDA i 2
SAE i
5757
JMP 1V+6
LDA i 4
STA i 5
SRO i
3567
JMP p-4
SET 2
5
JMP 2Q-1
[GAP SEARCH CONTROL
#1U SET 10
0
SET i 6
-7C
LDA i
7777
STC 1E
JMP 1B
SET 7
6
CLR
STC 1E
SET i 6
7F
JMP 1B
[FIND NEAREST OF TWO
#1G LDA
7
COM
ADD 6
ADA i
-7G-7G
APO
JMP p+3
JMP 1H
JMP 10
LDA
7
ADA i
1000
JMP 1H+2
JMP p+4
JMP 1H
JMP 10
JMP 1N
LDA
7
COM
JMP 10
[GAP SEARCH
#1B SET 1
0
SET i 2
7000
JMP 1K
LDH i 2
SHD i
5700
JMP p-4
XSK i 2
XSK i 2
XSK i 2
JMP 1C
JMP 1D
JMP 1C
JMP 1D
JMP 1B+4
[GET BN
#1C LDA i 2
BCL i
7000
STA
11
ADA i 2
APO
XSK i 0
COM
STA
12
SRO i
#1E FWD OR BWD
JMP 0
SET 12
11
STC 11
JMP 0
[BN COMPARE
#1D LDA
11
ADD 6
AZE i
COM
APO
JMP 0
ADD 1F
APO
AZE i
JMP 0
SET 6
12
JMP 1B+2
[WRITE INDEX
#1T STA 4
BCL i
7000
STA
2B
STC 1M+3
ADD 1F
COM
STA i 4
KST i
JMP 15
TAPE INS
1|7G
JMP 0
[FIX TAPE INSTRUCTIONS
[RDC UNIT
#1J LDA
6E+6
ADM 
2N  [MTB u
ADM 
1R-1 [RDC i u
JMP 0
[WRITE UNIT
#1S LDA
6E+6
BSE i
RCG
STA
1Z
ADD 3E-3 [2
STA
2A [MTB u
STA
2X+6 [MOTION CHK
ADD 3E-3 [2
STA
1T+13
ADA i
21
STA
2B-1
ADD 1P [1
STC 1M+2
JMP 0
[PARTIAL SAVE
$1400
#2P SET i 1
6E-1
SET i 2
-7
SET i 3
2T-1
LDA i 1
STA i 3
XSK i 2
JMP p-3
#1Q LDA i
7A
STA
2W
STC 2J+3
LDA i
4|7A
STC 2V
ADD 2T
STC 2F
STC 1
SET i 2
7777
LDA i
7B
BCO i
10
STA i
OTHER UNIT
BSE i
MTB
STA
2V+7
ADA i
23
STA
2V-1
ADD 1P [1
STC 2J+2
#2D ADD 2T+1
AZE i
ADD 2H-5
ADD 1P  [1
STC 2E
JMP 2Y
LDH i 1
SHD i
7700
JMP 1N
SAE i
12
JMP p-7
LDA i
#2E SECOND LINE NUMBER
ADD 2H-5
AZE i
JMP 1N
STC 2E
ADD 2H-5
ADM i
#2F FIRST LINE NUMBER
AZE
JMP 2D+5
[TRANSFER READY-FIRST LINE FOUND
LDA i
2065
STA i 2
COM
STA i 2
#2G JMP 2Z
JMP 2Y
LDH i 1
STH i 2
SHD i
7700
JMP 2H+4
SAE i
12
JMP 2G
LDA i
-1
ADM
2E
AZE
JMP 2G
[FINISHED MAKING NEW MS
#2H JMP 2Z
LDA i
7777
STH i 2
LDA
2
BCL i
6377
ROL 4
ADD 1P  [1
COM
STC 4
ADD 2W+12
STC 2V+7
JMP 2Z+7
BCL i
7000
COM
ADA i
7A
STC 1F
[CHECK TAPE
#2J SET 1
1F
CHECK
7A
AZE
JMP 1Q
ADD 1P [1
ADD 2J+3
STC 2J+3
XSK i 1
JMP 2J+2
RDC i 7E
4|7D+4
SET i 1
6E-1
SET i 2
-7
SET i 3
2T-1
LDA i 3
STA i 1
XSK i 2
JMP p-3
LDA
2D-13
JMP 2L+2
[READ OLD MS
#2Y SET 3
0
CLR
ADD 1
AZE
JMP 0
ADD 2W
BSE i
6000
STC 2W
RDC i 7B
#2W 7A
ADD 2V+2
LAM
2W
APO
JMP 2W-1
MTB 7B
0
SET i 1
6777
JMP 3
[WRITE NEW MS
#2Z SET i 4
-2
CLR
ADD 2
SAE i
6777
JMP 0
SET 3
0
LDA
2V
BCL i
3000
STC 2V
KST i
JMP 15
WRITE TAPE
#2V 4|7A
LDA i
1001
ADM
2V
XSK i 4
JMP 2V-3
STOP TAPE
0
SET i 2
7777
JMP 3
#2T 0 [LN 
0 [LN
-0 [NAME
-0
-0
-0
-0 [UNIT
7D=300
7A=350
7B=0
7E=0
7C=430
6E=2371
7G=426
7F=270  [FILE UPPER BOUND
6A=2001
9J=771
[FILJAN20