Directory of image this file is from
This file as a plain text file

[FLOS
[SUBTRACT, FLOAT, FIX
[THESE OCCUPY 1401-1467
[INCLUSIVE AND ARE NOT
[USED BY KERNEL PROGRAMS
$1401
[ENTER SUBTRACT
#1S CLR
ADD 0
JMP 1X-2
LDA 2
STC 1Q-2
LDA i2
COM
STC 1Q-1
SET i2
1Q-2
JMP 1A+3
[FLOAT INTEGER
#1I LDA i
13 [CONSTANT 13
APO
[FLOAT FRACTION
#1F CLR
STC 1Q-2
STC 1R-2
ADD O
JMP 1X-1
LDA 2
STC p+4 [TO ALLOW FLOAT IN PLACE
ADD 1Q-2
STA 3
LDA i
O
JMP 1A+102
[FIX INTEGER
#1J LDA i
-13 [CONSTANT -13
APO i
[FIX FRACTION
#1G CLR
STC p+4
ADD 0
JMP 1X-1
LDA i
0
ADA 2
JMP 1Q+3 [TEST OVERFLOW
COM
AZE i
CLR
APO
JMP 1H [OVERFLOW
ADD 1A+12 [-14
APO i
CLR
ADD 1A+10 [SCR i14
STC p+2
LDA i2
SCR i14
JMP 1A+114
ADD 1D+36
OVF i
COM
STA 3
JMP 1R
[FLOS
[KERNEL
[ADD, MULTIPLY, DIVIDE
[PORTIONS FOLLOWING
[THIS POINT
[INTERACT STRONGLY
[WITH ONE ANOTHER
$1470
[ENTER MULTIPLY
#1M CLR [SAVE RETURN
ADD 0
JMP 1X-2
LDA 1 [COMPUTE EXPONENT
ADA 2
JMP 1Q+3 [TEST OVERFLOW
STA 3 [STORE EXPONENT
LDA i2 [SET UP MULTIPLICAND
STC 1D+36
LDA i1 [OBTAIN MULTIPIER
MUL
4000+1D+36
AZE i [TEST FOR ZERO
JMP 1H+1 [ZERO RESULT
LZE [OBTAIN PRODUCT MAGNITUDE
COM
SCR 12 [TEST FOR PRODUCT LESS THAN 1|2
AZE
JMP p+4 [PRODUCT GREATER THAN OR EQUAL TO 1|2
ADD 1A+111 [-1
JMP 1Q+2 [DECREM EXPONENT
JMP p+2
SCR 1
ZTA [PICK UP PRODUCT
ZZZ [ROUNDOFF
ADD 1Q+1 [+1
OVF i
COM
LZE [CORRECT SIGN
COM
JMP 1R-1 [STORE MANTISSA AND EXIT
[ENTER DIVIDE
#1D CLR [SAVE RETURN
ADD 0
JMP 1X-2
LDA 2 [COMPUTE EXPONENT
COM
ADA 1
JMP 1Q+3 [TEST OVERFLOW
STA 3 [SAVE EXPONENT
LDA i 2
AZE i
JMP 1H [ZERO DIVISOR
APO [OBTAIN MAGNITUDE OF DIVISOR
COM
STC 1D+40
[SET UP DIVIDEND
LDA i1
AZE i [TEST FOR ZERO DIVIDEND
JMP 1H+1 [ZERO RESULT
BCO 2 [OBTAIN SIGN OF QUOTIENT
SCR 14
STC 1R-2
STC 1N+1
LDA 1
APO i [OBTAIN COMPLEMENT OF DIVIDEND MAGNITUDE
COM
STA 
1D+36
ADD 1D+40 [MAGNITUDE OF DIVISOR
APO [COMPARE MAGNITUDE OF DIVIDEND AND DIVISOR
JMP 1Q [INCREM EXPONENT
[TRIAL SUBTRACTION
LDA i
0 [COMPLEMENT OF DIVIDEND MAGNITUDE
ADA i
0 [DIVISOR MAGNITUDE
SCR i1 [SIGN TO LINK BIT
ROL i 1
APO
JMP p+3
[TRIAL SUBTRACTION FAILED
LDA 
1D+36
ROL 1
STC 1D+36
[GENERATE QUOTIENT
[NOTE ROLE OF LINK BIT
JMP 1N
JMP 1D+35 [DO NEXT TRIAL SUBTRACTION
[ENTER ADD
#1A CLR
ADD 0
JMP 1X-2
LDA 1 [DETERMINE WHICH ADDEND IS LARGER
COM
ADA 2
OVF [SKIP IF MAGNITUDES GROSSLY DIFFERENT
JMP p+4
SCR i14
BCO i
7763 [CONSTANT -14
SCR i1 [SIGN TO LINK BIT
ROL i 1
APO [MAGNITUDE OF EXPONENT DIFFERENCE
COM
ADD 1A+12 [-14
APO i
STC 0
ADD 1A+10 [CONTAINS SCR i14
STC 1A+61
[SET UP ADDITION
LDA 2
LZE i
LDA 1
STC 1D+36 [EXPONENT OF SMALLER ADDEND
LDA 2
LZE [LINK BIT SELECTS LARGER ADDEND
LDA 1
STA 3 [EXPONENT OF LARGER ADDEND
LDA i 1
LDA i 2
LZE
LDA 1
AZE 
JMP p+6
[ADDEND WITH LARGER EXPONENT HAS ZERO MANTISSA
ADD 1D+36
STA 3
ROL i1 [COMPLEMENT LINK BIT
COM
ROR i 1
LDA 2
LZE
LDA 1
STC 1N+1 [MANTISSA OF LARGER ADDEND
STC 1R-2 [SIGN
LDA 2
LZE i
LDA 1
SCR i1 [SIGN TO LINK BIT
ROL i 1
SCR i14 [SCALE DOWN SMALLER ADDEND
JMP 1A+114 [ROUNDOFF
ADM 
1N+1
OVF
JMP p+11
[ASSIMILATE MANTISSA OVERFLOW
SCR 1
BCO i
4000 [CONSTANT 4000
JMP 1A+114
STC 1N+1
JMP 1Q [INCREM EXPONENT
LDA 
1N+1
ADD 1D+36 [ROUNDOFF
OVF i
COM
STA 
1N+1
AZE i
JMP 1H+1 [ZERO RESULT
ROL i1 [SIGN BIT TO LINK
JMP 1N
LDA i
-1 [CONSTANT -1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[ROUNDOFF INTO 1D+36
STA i
0
SCR 14
ROL i 1
STC 1D+36
ADD 1A+115
JMP 0
[NORMALIZE LEFT
[AND ASSIMILATE LINK BIT
#1N LDA i
0
LAM
1N+1
OVF
JMP 0
[NORMALIZE COMPLETED
ROR i 1
JMP 1A+114
ADD 1D+36
OVF i
COM
BCO i [CORRECT SIGN OF MANTISSA
0
STA i3 [STORE MANTISSA
[NORMAL RETURN
#1R NOP      [# LDA i4
JMP p    [# JMP 4
[SET INDEX REGISTERS
ADD 1Q+1 [+1
ADD 1Q+1
#1X ADD 1Q+1
STA
1R+1      [# 4
ADA i
-6003 [CONSTANT 1774
STC 3
LDA 3
STC 1
LDA i3
STC 2
LDA i3
STC 3
JMP 0
[TEMPORARY STORAGE
0
0
[INCREMENT EXPONENT
#1Q LDA i
1 [CONSTANT 1
[DECREMENT EXPONENT
ADM 3
[TEST OVERFLOW
OVF
JMP 0
[OVERFLOW OR UNDERFLOW
APO
[OVERFLOW STOP
[ERROR STOP OR RETURN
#1H HLT      [# JMP 4
CLR
STA 3
JMP 1R-1
[FLOS
[22 MAY 68
[0945 HRS