file INSTCOND

File INSTCOND
Directory of image this file is from
This file as a plain text file
*20
	SEGMNT 0
	LIM=10
	AVGPTR=12
	*20
TIME,	-11
SBINS,	-400
SAMN,	-20
N,	20
TPEBLK,	0
WRTBLK,	0
INTAC,	0
	*1
	PMODE
	JMP INT+2
	LMODE
	*41
	JMP INT
	*170
INT,	NOP
	PDP
	3026		/DCA INTAC
	6135
	6141
	APO I
	JMP SYNC
	CLR
	IOB
	6234
	STA I
SAVDF,	0
	LDA I
	4100
	SAE I
CS,	0
	JMP US
	FIELD 1
        LDF 5
	SXL I 13
	LDF 2
	SAM 10		/RPD
	STA I
SAMTMP,	0
FACTOR,	SCR 5
	STA I
SAVAC,	0
	QAC
	LAM I 5
	LDA
	SAVAC
	LAM I 6
	CLR
	STA I 7
	XSK I 4
	NOP
ENDTME, XSK I 15	/END OF RUNTIME
	JMP .+2
	JMP ENDBLK
	IOB 
        6001
	XSK I 11
	JMP SMPL
	CLR
	STC INST
	STC CUM
	RTA
	BSE I
        0040
	SXL I 13
	JMP CSPLUS
	BSE I
K2,	0010
RELSET,	ATR		/KEEP K6 SET,SET K0
	SET I 14
	1777		/SHOW CS TIME
SMPL,   NOP
	CLR
	SAE I
SNKFLG,	0
	SKP
	JMP SAMBCK-5
	LDA
	40
	BSE I
	6000
	STC SAMBCK
	ADD SAVDF
	ROL 2
	BCL I
	7770
	BSE I
	LDF 0
	STC .+1
	0		/LDF CHANGE
	ADD INTAC
	NOP
	NOP
	DJR
	IOB
	6001
SAMBCK,	0		/JMP BACK
/
CSPLUS, BSE I
	0006
	JMP RELSET
/
ENTER,	LDA I
ONE,	1
	STC SNKFLG
S1,	LDF 7
	SXL I 13
	LDF 3
	SXL 0
	JMP E1
	SAM 7
	ROL 7
S2,	SXL 2
	JMP E2
	SAM 7
	ROL 7
S3,	LDF 6
	SXL I 13
	LDF 4
	SXL 4
	JMP E3
	SAM 7
	ROL 7
S4,	SXL 6
	JMP E4
	SAM 7
	ROL 7
EMG,	SXL 10
	JMP EMG1
	JMP S1
/
E1,	SXL 1
	JMP LG1
	LDA
	ONE
	ADM 4
	JMP S2
LG1,	LDA
	ONE
	ADM 5
	JMP S2
/
E2,	SXL 3
	JMP LG2
	LDA
	ONE
	ADM 6
	JMP S3
LG2,	LDA
	ONE
	ADM 7
	JMP S3
/
E3,	SXL 5
	JMP LG3
	LDA
	ONE
	ADM 4
	JMP S4
LG3,	LDA
	ONE
	ADM 5
	JMP S4
/
E4,	SXL 7
	JMP LG4
	LDA
	ONE
	ADM 6
	JMP EMG
LG4,	LDA
	ONE
	ADM 7
	JMP EMG
/
EMG1,	LDF 5
	SXL I 13
	LDF 2
	LDA
	ONE
	ADM 7
	LDA
	ONE
	ADM 4
	LDA 
	ONE
	ADM I
CUM,	0
	SXL I 13
	SKP
	JMP S1
	CLR
	STC RESLIM
	JMP S1
/
ENDBLK,	SET I 1
	5173
MORE,	LDA I
	0060
	STA
	CS
	LDA I
RESLIM,	0
	COM
	ADA
	CUM
	APO I
	JMP .+5		/RESPONSE BIG DONT SHOCK
	RTA
	BSE I
	0060		/KEEP K6 AND K0,SET K1
	ATR
	SET I 13
	-200		/END OF CS TIME SET US (K1) AND CS(K0) FOR 200 BINS
US,	XSK I 13
	JMP SETOUT	/KEEP RELAYS SET
	RTA
	BCL I
	0076
	ATR		/CLEAR K0 AND K1
TRT,    XSK I AVGPTR
	JMP CLKSET
	JMP AVG
/
SYNC,	ROL 10
        APO I
        JMP TRY3
POINT,  IOB
	6234		/RIB
	ROL 2
	BCL I
	7770
	BSE I
	LDF 0
	STC RESTDF
	LDA
	ONE
	LDF 4
	ADM 7
RESTDF,	0		/RESTORE DF WHERE INTERRUPTED
	LDA
	40
	ADA I
	6000
	STC .+4
	ADD INTAC
	IOB 
	6001
	0		/BACK TO INTERUPPTED POINT
TRY3,	ROL 2
	APO 
	JMP POINT	/EVENT 3 IS US
        SET I 17
TABLE,	2000
	SET 15
BINS,	SBINS
	SET 4
	TABLE
	SET I 5
DELBIN,	2400
	SET I 6
DLBIN2,	3000
	SET I 7
DLBIN3,	3400
	SET I 11
	-200		/PRECS TIMER
	SET I 14
	1		/SHOW CS
	CLR
	STA I
INST,	0       /SET INSTRUMENTAL POINTER
	STC SNKFLG
	LDA I
	JMP ENTER             
 RETRY,	STC SAMBCK
	LDA
	WRTBLK
	ADA I 
	1
	STA
	WRTBLK
	LDA
	TIME
	IOB
	6133		/PRESET TIMER
	LDA I
	4100		/1KC AND PRESET
	STA
	CS		/SHOW SYNC
	IOB
	6132		/CLLR
	IOB
	6135		/CLSA POSSIBLE FLAG
	LDA I
	317		/ENABLE CLOCK
	IOB
	6134		/SET CLOCK INT
SETOUT,	IOB
	6001
	JMP SMPL		/WAIT FOR CLOCK
/
/
ASTART,	IOB
        6046          
        LDA I  
        4000
	BSE 
	TPEBLK
	STA 
	WRTBLK		/INITIALIZE WRTBLK
	STA
	AVGBLK
	CLR
	SET I 2
	-30
	SET I 3
	TYPEIT-1
	IOB
	6041
	JMP .-2
	LDA I 3
	IOB
	6046
	XSK I 2
	JMP .-7
	CLR
	ATR		/CLEAR RELAYS
	LDA I
	60
	ESF
	CLR
	IOB
	6132
AVGSET,	SET I AVGPTR
	3777
	CLR
	LDF 5
	STA I AVGPTR
	LDF 6
	STA AVGPTR
	LDF 7
	STA AVGPTR
	LDF 4
	STA AVGPTR
	LDF 3
	STA AVGPTR
	LDF 2
	STA AVGPTR
	XSK AVGPTR
	JMP AVGSET+2
	SET I AVGPTR
	-400
	CLR
	SET AVGPTR
	SAMN		/N FOR AVERAGE
	RTA
	BCO I
	0001
	ATR		/FLIP K6
CLKSET,	LDA
	TIME
	IOB
	6133		/CLAB, PRESET NUMBER
	CLR
	IOB
	6132      /CLLR TO STOP CLOCK
	LDA I
	60
	IOB
	6134		/CLEN 
	IOB
	6135		/CLSA TO CLEAR CLOCK
	IOB
	6001
	LIF 1
	JMP DISPLA	/WAIT FOR SYNC ---
/
TYPEIT,	322
	305
	323
	324
	301
	322
	324
	240
	302
	331
	240
	314
	323
	240
	324
	317
	240
	260
	266
	261
	263
	215
	212
/CUT IN HERE FOR TTY SERVICE BEFORE IOB AND 6001
/
/
AVG,	STD
	JMP .-1
	LDA I 
	60
	ESF
	SET I 17
	3777
	CLR
	SET 14
	SBINS
	SNS I 0
	JMP RESET	/SUPPRESS TAPE
	FIELD 1
	LDF 7
	JMP WRTSET
	LDF 6
	JMP WRTSET
	LDF 5
	JMP WRTSET
	LDF 4
	JMP WRTSET
	LDF 3
	JMP WRTSET
	LDF 2
	JMP WRTSET
	JMP RESET
/
WRTSET,	LDA
	0
	STC WRET
	SET I 17
	4000
	JMP SET1
	JMP WRITE
	SET I 17
	5000
	JMP SET1
	JMP WRITE
	SET I 17
	6000
	JMP SET1
	JMP WRITE
	SET I 17
	7000
	JMP SET1
	JMP WRITE
	LDA I
WRET,	0
	STC 0
	JMP 0
/
SET1,	LDA
	0
	STC RET4
	LDA
	AVGBLK
	BCL I
	7000
	BSE
	17
	STC AVGBLK
	LDA I
RET4,	0
	STC 0
	JMP 0
/
WRITE,	LDA 
	0
	STC RET
	LDA
	AVGBLK
	ADA I
	1
	STA
	AVGBLK
	STD
	JMP .-1
	WRI U
AVGBLK,	0
	LDA I
RET,	0
	STC 0
	JMP 0
/
RESET,	SET I 17
	3777
	SET 15
	SAMN
	LDA I
	60
	ESF
	JMP AVGSET
/
/
/
/DISPLAY PROGRAM FOR DATA COLLECTION
/
	SEGMNT 1
	*20
DISPLA,	CLR
	IOB
	6046		/TLS
	LDF 0
	JMP .+1		/ENABLE INTERUPT
	LDA
	SBINS!2000
	STA I
DBINS,	0
	SET I 17
	WRTABL-1
	SET I 16
	-3		/DISPLAY TRIAL NUMBER
	LDA
	WRTBLK!2000
	ROL 3
	STC TEMWRT
UNPACK,	LDA I
TEMWRT,	0
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17	/GET HALF CHAR
	LDA I 3		/GET OTHER HALF
	STA I 17
	XSK I 16
	JMP UNPACK
DISGO,	SET I 17
	WRTABL-1
	SET I 1
	10
	SET I 16
	-6
	SET 3
	DBINS
	LDA I 
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS TRIAL NUMBER
	LDF 0
	SET I 17
	BLKTBL-1
	SET I 16
	-3		/DIS BLOCK NUMBER
	LDA
	AVGBLK!2000
	ROL 3
	STC TEMWRT
BKPACK,	LDA 
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA 
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP BKPACK
DISBK,	SET I 17
	BLKTBL-1
	SET I 1
	600
	SET I 16
	-6
	SET 3
	DBINS
	LDA I
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS BLOCK NUMB
	CLR
	RSW
	BCL I
	7770
	BSE I 
	0640
	STA
	IELD
IELD,	0	/SET DF SELECTED BY RITE SWTCHS
	SNS I 1		/SMALLEST
	JMP .+5
	SET I 2
K3777,	3777
	SAM 1
	JMP DISLOP
	SET I 2
KBMP2,	2377
	SNS I 2
	JMP .+3
	SAM 2
	JMP DISLOP
	SET I 2
	2777
	SNS I 3
	JMP .+3
	SAM 3
	JMP DISLOP
	SET I 2
	3377
	SNS I 4
	JMP .+3
	SAM 4
	JMP DISLOP
	SNS I 5
	JMP DISGO	/SUPPRESS INTEGRAL
	IOB
	6031
	JMP DISINT
IO,	IOB
	6036		/KRB
	IOB
	6046
	STA I
ELECT,	0
	ADA I
	-260
	APO
	JMP ERR
	LDA
	ELECT
	ADA I
LIM5,	-264
	APO I
	JMP ERR
	LDA
	ELECT
	BCL I
	7770
	STC ELECT
DISINT,	LDA I
	INTBL-1
	ADA
	ELECT		/FORM SET
	STC 11
	LDA 11
	STC INTSTR
	STC INT1
	STC INT2
	LSW
	BCL I
	7760
	BSE I
	SCR 0
	STC SHIFT
	LDA
	ELECT
	BSE I
	SAM 0
	STC SMPIT
	SET I 12
INTSTR,	0
	SET I 13
	-176
	JMP INTLUP-3
	LDA I
	10
	STC HORIZ
	JMP DISIN
	SET I 13
	-200
	CLR 
	STC INT1
	STC INT2
	JMP INTLUP-3
	LDA I
	600
	STC HORIZ
	JMP DISIN
/SCALE FACTOR
	SET I 17
	CSTBL-1
	SET I 16
	-3
	LDA
	SHIFT
	BCL I
	7760
	ROL 3
	STC TEMWRT
SCPACK,	LDA
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP SCPACK
	SET I 17
	CSTBL-1
	SET I 1
	400
	SET I 16
	-6
	LDA I
	-300
	DSC I 17
	XSK I 16
	JMP .-4
	LDF 0
	SAM 7
	STA
	RESLIM!2000
	DIS 16
	STC INT2
	LDA I
	300
	STC HORIZ
	LDA I
	300
	STC VERT
	JMP DISIN
	LDA I
	-300
	STC VERT
	JMP DISGO
/
/
	LDA
	0
	STC JMPLUP
INTLUP, LDA I 12
	APO
	COM		/ABS VALUE
SHIFT,	0
	STA I
ACSAVE,	0
	QAC
	LAM I
INT1,   0
	LDA
	ACSAVE
	LAM I
INT2,   0
SMPIT,	0
	ADA 
	INT2
	DIS 12
INTOUT, XSK I 13
	JMP INTLUP
	LDA I
JMPLUP,	0
	STC 0
	JMP 0
/
INTBL,	2001
	2401
	3001
	3401
/
ERR,    PDP
	PMODE
	TSF
	JMP .-1
	CLA CLL
	TAD K277
	TLS		/TYPE ?
	TSF
	JMP .-1
	CLA CLL
	TAD K215
	TLS
	TSF
	JMP .-1
	CLA CLL
	TAD K212	/CRLF
	TLS
	KSF
	JMP .-1
	LINC
	LMODE
	JMP IO
	PMODE
K277,	277		/?
K215,	215
K212,	212
	LMODE
/
/
DISIN,	LDA
	0
	STC RET17
	SET I 17
	INTABL-1
	SET I 16
	-4
	LDA
	INT2
	STC INTWRD
INPACK,	LDA I
INTWRD,	0
	ROL 3
	STA
	INTWRD
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP INPACK	/SET UP INTEGRAL FOR PRECS
	SET I 17
	INTABL-1
	SET I 1
HORIZ,	0
	SET I 16
	-10
	LDA I
VERT,	-300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS PRECS INT
/
	LDA I
RET17,	0
	STC 0
	JMP 0
/
CSTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
INTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/DISPLAY SUBROUTINE
DISLOP,	STA I
DTEM,	0
	LDA
	0
	STC DRET
	SET 3
	DBINS
	XSK I 2
	LDA
	DTEM
	ADA 2
	DIS 2
	XSK I 3
	JMP .-6
	LDA I
DRET,	0
	STC 0
	JMP 0
/
/
PATERN,	4136
	3641
	2101
	0177
	4523
	2151
	4122
	2651
	2414
	0477
	5172
	0651
	1506
	4225
	4443
	6050
	5126
	2651
	5120
WRTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	00
	0
	0
	0
	0
	0
	0
	0
	0
BLKTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/SYNC SIGNAL (PRECS PULSE) GOES INTO INPUT 1
/ELECTRODE ONE GOES TO COMPARATOR 0 AND 1
/ELECTRODE TWO GOES TO COMPARATOR 2 AND 3
/ELECTRODE THREE GOES TO COMPARATOR 4 AND 5
/ELECTRODE FOUR GOES TO COMPARATOR 6 AND 7
/EMG GOES TO COMPARATOR 10
/       COMPARATOR AND SENSE LINE NUMBERS ARE THE SAME
/
/
	/THIS PROGRAM SUPPORTS DIFFERENTIAL INSTRUMENTAL
/CONDITIONING.
/THE CS+ IS DEFINED BY A GROUND SIGNAL INTO SENSE LINE 13
/IN THIS CASE K0 AND K2 ARE SET FOR 1.28 SEC
/IF THE ACTIVITY LEVEL AS INDICATED BY SXL 10 EXCEEDS THE LEVEL
/SELECTED BY A/D 7 AND SHOWN IN THE MIDDLE TOP OF THE SCOPE
/THEN K1 IS NOT SET FOR A SUBSEQUENT 1.28 SEC, 
/IF THE RESPONSE AT SXL 10  DOES NOT EXCEED THE LEVEL SELECTED
/BY A/D 7 THEN K1 IS SET DELIVERING A US
/
/
/IF SXL 13 IS NOT GROUNDED , THEN K0 AND K3 AND K4 ARE SET
/FOR A CS-
/THE US IS DISABLED DURING THE CS-
/
/
/TO RUN CLASSICAL CONDITIONING WITH THIS/
/PROGRAM, GROUND SXL 13
Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with. I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation.

PDP-8 Home Page PDP-8 Site Map PDP-8 Site Search