Directory of image this file is from
This file as a plain text file

$1
JMP 6O
JMP 20
$20
JMP 6P
JMP 6E
6L
JMP 6C
6S 6M 6T
JMP 9L
21
2025
2000
0
0
JMP 9L
23
-0
-0
0
0
JMP 6E
6T
#1A CLR
OPR 75 [# OF LINES
COM
STC 1J
OPR 76 [X
STA
1H
SCR 13
STC 1H-1
OPR 77 [Y
STA 
1I
SCR 13
STC 1I-1
OPR 74 [Z
STA
2A
SCR 13
STC 2A-1
LDA i
20
LMB 8K
JMP 8L
LDA i
20
LMB 8K
JMP 8L
SET i 1
#1J 
LSW [DX
STA
1F
SCR 13
STC 1F-1
RSW [DY
STA
1G
SCR 13
STC 1G-1
OPR 73 [DZ
STA
2B
SCR 13
STC 2B-1
SNS 0
JMP 3A [ABSOLUTE
JMP 3B [RELATIVE
#3A SNS 1 [ABSOLUTE
JMP 3C [DRAW TO
JMP 3D [DRAW FROM
#3B SNS 1 [RELATIVE
JMP 3E [DRAW TO
JMP 3F [DRAW FROM
#3F JMP 9I [REL DRAW FROM
9S 9A
1H-1
JMP 9I
9F 9R
1F-1
JMP 9I
9S 9R
1F-1
XSK i 1
JMP 3F+3
JMP 1A
#3C JMP 9I [ABSOLUTE DRAW TO
9S 9A
1H-1
JMP 3J
JMP 9I
9T 9A
1H-1
XSK i 1
JMP 3C
JMP 1A
#3D JMP 9I [ABSOLUTE DRAW FROM
9S 9A
1H-1
JMP 3J
JMP 9I
9F 9A
1H-1
XSK i 1
JMP 3D
JMP 1A
#3E JMP 9I [RELATIVE DRAW TO
9S 9A
1H-1
JMP 9I
9T 9R
1F-1
XSK i 1
JMP 3E+3
JMP 1A
#3J LDA
0
STC 3K
CLR
LDA
1F
LAM
1H
LDA
1F-1
LAM
1H-1
CLR
LDA
1G
LAM
1I
LDA
1G-1
LAM
1I-1
CLR
LDA
2B
LAM
2A
LDA
2B-1
LAM
2A-1
#3K 0 [RETURN
0
#1F 0
0
#1G 0
0
#2B 0
0
#1H 0
0
#1I 0
0
#2A 0
[E+S   4|17|71
[EVANS AND SUTHERLAND SYSTEM SUBRS
[R. A. ELLIS
[COMPUTER SYSTEMS LAB
[WASHINGTON UNIV.
[724 S. EUCLID AVE
[ST. LOUIS, MO. 63110
$1000
[------------------------------------------
[LINE GEN OPS
[DRAW DIRECT
#9D SET 17
 0
JMP 8A [ARG PTR
JMP 8B [OUT GRP4
#8D JMP 8C [OUT X,Y
JMP 8J [E+S IN
JMP 8V [ERROR
JMP 8E [3D?
JMP 8W [NO, RET
JMP 8F [YES, Z+W
JMP 8J [E+S IN
JMP 8V [ERROR
JMP 8W [RET
[
[DRAW INDIRECT
#9I SET 17
 0
JMP 8A [ARG PTR
JMP 8B [OUT GRP4
JMP 8R [COORD SDDR
JMP 8D
[
[GET REGS
#9G SET 17
 0
JMP 8A [ARG PTR
LDA i [FETCH
 2000
JMP 8G [OUT GRP3
LMB 8J [E+S IN
JMP 8V [ERROR
[----------------
JMP 8E [3D?
JMP p+3 [NO
JMP 8J [COMM AGAIN
JMP 8V [ERROR
[----------------
JMP 8W [RET
[
[LOAD DIRECT
#9L SET 17
 0
JMP 8A [ARG PTR
CLR [LOAD
JMP 8G [OUT GRP3
#8I JMP 8C [OUT X,Y
JMP 8J [E+S IN
JMP 8V [ERROR
JMP 8E [3D?
JMP 8W [NO, RET
JMP 8C [YES, X,Y
JMP 8J [E+S IN
JMP 8V [ERROR
JMP 8W [RET
[
[LOAD INDIRECT
#9J SET 17 [SAVE RET
 0
JMP 8A [ARG PTR
CLR [LOAD
JMP 8G [OUT GRP3
JMP 8R [DATA ADDR
JMP 8I
[
[-------------------
[TAGS
[ABSOLUTE MODE
9A=0
[RELATIVE MODE
9R=100
[POINT
9P=1000
[DRAW TO
9T=2000
[DRAW FROM
9F=5000
[SET POINT
9S=3000
[------------------------------------------
[MATRIX MULT OPS
[LOAD DIRECT
#7L SET 17
 0
JMP 8A [ARG PTR
CLR [LOAD
JMP 8G [OUT GRP3
#8P JMP 8C [OUT X,Y
JMP 8J [E+S IN
JMP 8V [ERROR
JMP 8E [3D?
JMP 8W [NO, RET
JMP 8C [YES, X,Y
JMP 8J [E+S IN
JMP 8V [ERROR
JMP 8W [RET
[
[LOAD INDIRECT
#7I SET 17
 0
JMP 8A [ARG PTR
CLR [LOAD
JMP 8G [OUT GRP3
JMP 8R [DATA ADDR
JMP 8P
[
[RETRIEVE DIRECT
#7T SET 17
 0
JMP 8A [ARG PTR
LDA i [RET
 4000
JMP 8G [OUT GRP3
JMP 8P
[
[RETRIEVE INDIRECT
#7J SET 17
 0
JMP 8A [ARG PTR
LDA i [RET
 4000
JMP 8G [OUT GRP3
JMP 8R [DATA ADDR
JMP 8P
[
[GET REGS
#7G SET 17
 0
JMP 8A [ARG PTR
LDA i [GET
 2000
#8S JMP 8G [OUT GRP3
JMP 8J [E+S IN
JMP 8V [ERROR
[---------------
JMP 8E [3D?
JMP p+3 [NO
JMP 8J [COMM AGAIN
JMP 8V [ERROR 
[---------------
JMP 8W [RET
[
[SINK
#7K SET 17
 0
JMP 8A [ARG PTR
LDA i [SINK
 6000
JMP 8S
[
[-------------------
[TAGS
[SELECTED ROW
7R=400
[ADD TO SEL ROW
7A=500
[MULTIPLY SEL ROW
7M=600
[DIRECTIVE REG
7D=700
[NORMALIZE A MATRIX
7N=500
[PUSH|POP
7P=600
[SLIDE
7S=500
[------------------------------------------
[INTERPRETER
[SET MODE
#6E SET 17
 0
JMP 8A [ARG PTR
LDA i
#6R 0 [MODE REG
BSE 16
STC 6R
JMP 8W [RET
[
[CLEAR MODE
#6C SET 17
 0
JMP 8A [ARG PTR
LDA
 6R
BCL 16
STC 6R
JMP 8W [RET
[
[GET DATA FROM E+S
#6G SET 17
 0
JMP 8A [ARG PTR
LDA 16
SAE i
 6L
JMP 6A [MAT MUL
JMP 6B [LG
[READ DATA FROM MAT MUL
#6A JMP 8R [DATA ADDR
JMP 8Q [GET MM
JMP 8E [3D?
JMP 8W [NO, RET
JMP 8Q [GET MM
JMP 8W [RET
[READ DATA FROM LINE GEN
#6B JMP 8R [DATA ADDR
JMP 8H [GET LG
JMP 8E [3D?
JMP 8W [NO, RET
JMP 8H [GET LG
JMP 8W [RET
[
[READ MMINST AND OTHER PROGS
[FROM TAPE
#6O UMB 8K [MMINST
RDCiu
 4|8T
RDCiu
 5|8T+1
RDCiu
 6|8T+2
RDCiu
 7|8T+3
UMB 8U [OTHER
RDCiu
 4|8T+4
RDCiu
 5|8T+5
RDCiu
 6|8T+6
RDC u
 7|8T+7
UMB 1
JMP 0
[
[PRESET
#6P SET 17
 0
LMB 8K [PRESET
JMP 1000
JMP 17
[
[Y AXIS ROT MATRIX
[ROW 0
0    [COS PHI
0
0    [0
0
0    [0
0
0    [SIN PHI
0
[ROW 1
0    [0
0
3777 [1
7777
0    [0
0
0    [0
0
[ROW 2
0    [TX
0
0    [TY
0
3777 [SCALE
7777
0    [TZ
0
[ROW 3
0    [-SIN PHI
0
0    [0
0
0    [0
0
0    [COS PHI
0
[ENTRANCE
#6Y SET 17
 0
JMP 8A [ARG PTR
LDA 16 [PHI
STA i
#6Q
LMB 8U [SIN PHI
JMP 8Y
STA
 6Y-32
COM
STC 6Y-10
ADD 6Q
LMB 8U [COS PHI
JMP 8Z
STA
 6Y-40
STC 6Y-2
LDAi16 [TX
STA
 6Y-17
SCR 13 [GET LH
STC 6Y-20
LDAi16 [TY
STA
 6Y-15
SCR 13 [GET LH
STC 6Y-16
LDAi16 [TZ
STC 6Y-11
JMP 8W [RET
[
[X AXIS ROT MATRIX
[ROW 0
3777 [1
7777
0    [0
0
0    [0
0
0    [0
0
[ROW 1
0    [0
0
0    [COS THETA
0
0    [0
0
0    [-SIN THETA
0
[ROW 2
0    [TX
0
0    [TY
0
3777 [SCALE
7777
0    [TZ
0
[ROW 3
0    [0
0
0    [SIN THETA
0
0    [0
0
0    [COS THETA
0
[ENTRANCE
#6X SET 17
 0
JMP 8A [ARG PTR
LDA 16 [THETA
STA
 6Q
LMB 8U [SIN THETA
JMP 8Y
STA
 6X-6
COM
STC 6X-22
ADD 6Q
LMB 8U [COS THETA
JMP 8Z
STA
 6X-2
STC 6X-26
LDAi16 [TX
STA
 6X-17
SCR 13 [GET LH
STC 6X-20
LDAi16 [TY
STA
 6X-15
SCR 13 [GET LH
STC 6X-16
LDAi16 [TZ
STC 6X-11
JMP 8W [RET
[
[-------------------
[TAGS
[SWAP
6S=100
[3D
6T=40
[LINE GEN ACTIVE
6L=20
[MAT MUL ACTIVE
6M=10
[------------------------------------------
[SUBROUTINES
[ARG POINTER TO 16
#8A LDA
 17
BCL i
 6000
STC 16
MSC 12 [CLR FLAG
JMP 0
[
[OUT GRP 4 DRAW COMM
#8B LDA [MODE REG
 6R
ADA i [GRP 4
 4
OPR 5A [COMM LEFT
LDA 16
OPR 5B [COMM RIGHT
JMP 0
[
[OUTPUT X,Y TO E+S
#8C LDA i 16
COM
OPR 5C
LDA i 16
COM
OPR 5D
LDA i 16
COM
OPR 5E
LDA i 16
COM
OPR 5F
JMP 0
[
[TEST FOR 3D MODE
#8E LDA [MODE REG
 6R
BCL i
 7737
AZE
XSK i 0 [3D
JMP 0
[
[OUT Z,W TO E+S
#8F LDA i 16 [Z
COM
OPR 5E
LDA i 16
COM
OPR 5F
LDA i [W=1
 3777
COM
OPR 5C
LDA i
 7777
COM
OPR 5D
JMP 0
[
[OUT GRP 3 COMM
#8G ADA 16
OPR 5B [COMM RT
LDA [MODE REG
 6R
BSE i [GRP 3
 3
OPR 5A [COMM LEFT
JMP 0
[
[GET X,Y FROM LINE GEN
#8H SET 15 [SAVE RET
 0
LDA i [LG DATA RDY?
 5V
LMB 8K [CTL RET?
JMP 8M
JMP p-4 [NO
CLR [YES
OPR 5K
STAi16
CLR
OPR 5L
STAi16
CLR
OPR 5M
STAi16
CLR
OPR 5N
STAi16
LDA i [LG DATA ACCEPTED
 5Q
LMB 8K [CTRL OUT
JMP 8L
JMP 15 [RET
[
[GEN E+S INPUT CTRL
#8J SET 15
 0
LDA i [E+S IN
 5O
LMB 8K [CTRL OUT
JMP 8L
#8O LDA i [IN ICCEPTED?
 5S
LMB 8K [CHK RET?
JMP 8M
JMP 8N [NO
XSKi15 [YES, RET p+2
JMP 15 [RET
#8N LDA i [IN NOT ACCEPTED?
 5T
LMB 8K [CHK RET
JMP 8M
JMP 8O [NO, LOOK AGAIN
JMP 15 [YES, ERROR RET
[
[INPUT X,Y FROM MAT MUL
#8Q SET 15
 0
LDA i [MM DATA OUT RDY?
 5U
LMB 8K [CHK RET
JMP 8M
JMP p-4 [NO
CLR [YES
OPR 5G
STAi16
CLR
OPR 5H
STAi16
CLR
OPR 5I
STAi16
CLR
OPR 5J
STAi16
LDA i [MM DATA OUT ACCEPTED
 5P
LMB 8K [CTRL OUT
JMP 8L
JMP 15
[
[GET DATA ADDR FOR INDIRECT
#8R LDAi16
ADA i
 -1
STC 16
MSC 2 [SET FLAG
JMP 0
[
[ERROR, HIT MAIN DISPLAY
#8V SET 15
 0
LMB 8K [MAIN SUBR
JMP 1010
JMP p-2
JMP 15 [KST, RET
[
[RETURN
#8W SKP 17 [FLG SET?
JMP 8X [NO, DIRECT
XSKi17 [YES, IND
XSKi17
JMP 17
#8X LDA i
 JMP 1
ADM
 16
JMP 16
[
[-------------------
[TAGS
[MMINST PAGE
8K=2
[GEN CONTROL OUT
8L=1040
[CHK FOR CTRL RET
8M=1060
[u1 PROGS START BN
8T=400
[OTHER PAGE
8U=3
[SIN
8Y=20
[COS
8Z=50
[
[------------------------------------------
[LINC-MACRO MOD INTERFACE TAGS
[DATA FROM LINC
[COMMAND LEFT
5A=50
[COMMAND RIGHT
5B=51
[X LEFT
5C=52
[X RIGHT
5D=53
[Y LEFT
5E=54
[Y RIGHT
5F=55
[
[DATA TO LINC
[MM X LEFT
5G=70
[MM X RIGHT
5H=71
[MM Y LEFT
5I=72
[MM Y RIGHT
5J=73
[SCOPE X LEFT
5K=74
[LG X RIGHT
5L=75
[LG Y LEFT
5M=76
[LG Y RIGHT
5N=77
[
[CONTROL FROM LINC
[INPUT TO E+S
5O=1
[MM DATA OUT ACCEPTED
5P=10
[LG DTAT OUT ACCEPTED
5Q=4
[PRESET
5R=4000
[
[CONTROL TO LINC
[INPUT ACCEPTED BY E+S
5S=2
[INPUT NOT ACCEPTED BY E+S
5T=1
[MM DATA OUT READY
5U=10
[LG DATA OUT READY
5V=4
[PRESET
5W=4000