Directory of image this file is from
This file as a plain text file

[FIILTMOD
[SIGNAL DATA
[FILTER DATA
[F<W>*G<W>
$20
STC 3D
ZTA
STC 3B
ADD 0
STC 3B+1
ADD 3D
SHD i
4700 [T
JMP 2Q [ENTER SIGNAL DATA
SHD i
2500 [B
JMP 3Q  [ENTER G[W|
SHD i
4500 [R
JMP 3A [CV AMP AND PHI TO R AND I
SHD i
4000 [M
JMP 3N [FILTER
JMP 3B [INVALID CODE
[SET BLKS NOS FOR RDC INST TO VALES STARTING
[WITH CONTENTS OF RSW
#2T STA
2T+15
STC 2T+23
ADD 0
STC 2S
SET i17
-14
SET i16
-4
LDA i
X
STC 2T+21
LDA
2R+2   [ADD SUBJECT TO CHANG
BCL i
0777
ADA i
X      [BLK NO
STA
2R+2   [ADD SUBJECT TO CHANG
LDA
p-4
ADA i
1
STC p-7
XSK i17
JMP p+2
#2S XXXX    [RETURN
XSK i16
JMP p+2
JMP p+6
LDA
2T+15
ADA i
2
JMP p+7
LDA
2T+15
ADA i
3
SET i16
-4
STA
2T+15
STC 2T+23
JMP 2T++14
#2Q LDA i   [CHANG ADDS IN SUBR
2R+2
JMP 2T
#2R UMB 15  [ENT SIGN DAT
RDC
4|200
RDC
5|201
RDC
6|202
RDC
7|203
UMB 16
RDC
4|204
RDC
5|205
RDC
6|206
RDC
7|207
UMB 17
RDC
4|210
RDC
5|211
RDC
6|212
RDC
7|213
JMP 3B
#3Q LDA i  [CHANG ADDS IN SUBR
3R+2
JMP 2T
#3R UMB 7  [ENT FILTER DAT
RDC
4|150
RDC
5|151
RDC
6|152
RDC
7|153
UMB 10
RDC
4|154
RDC
5|155
RDC
6|156
RDC
7|157
UMB 11
RDC
4|160
RDC
5|161
RDC
6|162
RDC
7|163
#4R KBD
SHD i
3200 [G
JMP p+5 [DISPLAY
SHD i
4500 [R
JMP 3B [RETURN TO CONT. CNTR PAGE 0 104
JMP 3B
LDA i
NOP
STC 4Q
LDA i
UMB 7
UMB 2
STA
2A
STA
2L
ADA i 
1   [UMB 10
STA
2A+3
STA
2L+3
ADD p-5 [UMB11
STA
2A+6
STA
2L+6
#4Q XXXX
KBD i
SHD i
2400 [A
JMP p+5 [DISPLAY AMP G<W>
SHD i
4100 [N
JMP 4T [DIS PHAS OF G W
JMP p-7 [INVALID CODE
LDA i[ADD INST IN DIS PRO
LDA i6
UMB 2
STA
2E
CLR
LMB 2
JMP 20
LDA i [RESTORE NOP IN DIS PRO
NOP
UMB2
STA 
2E
JMP 4S
#4T LDA i [ADD INST JMP 2E+7 IN DIS PRO
2E
ADA i
4007
UMB 2
STA
2F
LDA i
-1
LMB 2
JMP 20
LDA i [RESTOR NOP IN DIS PRO
NOP
UMB 2
STA
2F
#4S LDAi
JMP 4R
STC 4Q
LDA i
UMB 15
JMP 4R+15
#3N SET i 4 [G<W>*F<W>
2000
SET i 5
2000
UMB 7
LDA 4 [EXP |G<W>|
STC 3F
LDA i 5 [EXP PHI G<W>
STC 3F+3
UMB 10
LDA 4 [MSB
STC 3F+1
LDA 5 [MSB
STC 3F+4
UMB 11
LDA 4 [LSB
STC 3F+2
LDA 5 [LSB
STC 3F+5
UMB 12
LDA 4 [EXP |F<W>|
STC 3D
LDA 5 [EXP PHI F<W>
STC 3D+3
UMB 13
LDA 4 [MSB
STC 3D+1
LDA 5 [MSB
STC 3D+4
UMB 14
LDA 4 [LSB
STC 3D+2
LDA 5 [LSB
STC 3D+5
JMP 1M [|G<W>|*|F<W>|
3F
3D
3D
JMP 1A [PHI + PHI
3F+3
3D+3
3D+3
[REDUCES PHI TO WITHIN +-PI
JMP 1V    [REDUCES TO WITHIN +-2PI
3D+3
3D+3
LDA      [FURTHER TO WITHIN +-PI
3D+4
APO
JMP p+7   [PHI NEG
LDA i     [PHI POS
JMP 1S
STA
2G
STC 2G+10
JMP 2G
LDA i
JMP 1A
JMP p-6
#2G JMP XX
2Z [PI
3D+3
2Z+6
LDA
2Z+7
APOi
JMP p+5   [|PHI| L.T. PI
JMP XX
3D+3
2Z+3 [2PI
3D+3
LDA [STORE FILTERED SIGNAL IN 12,13,14
3D+2 [EXP AMP
STA 4
LDA
3D+5 [EXP PHI
STA 5
UMB 13
LDA
3D+1
STA 4
LDA
3D+4
STA 5
UMB 12
LDA
3D
STA 4
LDA
3D+3
STA 5
XSK i 4 [FINISHED?
JMP p+2 [NO
JMP p+4 [YES
LDA i 4
LDA i 5
JMP 3N+4
JMP 3B
#3F 0
0
0
0
0
0
#3D 0
0
0
0
0
0
#3Y -5   [RADS. PER DEGREE
2167
3200
#3A SETi4
2000
SET i 5
2000
UMB12
LDA4
STC3F
LDA i 5
STC 3F+3
UMB 13
LDA 4
STC 3F+1
LDA 5
STC 3F+4
UMB 14
LDA 4
STC 3F+2
LDA 5
STC 3F+5
JMP 1W [COS PHAS
3F+3
3D
JMP 1Y [SIN PHAS
3F+3
3D+3
JMP 1M [AMP#COS
3F
3D
3D
JMP 1M [AMP#SIN
3F
3D+3
3D+3
LDA
3D
UMB 15
STA 4
LDA
3D+3
STA 5
UMB 16
LDA
3D+1
STA 4
LDA
3D+4
STA 5
UMB 17
LDA
3D+2
STA 4
LDA
3D+5
STA 5
XSK i4
JMP p+2
JMP p+4
LDA i4
LDA i 5
JMP 3A+4
#3B LMB 0
JMP 104
#2Z 2 [PI
3110
1767
3 [2PI
3110
1767
X [TEM
X
X
2A=2034 [ADD OF 2A IN DIS PRO
2L=2154 [ADD IN DIS PRO
2E=2073 [ADD IN DIS PRO
2F=2025 [ADD IN DIS PRO
[END OF FILTER
[TO OBTAIN THE 
[FILTERED SIGNAL
[AND TO CV FROM
[AMP AND PHASE TO
[REAL AND IMAG.
[2PIRLESD
[REDUCES X TO WITHIN APPROX +-2*PI
[DOUBLE PRECISION
[USES FLOD-1R 1A,1S,1N,1R,1H,1Q,1X
[JMP 1V
[ADDR X
[ADDR RESULT
[
[2*PI  1V-3
3
3110
1767
#1V CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC 1V+26
ADD 3
STC 1V+43
LDAi
JMP 1S
STC 1V+40
LDA 2
STA 3
LDA i2
STA i3
LDA i2
STA i3
JMP 1V+44
LDA 2 [1V+21
COM
ADA i
4
APOi
JMP RETURN [1V+26
LDA
2
STC 1V+41
LDAi2
APOi
JMP p+4
LDAi
JMP 1A
STC p+1
JMP 1S [1V+40
ADDR X [1V+41
1V-3
ADDR RESULT 1V+43
SET 2
p-2
JMP 1V+21
[END 2PIRLESD
[JAN 9|2|69
[MOD: MJM 3-11-70
$1000
[FLOSBASE
[FLOD-1R PIECED
[BASIC ROUTINES
[1N,1R,1X,1Q,1H
[TEMPORARY STORAGE
0
0
[NORMALIZE STEP
#1N LDA i
0
LAM
p-2
SCR 14
LDA i
0
LAM
p-2
OVF
JMP 0
ROR i 1
BCO i
0
STA i 3
ROL i 1
ZTA
BCO
p-5
ROL 1
ROR i1
STA i 3
[NORMAL EXIT
#1R NOP      [*  #1R LDA i 4
JMP p    [*      JMP 4
[SET INDEX REGISTERS
ADD 1Q+1 [+1
ADD 1Q+1
#1X ADD 1Q+1
STA
1R+1     [*    4
ADA i
-6003 [CONSTANT 1774
STC 3
LDA 3
STC 1
LDA i3
STC 2
LDA i3
STC 3
JMP 0
[ADJUST EXPONENT
#1Q LDA i
1
ADM 3
OVF
JMP 0
APO [SKIP IF UNDERFLOW
[ERROR STOP OR RETURN
#1H HLT      [*  #1H JMP 4
CLR
STA 3
STA i3
JMP 1R-1
[END FLODBASE
[JAN 6|26|69
[ADDD
[FLOD-1R PIECED
[ADD
#1A CLR
ADD 0
JMP 1X-2
LDA 1
COM
ADA 2
OVF
JMP p+4
SCR 14 [1A+10
BCO i
-40
APO i
JMP 1A+101
STC 1N-1
STC 1N+15
[SET UP ADDITION
[REG1 POINTS TO
[ADDEND WITH LARGER
[EXPONENT
[
LDA 2
STC 1N+6 [SMALLER EXPONENT
LDA 1
STA 3 [LARGER EXPONENT
LDA i 2
LDA i1
AZE
JMP p+5
[ADDEND WITH LARGER
[EXPONENT IS ZERO
ADD 1N+6
STA 3
JMP 1A+101 [SWAP
[LOAD LEFT HALF
[OF LARGER
LDA 1
STC 1N+6
[LOAD RIGHT HALF OF LARGER
LDA i 1
ROL 1
STC 1N+1
[SCALE SMALLER
ADD 1N-1
JMP 1A+110
STC 1A+53
[CLEAR LINK
ROL i1
ZTA
ROL 1
ZZZ
ADD 1Q+1 [+1
[RIGHT + RIGHT
LAM 
1N+1
SCR 14
[LEFT + LEFT
LDA i
0    [1A+53
LAM
1N+6
OVF
JMP p+6
[OVERFLOW:INDEX EXP. AND SCALE RIGHT 1
JMP 1Q
LDA
1N+6
ROR i 1
JMP 1N+16 [EXIT
STC 0
LAM
1N+1
STC 0
LAM
1N+6
AZE    [1A+73
JMP 1A+136
SAE
1N+1
JMP 1A+136
JMP 1H+1 [ZER0 RESULT
[SWAP REG1 AND REG2
STC 1N-2 [1A+101
ADD 2
SET 2
1
STC 1
ADD 1N-2
JMP 0
[24-BIT SCALE
APO   [1A+110
COM   [1A+111
ADA i
-14
SCR i 1
ROL i 1
[IF SCALE>14, L=0
APO i
ADD p-4
APO i
CLR
ADD 1A+130
STC 1A+134
LDA 2
STC 1N-2
LDA i 2
ROL 1
SCR 14 [1A+130
ADD 1N-2
LZE i
SCR 14
SCR X  [1A+134
JMP 0
[CLEAR LINK
ROL i1 [1A+136
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[END ADDD
[JAN 6|26|69
[SUBD
[FLOD-1R PIECED
[SUBTRACT
#1S CLR
ADD 0
JMP 1X-2
LDA 2
STC 1S+16
LDA i2
COM
STC 1S+17
LDA i2
COM
STC 1S+20
SET i2
1S+16
JMP 1A+3
[TEMPORARY STORAGE
0 [1S+16
0
0
[END SUBD
[JAN 6|26|69
[MULD
[FLOD-1R PIECED
[MULTIPLY
#1M CLR
ADD 0
JMP 1X-2 [SET INDEX REGISTERS
LDA 2 [COMPUTE EXPONENT
ADA 1
JMP 1Q+3
STA 3
LDA i 2 [SET UP MULTIPLICANDS
STC 1N-1 [LWFT HALF
LDA i 2
STC 1N-2 [RIGHT HALF
LDA i 1
MUL [L1 X L2
4000+1N-1
AZE i
JMP 1H+1 [PRODUCT ZERO
LZE
COM
STC 1N+6
ZTA
STC 1N+1
LDA 1
MUL [L1 X R2
4000+1N-2
LZE
COM
ADM 
1N+1
ZTA
STC 1M+60
LZE
COM
STC 1N+15
LDA i 1
MUL [R1 X R2
4000+1N-2
LZE
COM
ADM 
1M+60
LDA 1
MUL [R1 X L2
4000+1N-1
LZE
COM
STC 0
ZTA
LAM i
0 [1M+60
BCL i 
3777
ROL i 2
LAM 
0
LAM
1N+1
BCL i
3777
ROL i 2
LAM 
1N+6
LDA
1M+60
ROL i 2
LDA 
1N+1
ROL i 1
STC 1N+1
[ CLEAR LINK
ROL i 1 [1M+104
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[END MULD
[JAN 6|26|69
[DIVD
[FLOD-1R PIECED
[DIVIDE
#1D CLR
ADD 0
JMP 1X-2
[COMPUTE EXPONENT
LDA 2
COM
ADA 1
STA 3
JMP 1Q+3
JMP 1Q
[SET SIGN
LDA i 2
BCO i 1
SCR 14
STC 1N+15
[CLEAR QUOTIENT
STC 1N+1
STC 1N+6
LDA 2
AZE i
JMP 1H [DIVISOR ZERO
APO i
COM
BCL i 
4000 [1D+25
[LEFT DIVISOR
STC 1D+37
LDA i 2
APO i
COM
[CLEAR SIGN AND ADD +1
ADD 1D+25
ROL i 1
ROR 1
[RIGHT DIVISOR
STC 1N-2
LAM i
0 [1D+37
LDA 1
AZE i
JMP 1H+1
APO
COM
[LEFT DIVIDEND
STC 1D+100
LDA i 1
APO
COM
[RIGHT DIVIDEND
STC 1N-1
JMP 1D+105 [TRIAL SUB
APO
JMP p+10
LDA i
-1 [CONSTANT
JMP 1Q+2
JMP 1D+73 [DIVIDE LOOP
JMP 1D+105 [TRIAL SUB
APO i
JMP 1D+73
[SUBTRACTION SUCCEEDED
ROL i 1
STC 1D+100
ZTA
ROL 1
BCL i 
4000
JMP 1D+102
[SUBTRACTION FAILED
CLR [1D+73
ADD 1N-1
SCR 12
ADD p+2
ADM i
0 [1D+100
ZTA
STC 1N-1 [1D+102
JMP 1N
JMP 1D+61 [CLOSE LOOP
[TRIAL SUBTRACT SR
CLR [1D+105
ADD 1N-1
ADD 1N-2
ROR i 1
SCR i 12
ADD 1D+100
ADD 1D+37
JMP 0
[END DIVD
[JAN 6|26|29
[COSSIND
[COS OR SIN OF X
[DOUBLE PRECISION
[TAYLOR SERIES
[USES FLOD-1R 1A,1M,1S,1D,1R,1Q,1H,1N,1X
[JMP 1W [COS, 1Y FOR SIN
[ADDR X
[ADDR RESULT
[
[COS OF X
[ONE  1W-22
1
2000
0
[POWER OF X 1W-17
0
0
0
[FACTORIAL  1W-14
0
0
0
[TERM  1W-11
0
0
0
[X"2  1W-6
0
0
0
[N  1W-3
0
0
0
#1W CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC 1W+121
ADD 3 [ADDR RESULT
STA
1W+116
STA
1W+106
STC 1W+110
[ONE TO SUM,POWER X,FACT
ADD 1W-22
STA 3
STA
1W-14
STC 1W-17
ADD 1W-21
STA i3
STA
1W-13
STC 1W-16
STA i3
STC 1W-12
STC 1W-15
[0 TO N
STC 1W-3
STC 1W-2
STC 1W-1
LDAi
JMP 1A
STA
1W+105
BCOi
JMP 1S
STC 1W+103
ADD 2
STA
p+6
STC p+6
LDAi2
AZEi
JMP 1W+121
JMP 1M
ADDRX
ADDR X
1W-6
[LOOP
JMP 1M [1W+55
1W-17
1W-6
1W-17
JMP 1A
1W-22
1W-3
1W-3
JMP 1M
1W-3
1W-14
1W-14
SROi
2525
JMP p-12
JMP 1D
1W-17
1W-14
1W-11
LDA
p+4
BCOi
ALTERNATE + , - 1W+103
STC p+1
JMP 1S [1W+105
ADDR RESULT [1W+106
1W-11
ADDR RESULT
LDAi
30
ADD 1W-11
COM
ADA
ADDR RESULT [1W+116
APO
JMP 1W+55
RETURN [1W+121
[ENTER SIN OF X
#1Y CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC 1W+121
ADD 3
STC 1Y+20
ADD 2
STC p+3
JMP 1S
1Y+23
ADDR X
1W-11
SET i2
1W-11
SET i3
ADDR  RESULT [1Y+20
CLR
JMP 1W+5 
1  [PI|2  1Y+23
3110
1762
[END COSSIND
[JAN 9|1|69
[FLFRD
[FLOD-1R PIECED
[FLOAT FRACTION
#1F CLR
ADD 0
JMP 1X-1
STC 1N-1
STC 1N+15
LDA 2
STC 1N+6
ADD 1N-1 [EXPONENT
STA 3
LDA i 2
ROL 1
STC 1N+1
ADD 1N+6
AZE   
JMP 1F+23
SAE
1N-1
JMP 1F+23
JMP 1H+1 [ZERO RESULT
[ CLEAR LINK
ROL i1 [1F+23
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[END FLFRD
[JAN 6|26|69
[FLINTD
[FLOD-1R PIECED
[FLOAT INTEGER
#1I CLR
ADD 0
JMP 1X-1
LDA i
26
JMP 1F+3
[END FLINTD
[JAN 6|26|69
[SAMSETUP
SET i 1
-1000
SET i 2
0
SET i 3
4A
#4B SXL i 5
JMP p-1
SXL 4
JMP p-1
SAM 4
COM
STC 4A
DIS 3
XSK i 2
XSK i 1
JMP p+2
JMP 4B
SXL i 4
JMP p-1
SAM 4
COM
STC 4A
DIS 3
XSK i 2
XSK i 1
JMP 4B+4
KST
JMP 4B
LMB 0
JMP 104
#4A 0000
[XXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXX