Directory of image this file is from
This file as a plain text file

[FLOD
[SUBTRACT, FLOAT, FIX
$1176
[ENTER SUBTRACT
#1S CLR
ADD O
JMP 1X-2
LDA 2
STC 1M+112
LDA i2
COM
STC 1M+113
LDA i 2
COM
STC 1M+114
SET i2
1M+112
JMP 1A+3
[FLOAT INTEGER
#1I LDA i
26
APO
[FLOAT FRACTION
#1F CLR
STC 1M+112
STC 1N+15
ADD O
JMP 1X-1
LDA 2
STC 1N+6
ADD 1M+112
[EXPONENT
STA 3
LDA i 2
ROL 1
STC 1N+1
CLR
JMP 1A+144
[FIX INTEGER
#1J LDA i
-26
APO i
[FIX FRACTION
#1G CLR
STC 1G+7
STC 1N+15
ADD O
JMP 1X-1
[CONTAINS ZERO ON RETURN
COM
ADA i
O
ADA 2
APO i
JMP 1H [OVERFLOW
COM
ADD 1A+12 [-14
APO i
JMP 1G+23
ADD 1A+10 [SCR 14
STC 1G+40
ADD 1A+25 [SCR 0
JMP 1G+31
ADD 1A+12 [-14
APO i
STC 0
ADD 1A+10 [SCR 14
STC 1G+40
ADD 1A+10 [SCR 14
STC 1G+41
LDA i2
STC p+4
LDA i2
SCR 13
LDA i
0 [LEFT HALF
SCR
SCR
STA 3
JMP 1R-7
[FLOD
[KERNEL
[PORTIONS FOLLOWING
[THIS POINT
[INTERACT STRONGLY
[WITH ONE ANOTHER
$1304
[ENTER MULTIPLY
#1M CLR
ADD 0
JMP 1X-2 [SET INDEX REGISTERS
LDA 2 [COMPUTE EXPONENT
ADA 1
JMP 1Q+3
STA 3
LDA i 2 [SET UP MULTIPLICANDS
STC 1M+113 [LEFT HALF
LDA i 2
STC 1M+112 [RIGHT HALF
LDA i 1
MUL [L1 X L2
4000+1M+113
AZE i
JMP 1H+1 [PRODUCT ZERO
LZE
COM
STC 1N+6
ZTA
STC 1N+1
LDA 1
MUL [L1 X R2
4000+1M+112
LZE
COM
ADM 
1N+1
ZTA
STC 1M+60
LZE
COM
STC 1N+15
LDA i 1
MUL [R1 X R2
4000+1M+112
LZE
COM
ADM 
1M+60
LDA 1
MUL [R1 X L2
4000+1M+113
LZE
COM
STC 0
ZTA
LAM i
0 [1M+60
BCL i 
3777
ROL i 2
LAM 
0
LAM
1N+1
BCL i
3777
ROL i 2
LAM 
1N+6
LDA
1M+60
ROL i 2
LDA 
1N+1
ROL i 1
STC 1N+1
ROL i1
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[TEMPORARY
[STORAGE
0 [1M+112
0
0
[NORMALIZE STEP
#1N LDA i
0
LAM
p-2
SCR 14
LDA i
0
LAM
p-2
OVF
JMP 0
ROR i 1
BCO i
0
STA i 3
ROL i 1
ZTA
BCO
p-5
ROL 1
ROR i1
STA i 3
[NORMAL EXIT
#1R NOP   [# LDAi4
JMP 4 [# JMP 4
[DIVIDE
#1D CLR
ADD 0
JMP 1X-2
[COMPUTE EXPONENT
LDA 2
COM
ADA 1
STA 3
JMP 1Q+3
JMP 1Q
[SET SIGN
LDA i 2
BCO i 1
SCR 14
STC 1N+15
[CLEAR QUOTIENT
STC 1N+1
STC 1N+6
LDA 2
AZE i
JMP 1H [DIVISOR ZERO
APO i
COM
BCL i 
4000 [1D+25
[LEFT DIVISOR
STC 1D+37
LDA i 2
APO i
COM
[CLEAR SIGN AND ADD +1
ADD 1D+25
ROL i 1
ROR 1
[RIGHT DIVISOR
STC 1M+112
LAM i
0 [1D+37
LDA 1
AZE i
JMP 1H+1
APO
COM
[LEFT DIVIDEND
STC 1D+100
LDA i 1
APO
COM
[RIGHT DIVIDEND
STC 1M+113
JMP 1D+105 [TRIAL SUB
APO
JMP p+10
LDA i
-1 [CONSTANT
JMP 1Q+2
JMP 1D+73 [DIVIDE LOOP
JMP 1D+105 [TRIAL SUB
APO i
JMP 1D+73
[SUBTRACTION SUCCEEDED
ROL i 1
STC 1D+100
ZTA
ROL 1
BCL i 
4000
JMP 1D+102
[SUBTRACTION FAILED
CLR [1D+73
ADD 1M+113
SCR 12
ADD p+2
ADM i
0 [1D+100
ZTA
STC 1M+113 [1D+102
JMP 1N
JMP 1D+61 [CLOSE LOOP
[TRIAL SUBTRACT SR
CLR [1D+105
ADD 1M+113
ADD 1M+112
ROR i 1
SCR i 12
ADD 1D+100
ADD 1D+37
JMP 0
[ENTER ADD
#1A CLR
ADD 0
JMP 1X-2
LDA 1
COM
ADA 2
OVF
JMP p+4
SCR 14 [1A+10
BCO i
7763 [1A+12
SCR i 1
ROL i 1
LZE
COM
ADD 1A+12
APO i
JMP 1A+27
ADD 1A+10 [SCR 14
STC 1A+106
ADA i
SCR 0
JMP 1A+35
ADD 1A+12 [1A+27
APO i
STC 0
ADD 1A+10 [SCR 14
STC 1A+106
ADD 1A+10 [SCR 14
STC 1A+107 [1A+35
STC 1N+15
[SET UP ADDITION
[LINK BIT SELECTS
[L=1 IF 1 POINTS TO
[ADDEND WITH
[LARGER EXPONENT
LDA 2
LZE i
LDA 1
STC 1N+6 [SMALLER EXPONENT
LDA 2
LZE
LDA 1
STA 3 [LARGER EXPONENT
LDA i1
LDA i2
LZE
LDA 1
AZE
JMP p+6
[ADDEND WITH LARGER
[EXPONENT IS ZERO
[COMPLEMENT LINK BIT
ADD 1N+6
STA 3
ROL i 1
COM
ROR i1
[LOAD LEFT HALF
[OF LARGER
LDA 2
LZE
LDA 1
STC 1N+6
[LOAD LEFT HALF
[OF SMALLER
LDA 2
LZE i
LDA 1
STC 1A+122
[LOAD RIGHT HALF OF LARGER
LDA i 2
LZE 
LDA i 1
ROL 1
STC 1N+1
[LOAD RIGHT HALF OF SMALLER
LDA 2
LZE i
LDA i 1
ROL 1
SCR 14
LDA
1A+122
[SHIFT SMALLER ADDEND
SCR [1A+106
SCR
STC 1A+122
[CLEAR LINK
ROL i1
ZTA
ROL 1
ZZZ
ADD 1Q+1 [+1
[RIGHT + RIGHT
LAM 
1N+1
SCR 14
[LEFT + LEFT
LDA i
0 [1A+122
LAM
1N+6
OVF
JMP p+10
JMP 1Q
LDA
1N+6
SCR 1
BCO i
4000
JMP 1N+16
STC 0
LAM
1N+1
STC 0
LAM
1N+6
STC 0
LAM
1N+1
AZE
JMP p+5
SAE
1N+6
JMP p+2
JMP 1H+1
LDA
1N+6
JMP 1M+104
[SET INDEX REGISTERS
ADD 1Q+1 [+1
ADD 1Q+1
#1X ADD 1Q+1
STA
1R+1  [# 4
ADA i
-6003 [CONSTANT 1774
STC 3
LDA 3
STC 1
LDA i3
STC 2
LDA i3
STC 3
JMP 0
[ADJUST EXPONENT
#1Q LDA i
1
ADM 3
OVF
JMP 0
APO [SKIP IF UNDERFLOW
[ERROR STOP OR RETURN
#1H HLT   [# JMP 4
CLR
STA 3
STA i3
JMP 1R-1
[FLOD
[22 MAY 68
[0945 HRS