Directory of image this file is from
This file as a plain text file

*20
	SEGMNT 0
	LIM=10
	AVGPTR=12
	TIME=20
	SBINS=21
	TPEBLK=22
	SAMN=23
	N=24
	WRTBLK=25
	INTAC=26
	*1
	PMODE
	JMP INT+2
	LMODE
	*41
	JMP INT
	*170
INT,	NOP
	PDP
	3026		/DCA INTAC
	6135
	6141
	APO I
	JMP SYNC
	CLR
	IOB
	6234
	STA I
SAVDF,	0
	LDA I
	4100
	SAE I
CS,	0
	JMP US
	SXL 12
	JMP KILTS	/DIFFERENTIAL COND
	FIELD 1
        LDF 5
	SAM 10		/RPD
	STA I 4
FACTOR,	0
	STA I
SAVAC,	0
	QAC
	LAM I 5
	LDA
	SAVAC
	LAM I 6
	XSK I 7
	NOP
ENDTME, XSK I 15	/END OF RUNTIME
	JMP .+2
	JMP ENDBLK
	IOB 
        6001
	XSK I 11
	JMP SMPL
	CLR
	STC INST
	RTA
	BSE I
        0040
	ATR		/KEEP K6 SET,SET K0
	SET I 14
	1777		/SHOW CS TIME
	LDF 5
	LDA
	ONE
	ADM 7
SMPL,   NOP
	CLR
	SAE I
SNKFLG,	0
	SKP
	JMP SAMBCK-5
	LDA
	40
	BSE I
	6000
	STC SAMBCK
	ADD SAVDF
	ROL 2
	BCL I
	7770
	BSE I
	LDF 0
	STC .+1
	0		/LDF CHANGE
	ADD INTAC
	SXL 12
	JMP KILL
	DJR
	IOB
	6001
SAMBCK,	0		/JMP BACK
/
KILL,	LDA I
	SAMBCK
	BSE I
	6000
	STC SAMBCK
	JMP SAMBCK-2
/
KILTS,	XSK I 4
	XSK I 5
	XSK I 6
	XSK I 7
	JMP ENDTME
	JMP ENDTME
ENTER,	LDA
	ONE
	STC SNKFLG
S0,	LDF 7
	SXL I 0
	JMP .+5
	LDA I
ONE,	1
	ADM 4
	SKP
	ROL 12
S1,	SXL I 1
	JMP .+5
	LDA
	ONE
	ADM 5
	SKP
	ROL 12
S2,	SXL I 2
	JMP .+5
	LDA
	ONE
	ADM 6
	SKP
	ROL 12
S3,	SXL I 3
	JMP .+5
	LDA
	ONE
	ADM 7
	SKP
	ROL 12
S4,	LDF 6
        SXL I 4
	JMP .+5
	LDA
	ONE
	ADM 4
	SKP
	ROL 12
S5,	SXL I 5
	JMP .+5
	LDA 
	ONE
	ADM 5
	SKP
	ROL 12
S6,	SXL I 6
	JMP .+5
	LDA
	ONE
	ADM 6
	SKP
	ROL 12
S7,	SXL I 7
	JMP .+5
	LDA
	ONE
	ADM 7
	SKP
        ROL 12
	JMP S0
/
ENDBLK,	SET I 1
	5173
MORE,	LDA I
	0060
	STA
	CS
	LDA I 
INST,	0		/IF =1 RESPONSE BIG,DONT SHOCK
	AZE
	JMP .+5
	RTA
	BSE I
	0060		/KEEP K6 AND K0,SET K1
	ATR
	SET I 13
	-200		/END OF CS TIME SET US (K1) AND CS(K0) FOR 200 BINS
US,	XSK I 13
	JMP ASTART-3	/KEEP RELAYS SET
	RTA
	BCL I
	0060
	ATR		/CLEAR K0 AND K1
TRT,    XSK I AVGPTR
	JMP CLKSET
	JMP AVG
/
SYNC,	ROL 10
        APO I
        JMP TRY3
POINT,  IOB
	6234		/RIB
	ROL 2
	BCL I
	7770
	BSE I
	LDF 0
	STC RESTDF
	LDA
	ONE
	LDF 4
	ADM 7
RESTDF,	0		/RESTORE DF WHERE INTERRUPTED
	LDA
	40
	ADA I
	6000
	STC .+4
	ADD INTAC
	IOB 
	6001
	0		/BACK TO INTERUPPTED POINT
TRY3,	ROL 2
	APO 
	JMP POINT	/EVENT 3 IS US
        SET I 17
TABLE,	2000
	SET 15
BINS,	SBINS
	SET 4
	TABLE
	SET I 5
DELBIN,	2400
	SET I 6
DLBIN2,	3000
	SET I 7
DLBIN3,	3400
	SET I 11
	-200		/PRECS TIMER
	SET I 14
	1		/SHOW CS
	CLR
	STC INST	/SET INSTRUMENTAL POINTER
	STC SNKFLG
	LDA I
	JMP ENTER
	STC SAMBCK
	LDA
	WRTBLK
	ADA I 
	1
	STA
	WRTBLK
	LDA
	TIME
	IOB
	6133		/PRESET TIMER
	LDA I
	4100		/1KC AND PRESET
	STA
	CS		/SHOW SYNC
	IOB
	6132		/CLLR
	IOB
	6135		/CLSA POSSIBLE FLAG
	LDA I
	317		/ENABLE CLOCK
	IOB
	6134		/SET CLOCK INT
	IOB
	6001
	JMP SMPL		/WAIT FOR CLOCK
ASTART,	LDA I  
        4000
	BSE 
	TPEBLK
	STA 
	WRTBLK		/INITIALIZE WRTBLK
	STA
	AVGBLK
	CLR
	ATR		/CLEAR RELAYS
	LDA I
	60
	ESF		/IO PRESET
	CLR
	IOB
	6132		/CLLR TO STOP CLOCK
AVGSET, SET I AVGPTR
	3777
	CLR
	LDF 5
	STA I AVGPTR
	LDF 6
	STA AVGPTR
	LDF 7
	STA AVGPTR
	XSK AVGPTR
	JMP AVGSET+2
	SET I AVGPTR
	-400
	CLR
	SET AVGPTR
	SAMN		/N FOR AVERAGE
	RTA
	BCO I
	0001
	ATR		/FLIP K6
CLKSET,	LDA
	TIME
	IOB
	6133		/CLAB, PRESET NUMBER
	CLR
	IOB
	6132      /CLLR TO STOP CLOCK
	LDA I
	60
	IOB
	6134		/CLEN 
	IOB
	6135		/CLSA TO CLEAR CLOCK
	IOB
	6001
	LIF 1
	JMP DISPLA	/WAIT FOR SYNC ---
/CUT IN HERE FOR TTY SERVICE BEFORE IOB AND 6001
/
/
AVG,	STD
	JMP .-1
	LDA I 
	60
	ESF
	SET I 17
	3777
	CLR
	SET 14
	SBINS
	SNS I 0
	JMP RESET	/SUPPRESS TAPE
	FIELD 1
	LDF 7
	JMP WRTSET
	LDF 6
	JMP WRTSET
	LDF 5
	JMP WRTSET
	JMP RESET
/
WRTSET,	LDA
	0
	STC WRET
	SET I 17
	4000
	JMP SET1
	JMP WRITE
	SET I 17
	5000
	JMP SET1
	JMP WRITE
	SET I 17
	6000
	JMP SET1
	JMP WRITE
	SET I 17
	7000
	JMP SET1
	JMP WRITE
	LDA I
WRET,	0
	STC 0
	JMP 0
/
SET1,	LDA
	0
	STC RET4
	LDA
	AVGBLK
	BCL I
	7000
	BSE
	17
	STC AVGBLK
	LDA I
RET4,	0
	STC 0
	JMP 0
/
WRITE,	LDA 
	0
	STC RET
	LDA
	AVGBLK
	ADA I
	1
	STA
	AVGBLK
	STD
	JMP .-1
	WRI U
AVGBLK,	0
	LDA I
RET,	0
	STC 0
	JMP 0
/
RESET,	SET I 17
	3777
	SET 15
	SAMN
	LDA I
	60
	ESF
	JMP AVGSET
/
/
/
/DISPLAY PROGRAM FOR DATA COLLECTION
/
	SEGMNT 1
	*20
DISPLA,	CLR
	IOB
	6046		/TLS
	LDF 0
	JMP .+1		/ENABLE INTERUPT
	LDA
	SBINS!2000
	STA I
DBINS,	0
	SET I 17
	WRTABL-1
	SET I 16
	-3		/DISPLAY TRIAL NUMBER
	LDA
	WRTBLK!2000
	ROL 3
	STC TEMWRT
UNPACK,	LDA I
TEMWRT,	0
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17	/GET HALF CHAR
	LDA I 3		/GET OTHER HALF
	STA I 17
	XSK I 16
	JMP UNPACK
DISGO,	SET I 17
	WRTABL-1
	SET I 1
	10
	SET I 16
	-6
	SET 3
	DBINS
	LDA I 
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS TRIAL NUMBER
	LDF 0
	SET I 17
	BLKTBL-1
	SET I 16
	-3		/DIS BLOCK NUMBER
	LDA
	AVGBLK!2000
	ROL 3
	STC TEMWRT
BKPACK,	LDA 
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA 
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP BKPACK
DISBK,	SET I 17
	BLKTBL-1
	SET I 1
	600
	SET I 16
	-6
	SET 3
	DBINS
	LDA I
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS BLOCK NUMB
	CLR
	RSW
	BCL I
	7770
	BSE I 
	0640
	STA
	IELD
IELD,	0	/SET DF SELECTED BY RITE SWTCHS
	SNS I 1		/SMALLEST
	JMP .+5
	SET I 2
K3777,	3777
	SAM 1
	JMP DISLOP
	SET I 2
KBMP2,	2377
	SNS I 2
	JMP .+3
	SAM 2
	JMP DISLOP
	SET I 2
KBMP3,	2777
	SNS I 3
	JMP .+3
	SAM 3
	JMP DISLOP
	SET I 2
	LIST
KBMP4,	3377
	SNS I 4
	JMP .+3
	SAM 4
	JMP DISLOP
	SNS I 5
	JMP DISGO	/SUPPRESS INTEGRAL
	IOB
	6031
	JMP DISINT
IO,	IOB
	6036		/KRB
	IOB
	6046
	STA I
ELECT,	0
	ADA I
	-260
	APO
	JMP ERR
	LDA
	ELECT
	ADA I
LIM5,	-264
	APO I
	JMP ERR
	LDA
	ELECT
	BCL I
	7770
	STC ELECT
DISINT,	LDA I
	INTBL-1
	ADA
	ELECT		/FORM SET
	STC 11
	LDA 11
	STC INTSTR
	STC INT1
	STC INT2
	LSW
	BCL I
	7760
	BSE I
	SCR 0
	STC SHIFT
	LDA
	ELECT
	BSE I
	SAM 0
	STC SMPIT
	SET I 12
INTSTR,	0
	SET I 13
	-176
	JMP INTLUP-3
	LDA I
	10
	STC HORIZ
	JMP DISIN
	SET I 13
	-200
	CLR 
	STC INT1
	STC INT2
	JMP INTLUP-3
	LDA I
	600
	STC HORIZ
	JMP DISIN
/SCALE FACTOR
	SET I 17
	CSTBL-1
	SET I 16
	-3
	LDA
	SHIFT
	BCL I
	7760
	ROL 3
	STC TEMWRT
SCPACK,	LDA
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP SCPACK
	SET I 17
	CSTBL-1
	SET I 1
	400
	SET I 16
	-6
	LDA I
	-300
	DSC I 17
	XSK I 16
	JMP .-4
	JMP DISGO
/
	LDA
	0
	STC JMPLUP
INTLUP, LDA I 12
	APO
	COM		/ABS VALUE
SHIFT,	0
	STA I
ACSAVE,	0
	QAC
	LAM I
INT1,   0
	LDA
	ACSAVE
	LAM I
INT2,   0
SMPIT,	0
	ADA 
	INT2
	DIS 12
INTOUT, XSK I 13
	JMP INTLUP
	LDA I
JMPLUP,	0
	STC 0
	JMP 0
/
INTBL,	2001
	2401
	3001
	3401
/
ERR,    PDP
	PMODE
	TSF
	JMP .-1
	CLA CLL
	TAD K277
	TLS		/TYPE ?
	TSF
	JMP .-1
	CLA CLL
	TAD K215
	TLS
	TSF
	JMP .-1
	CLA CLL
	TAD K212	/CRLF
	TLS
	KSF
	JMP .-1
	LINC
	LMODE
	JMP IO
	PMODE
K277,	277		/?
K215,	215
K212,	212
	LMODE
/
/
DISIN,	LDA
	0
	STC RET17
	SET I 17
	INTABL-1
	SET I 16
	-4
	LDA
	INT2
	STC INTWRD
INPACK,	LDA I
INTWRD,	0
	ROL 3
	STA
	INTWRD
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP INPACK	/SET UP INTEGRAL FOR PRECS
	SET I 17
	INTABL-1
	SET I 1
HORIZ,	0
	SET I 16
	-10
	LDA I
	-300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS PRECS INT
/
	LDA I
RET17,	0
	STC 0
	JMP 0
/
CSTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
INTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/DISPLAY SUBROUTINE
DISLOP,	STA I
DTEM,	0
	LDA
	0
	STC DRET
	SET 3
	DBINS
	XSK I 2
	LDA
	DTEM
	ADA 2
	DIS 2
	XSK I 3
	JMP .-6
	LDA I
DRET,	0
	STC 0
	JMP 0
/
/
PATERN,	4136
	3641
	2101
	0177
	4523
	2151
	4122
	2651
	2414
	0477
	5172
	0651
	1506
	4225
	4443
	6050
	5126
	2651
	5120
WRTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	00
	0
	0
	0
	0
	0
	0
	0
	0
BLKTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	NOLIST
/
/
	SEGMNT 2
	*20
AAHERE,	CLR		/STARTING POINT FOR PROGRAM
	IOB
	6046
	LDF 0
	JMP QAINIT
	COMNT
	ANSWER
	JMP QARFSH
	JMP QAINIT
	QEST1
	ANSWER
	JMP QARFSH	/GET TAPEBLOCK AND N FOR AVG
	LDA I
TIMSET,	-3
	STA 
	TIME!2000	/SET TIME TO 10 MSEC PER BIN
	LDA I
	-400
	STA
	SBINS!2000	/SET BINS TO 256
	SET I 14
	ANSWER
	CLR
	STA I
TEMP,	0
	JMP FETCH
	JMP RTEMP	/GET TAPEBLOCK
	COM
	STA
	TPEBLK!2000
	CLR
	STC TEMP
	LDH I 14
	JMP FETCH	/GET N FOR AVG
	JMP RTEMP
	STA
	SAMN!2000
	COM
	STA
	N!2000
DWLSET,	CLR
	JMP QAINIT
	OPTION
	ANSWER
	JMP QARFSH
	SET I 14
	ANSWER
	CLR
	STA
	TEMP
	JMP FETCH
	JMP RTEMP	/GET DWELL TIME
	COM
	SAE I
	10		/10 MSEC
	SKP
	JMP TENSET
	SAE I
	4
	SKP
	JMP FORSET
	SAE I
	3
	SKP
	JMP TRESET
	SAE I
	1
	SKP
	JMP ONESET
	JMP DWLSET  
TENSET,	LDF 0
	LDA I
	-11
	STA
	TIME!2000
	JMP WAIT
/
/
/
FORSET,	LDF 0
	LDA I
	-3
	STA
	TIME!2000
	JMP WAIT
/
TRESET, LDF 0
	LDA I
	-2
	STA
	TIME!2000
	JMP WAIT
/
ONESET,	LDF 0
	LDA I
	7777
	STA
	TIME!2000
 WAIT,	JMP QAINIT
	COACH
	ANSWER
	JMP QARFSH
PATCH,	JMP GETFTR
ANSWER,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
FETCH,	SET I 13
	-3
	LDH I 14
	BCL I
	7770
	ADD TEMP
	ROL 3
	STC TEMP
	XSK I 13
	SKP
	JMP 0
	DJR
	JMP FETCH+2
QEST1,	TEXT ZFSTART TAPE BLOCK<3
FN FOR AVG<3\Z
COACH,	TEXT ZFDATA ARE COLLECTED
FON TAPE 1
FDEPRESS LF TO START<1\Z
COMNT,  TEXT ZFALL ANSWERS IN OCTAL
FRESTART BY I/O PRESET
FAND DEPRESSING START
F20
F NOW - L/F<1\Z
OPTION,	TEXT ZFDWELL TIME PER BIN
F1=1 MSEC
F3=3 MSEC
F4=4 MSEC
F10=10 MSEC
F <3\Z
/
/
/SCALE FACTOR SUBROUTINE TO SET FACTOR
	CNTR=11
GETFTR,	CLR
	STC CNTR
	LDA
	N!2000
	ROR I 1
	LZE 
	JMP .+3
	XSK I CNTR	/BMP CNTR, LINK=0
	JMP .-4
	LDA I
	SCR 0
	BSE
	CNTR
	STA
	FACTOR!2000
	LDF 3
	LIF 0
AATCH,	JMP ASTART
/
RTEMP,	LDA
	TEMP
	ROR 3
	COM
AA,     JMP 0
	NOLIST
/QANDA SUBROUTINE FOR THE
/PDP-12
/REMOVE *1000 BELOW IF
/INSERTING SOURCE DIRECTLY
/INTO YOUR PROGRAM SOURCE
 *1000/REMOVE,IF DESIRED
/
/TO HERE TO INITIALIZE THE ROUTINE
/
QAINIT,	LDA I		/SAVE JMP RETURN
	2
	ADD 0
	STA I
QAB,	0		/JMP 	+3
	ADD QAL+3
	STC 1		/PTR TO FIRST PARAM
	LDA 1		/GET FIRST PARAM
	ADD QAQ+1	/PTR TO HALFWORD-1
	STC QAG-3
	LDA I 1
	STC QARFSH-1
	STC 6		/XR6 USED AS A SWITCH. =0 IF NO ANSWER FIELD, =1777 IF YES
QACA,	SET 3	/XR3 TO PTR TO ANSWERS
	QARFSH-1
	SET 4		/XR4 TO PTR TO QUESTIONS
	QAG-3
			/TO HERE IF FIRST TIME THROUGH OR FOLLOWING A CR
	SET 1
	4
	JMP QAT
	NOP		/F
	LDH I 4		/H. BUMP PTR IF H OR F
QAD,	JMP QAO
	JMP .+6		/74
	JMP QAE		/34
	SAE I		/CR?
	43
	JMP QAD		/NO
	JMP QACA+4 /EXAMINE NEXT CHAR
			/INITIALIZE ANSWER BUFR
	STH 3		/74 TO ANSWERS
	LDH I 4		/NEXT HALFWORD
	ADA I
	-60
	COM
	STC 6
	STH I 3		/0 IN AC
	XSK I 6
	JMP .-2
	LDH I 3		/BUMP PTR TO ANSWERS
	JMP QAD
			/ANSWER BUFR IS INITIATED
QAE,	STH 3
	SET I 4		/XR4 TO PTR TO LAST TYPED CHAR IN ANSWER BUFR
	0
			/----RE-ENTER HERE TO REFRESH----
QARFSH,	LDA I		/INITIAL Y POSITION
277
	STC QAH-1
	SET I 3		/XR3 TO PTR TO HALFWORD QUESTIONS-1
	0
	SET 5		/XR5 TO PTR TO LAST DISPLAYED CHAR IN ANSWER BUFR
	QARFSH-1
QAG,	SET 1
	3
	JMP QAT
	JMP .+7		/F
	LDH I 3		/H. BUMP PTR
	LDA I		/NEITHER. ASSUME HALF SIZE
	BCL I
	STC QAM+2	/SET INSTR TO CLEAR FF FOR HALF SIZE
	ADD QAW		/NOP IN AC
	JMP QAM
	LDH I 3		/BUMP PTR
	LDA I
	BSE I
	STC QAM+2	/SET INSTR TO SET FF FOR FULL SIZE
	ADD QAW+1	/ADD 9U IN AC
QAM,	STC QAP+3
	MSC I 4		/EAD CONTROL REGISTER
	BSE I		/THIS INSTR CHANGES. EITHER BSE & OR BCL &
	200
	MSC 4		/AC TO CONTROL REGISTER
	SET I 1		/XR1 TO INITIAL X POSITION
	100
	LDA I		/Y COORDINATE MULTIPLE
	-40
	ADM I		/Y COORDINATE
	0
QAH,	LDH I 3
	JMP QAO+1
	JMP QAZ		/74 BUMP PTR TO NEXT CHAR, PUT 40 IN AC
	JMP QAJ		/34
	SHD I		/NEITHER
	4300
	JMP QAG		/CR. MOVE X AND Y COORDINATE
	JMP QAP		/ISPLAY CHAR
	JMP QAH		/PICK UP NEXT CHAR
	JMP QAP		/TO HERE IF DISPLAYING ANSWER BUFR
	SRO I	/SWITCH TO DISPLAY CURSOR. EITHER 0000 OR 7777
	0		/IFXR4=XR5, THEN SWITCH=7777
	JMP QAF
			/QUESTION MODE
QAI,	LDH I 5
	JMP QAO+1
	JMP QAH		/74
	JMP QAH		/34
	JMP QAI-4	/NEITHER. DISPLAY IT
QAJ,	JMP GETKBD	/TO HERE IF DISPLAYED BUFFER
	AZE I
	JMP QAB	/NOTHING TYPED . EXIT
	SET I 2
	QAY
	SHD 2		/LF?
	JMP QAK+4	/YES. EXIT
	SHD I 2		/CR?
	JMP QAN
	XSK 6		/IS THERE AN ANSWER FIELD?
	JMP QARFSH
	SHD I 2		/<?
	JMP QAL
	SHD I 2		/>?
	JMP QAK
	SHD I 2		/ALT?
	JMP QACA /REINITIALIZE
	SHD I 2		/BACK SLASH?
	JMP QARFSH	/IGNORE
	SHD I 2		/RUBOUT?
	JMP QAL		/IGNORE
	SHD I 2		/TAB?
	JMP QARFSH	/IGNORE
	STC .+5		/ACCEPTABLE CHAR
	JMP QAO		/TEST NEXT CHAR
	JMP QAQ		/74 BACK PTR UP BY 1
	JMP QAQ		/34 ^
	LDA I		/OK. STORE IT
	0
	STH 4
	JMP QARFSH	/REDISPLAY
QAL,	LDH 4		/TO HERE IF RUBBOUT OR <
	JMP QAO+1
	JMP QARFSH	/74 IGNORE
	-6002
	LDH 2		/TEST THE CHAR
	SAE I		/RUBOUT?
	37
	JMP QAQ		/NO. BACK PTR UP BY 1
	SET 5
	4
	SET 3
	4
	JMP .+2
	LDH I 5		/BUMP PTR
	LDH I 3		/GET NEXT CHAR
	JMP QAO+1
	NOP		/IF 74 OR 34, REPLACE CURRENT CHAR WITH 0
	CLR
	STH 5
	AZE		/WAS IT 74 OR 34?
	JMP .-7		/NO. CONTINUE
	JMP QAQ		/BACK PTR UP BY 1
			/TO HERE IF CR
QAN,	XSK 6	
	JMP QAK+4	/EXIT ROUTINE IF NO ANSWER FIELD
	JMP QAO
	JMP QARFSH	/74 MOVE PTR TO NEXT QUESTION FIELD
	JMP QAE+1	/34 END OF BUFR. MOVE PTR TO FIRST QUESTION FIELD
	JMP QAN+2
	
QAO,	LDH I 4		/S\R
	SHD I		/	+1 74 BEGIN FIELD
	7400		/	+2 34 END BUFR
	JMP 0		/	+3 NEITHER 74 NOR 34
	SAE I
	34
	XSK I 0
	XSK I 0
	JMP 0
			/S\R TO DISP LINC CHAR IN AC
QAP,	ROL 1		/MULT BY 2 FOR INDEX TO ADDRESS OF TABLE
	ADD QAX+4
	STC 2		/ADDRESS OF CHAR TO DISP IN XR2
	ADD QAU		/THIS INSTR CHANGES. EITHER OP OR ADD 9U
	ADD QAU
	ADD 1		/ADD 4 TO XR1 TO SPACE CHAR
	STC 1
	ADD 5		/GET ADDRESS OF ANSWER BUFR
	COM
	ADD 4
	AZE
	CLR
	STC QAI-2	/SWITCH=0 OR 7777
	ADD QAH-1	/Y COORDINATE IN AC
	DSC 2
	DSC I 2		/DISPLAY CHAR
	JMP 0
QAQ,	LDA I		/BACK UP PTR BY 1
	-4000
	ADM
	4
	JMP QARFSH	/REDISPLAY
			/
QAT,	LDH I 1		/S\R
	SHD I		/	+1 F
	0600		/	+2 H
	JMP 0		/	+3 NEITHER
	SAE I
	10
	XSK I 0
	XSK I 0
	JMP 0
			/
QAZ,	LDH I 3
	LDA I
	40
	JMP QAI-4
			/TO HERE IF >
QAK,	LDH I 4
	AZE I		/IS CURRENT CHAR BLANK?
	JMP QAQ		/YES. IGNORE
	JMP QAX		/MOVE DOT FORWARD
			/TO HERE TO EXIT WITH SKIP
	LDA I
	1
	ADM
	QAB
	JMP QAB
			/CHARACTER PATTERNS
QAV,	0101		/KBD 0, ILLEGAL. USED AS MARKER
	0101
	4477		/1:A
	7744
	5177		/2:B
	2651
	4136		/3:C
	2241
	4177		/4:D
	3641
	4577		/5:E
	4145
	4477		/6:F
	4044
	4136		/7:G
	2645
	1077		/10:H
	7710
	7741		/11:I
	0041
	4142		/12:J
	4076
	1077		/13:K
	4324
	0177		/14:L
	0301
	3077		/15:M
	7730	
	3077		/16:N
	7706	
	4177		/17:O
	7741
	4477		/20:P
	3044
	4276		/21:Q
	0376
	4477		/22:R
	3146
	5121		/23:S
	4651
	4040		/24:T
	4077
	0177		/25:U
	7701	
	0176		/26:V
	7402
	0677		/27:W
	7701
	1463		/30:X
	6314
	0770		/31:Y
	7007
	4543		/32:Z
	6151
	4177		/33:/
	0000
			/34:BACKSLASH IGNORED ON INPUT
	0		/NOT USED
	0		/NOT USED
	0000		/35:]
	7741
			/CODES 36:ALT, 37:RUBOUT NOT DISPLAYED
QAY,	4543		/LF,CR
	7476		/<,>
	3634		/ALT, BACKSLASH
	3747		/RUBOUT, TAB
	0000		/40:SPACE
	0000
	7500		/41:X!
	0000
	7000		/42:"
	0070
			/CODES 43:, 44:, 45:LF NOT DISPLAYED
QAX,	JMP QAO+1
	JMP QAQ
	JMP QAQ
	JMP QARFSH
	QAV
	0		/NOT USED
	5166		/46: &
	0526
			/CODE 47:TAB NOT DISPLAYED
	0		/NOT USED
	0		/NOT USED
	3600		/50:(
	0041
	4100		/51:)
	0036
	2050		/52:*
	0050
	0404		/53:+
	0437
	0500		/54:,
	0006
	0404		/55:-
	0404
	0001		/56:.
	0000
	0601		/57:\
	4030
	4536	/60:0
	3651
	2101		/61:1
	0177
	4523		/62:2
	2151
	4122		/63:3
	2651
	2414		/64:4
	0477
	5172		/65:5
	0651
	1506		/66:6
	4225
	4443		/67:7
	6050
	5126	/70:8
	2651
	5122		/71:9
	3651
	2200		/72::
	0000
	4601		/73:;
	0000
			/CODE 74:<NOT DISPLAYED
QAU,	2		/CONSTANT
	0	/NOT USED
	1212		/75:=
	1212
			/CODE 76:> NOT DISPLAYED
QAW,	NOP
	ADD QAU
	4020		/77:?
	2055
/
QAF,	DSC I
	6000
	JMP QAI
/
			/END Q+A
/
/
/
/
/KEYBOARD INPUT ROUTINE
/
QAKRB=6036	/PDP-8 IOT KBD
QATSF=6041	/TSF
QATLS=6046	/TLS
/
GETKBD,	LDA
	0
	STC QAEXIT+6	/SAVE RETURN
	ADD 1		/SAVE XRS 1 AND 2
	STC QAEXIT+3
	ADD 2
	STC QAEXIT+5
	STC QAEXIT+1
	KST	/WAS SOMETHING TYPED?
	JMP 0		/NO: EXIT
	IOB
	QAKRB	/GET TTY CHAR, CLEAR FLAG
	STA I		/SAVE IT
QATY,	0
	ADA I
	-237
	APO		/BETWEEN 200 AND 237?
	JMP QACNTR	/CONTROL CHAR. CHECK FOR CR,LF,TAB
/
	SET I 1		/NO
	QACHAR-1
	SET I 2
	-7
	LDA
	QATY
	SAE I 1
	JMP .+2
	JMP QAEXIT	/ILLEGAL CHAR. DONT ECHO
	XSK I 2	/CHECKED THEM ALL?
	JMP .-4
/
	ADA I
	-337
	APO		/BETWEEN 240 AND 337?
	JMP QALEGL	/YES. LEGAL CHAR
/
	SAE I 1		/NO. CHECK FURTHER.
	JMP .+7
	LDA I		/RUBOUT
	334
	JMP QATPE	/ECHO BACKSLASH
	LDA I
	37
	JMP QAEXIT+2	/LEGAL EXIT
/
	SAE I 1
	JMP QAEXIT	/ILLEGAL
			/ALT
	JMP QAEXIT+2	/EXIT, DONT ECHO
/
QALEGL,	LDA
	QATY
	JMP QATPE	/ECHO CHAR
	ADD QATY
	BCL I		/STRIP IT TO 6-BIT
	7700
	JMP QAEXIT+2
/TO HERE IF CONTROL CHAR
QACNTR,	SAE I
	7755
	JMP QACKLF
	LDA I		/CR
	43
	STC QAEXIT+1
	LDA I
	215
	JMP QATPE
	LDA I
	212
	JMP QATPE
	JMP QAEXIT
/
QACKLF,	SAE I
	7752
	JMP .+4
	LDA I		/LF
	45
	JMP QACNTR+5
	SAE I
	7751
	JMP QAEXIT	/ILLEGAL
	LDA I
	47
	JMP QAEXIT+2	/EXIT, DONT ECHO
/
QAEXIT,	LDA I	/GET 6-BIT ASCII
	0
	SET I 1		/RESTORE XRS
	0
	SET I 2
	0
	JMP		/EXIR S\R GETKBD
/S\R TO PRINT C(AC)
QATPE,	IOB
	QATLS	/PDP-8 IOT TLS
	LDA
	0
	STC .+4	/SAVE RETURN
	IOB
	QATSF	/WAIT FOR FLAG
	JMP .-2
	JMP 	/EXIT
/
QACHAR,	243	/HASH
	244	/DOLLAR SIGN
	245	/PER CENT
	247	/APOSTROPHE
	300	/AT SIGN
	336	/UP ARROW
	337	/BACK ARROW
	40	/RUBOUT
/GET8
/SYNC SIGNAL (PRECS PULSE) GOES INTO INPUT 1
/AND TWO AMPLITUDES FOR EACH.
/SAMPLE LOOP TIME IS 130 MICROSECONDS
/THIS PROGRAM SUPPORTS CLASSICAL CONDITIONING BY DEFAULT.
/       BY DISCONNECTING INPUTS TO SXL 12 AND 13
/  INSTRUMENTAL CONDITIONING IS SUPPORTED BY CONNECTING 12 TO THE NEGATIVE OUT
/OF A COMPARATOR. SAID COMPARATOR TRIGGERING WHEN THE AMPLITUDE OF THE DEPENDENT
/VARIABLE EXCEEDS THE MOVEABLE REFERENCE VOLTAGE
/IN THIS CASE RELAY K1 IS NOT SET.
/
/
/K0 IS SET FOR 128 TIME POINTS, THEN BOTH K0 AND K1 ARE SET FOR AN
/ADDITIONAL 128 TIME POINTS, (SUBJECT TO INSTRUMENTAL RESPONSE)
/
/
/PROGRAM ALSO SUPPORTS DIFFERENTIAL CONDITIONING VIA K5
/K5 IS SET DURING ODD AVERAGES AND IS USED IN CONJUNCTION WITH SENSE LINE 13
/WITH 13 GROUNDED NO DATA ARE COLLECTED /WITH 13 HIGH DATA ARE COLLECTED IN DF5-7
/EIGHT POSTSTIMULUS HISTOGRAMS ARE COLLECTED
/ONE FOR EACH OF EIGHT ELECTRODES, THE  SIGNALS ARE PRE-
/PROCESSED BY THE COMPARATORS