Directory of image this file is from
This file as a plain text file

[JANC    1|29|71
[CONTROL FOR JANC
[R A ELLIS AND C B W DODDS
[WASHINGTON UNIVERSITY
[COMPUTER SYSTEMS LAB
[ST. LOUIS, MO. 63110
$1
JMP 20
$20
SNS i 4A
JMP 1A [SIM
[PRESET ON
CLR
OPR 4F [OUT
[PRESET OFF
LDA i
3
OPR 4F [OUT
STA i
#2I   [IN VECTOR
STA i
#2O   [OUT VECTOR
#1A JMP 3D [READ AND DISP REGS
KST
JMP 1A
KBD i
SHD i
 "G;
JMP 1N [GO
SHD i
 "R;
JMP 1R [RESUME
SHD i
 "S;
JMP 1S [LOAD S
SHD i
 "A;
JMP 2A [LOAD A
SHD i
 "E;
JMP 1E [EXAM
SHD i
 "L;
JMP 1L [LOAD PROG
SHD i
 "F;
JMP 1F [FILL
SHD i
 "X;
JMP 1U [XTRA
JMP 1A [NONE
[XTRA CONTROL SIGNAL
#1U SNSi4A
JMP 1A [NO SIM
LDA i [XTRA
 4Q
JMP 2B [OUT CHK
JMP 1A
[GO
#1N SNS 4A
JMP 1O
LDA  [S TO P
 9S
STC 9P
JMP 1M
#1O LDA i [START JANC
 4H
JMP 2J [CTRL OUT
JMP 1P
[RESUME
#1R SNS 4A
JMP 1B
#1M JMP 9B [SIM
JMP 1A [I BY I
#1Q JMP 3T [TTL
JMP 1R [RESUME
#1B LDA i [RES JANC
 4I
JMP 2J [CTRL OUT
#1P JMP 3D [READ AND DISP REGS
LDA i [I BY I?
 4J
JMP 2K [CTRL RET?
JMP 1T [NO
JMP 1A [YES
#1T LDA i [TTL RET?
 4K
JMP 2K [CTL RET?
JMP 1P [NO
JMP 1Q [YES
[LOAD S
#1S SNS 4A
JMP 1C
RSW [SIM
STC 9S
JMP 1A
#1C RSW
OPR 4M [DATA OUT
LDA i [LOAD S
 4L
JMP 2B [CTRL OUT AND CHK
JMP 1A
[LOAD A
#2A SNS 4A
JMP 1D
RSW [SIM
STC 9A
JMP 1A
#1D LDA i [CLEAR A
15
OPR 4M [DATA OUT
LDA i [LOAD S
4L
JMP 2B [OUT CHK
LDA i [LOGIC A
4N
JMP 2B [OUT CHK
LDA i [STORE A
11
OPR 4M [DATA OUT
LDA i [LOAD S
4L
JMP 2B [OUT CHK
RSW
OPR 4M [DATA OUT
LDA i [LOAD A
 4N
JMP 2B [CTRL OUT AND CHK
JMP 1A
[EXAM
#1E SNS 4A
JMP 1G
LDA [SIM READ
 9S
ADA i
 2000
STC p+2
LDA [READ
 0
ADM [M+A
 9A
JMP 1M
#1G LDA i [READ MEM
 4O
JMP 2J [CTRL OUT
JMP 1P
[LOAD
#1L RCG
 3|4E
SNS i 4A
JMP 1A
#1H SET i 1
 3777
#1K LDA i [STORE D
11
OPR 4M [DATA OUT
LDA i [LOAD S
4L
JMP 2B [OUT CHK
LDA i 1 [DATA
OPR 4M [DATA OUT
LDA i [LOAD A
 4N
JMP 2B [OUT CHK
LDA [ADDR
 1
ADA i
 -2000
APO
COM [-0
OPR 4M [ADDR OUT
LDA i [LOAD S
 4L
JMP 2B [OUT CHK
LDA i [WRITE
 4P
JMP 2B [OUT CHK
XSK 1 [THRU?
JMP 1K [NO
JMP 1A
[FILL
#1F SNS 4A
JMP 1J
LDA [SIM WRITE
 9S
ADA i
 2000
STC 1I
ADD 9A [ACC
STA [WRITE
#1I
JMP 1A
#1J LDA i [WRITE
 4P
JMP 2B [OUT CHK
JMP 1A
[
[SUBROUTINES
[READ AND DISP JANC REGS
#3D LDA
 0
STC 3R
SNS 4A
JMP 3B [MM
LDA [SIM
 9A
STA i
#3A
LDA
 9S [SIM S
STA i
#3S
LDA
 9P [SIM P
STA i
#3P
JMP 3C
#3B CLR
OPR 4B [JANC A
STC 3A
OPR 4C
STC 3S [JANC S
OPR 4D [JANC P
STC 3P
[DISP A, S, P
#3C SETi1 [H POSIT
 200
LDA i [VERT
 300
DSCi [A
 4477
DSCi
 7744
SETi1
 200
LDA i
 200
DSCi [S
 5121
DSCi
 4651
SETi 1
 200
LDA i
 100
DSCi [P
 4477
DSCi
 3044
LDA i
 300
STC 2V
LDA i
 300
STC 2H
LDA
 3A
JMP 2D
LDA i
 200
STC 2V
LDA
 3S
JMP 2D
LDA i
 100
STC 2V
LDA
 3P
JMP 2D
#3R   [RET
[
[DISP #
[4 DIGIT # IN ACC
[H POSIT IN 2H
[V POSIT IN 2V
#2D STC 2C
ADD 0
STC 2R
SET i 3 [# CHARS
 -4
SET i 1
#2H  [H POSIT
#2G LDA i
#2C
ROL 3
STA
 2C
BCL i
 7770
ROL 1
ADA i
 2F
STC 2
LDA i
#2V  [VERT POSIT
DSC 2
DSC i 2
XSK i 1
XSK i 1
XSK i 3
JMP 2G
#2R   [RET
[CHARS 0-7
#2F 4136
3641
2101
0177
4523
2151
4122
2651
2414
0477
5172
0651
1506
4225
4443
6050
[
[MM SUBRS
[CONTROL OUT AND CHK
#2B STA
 2E
BCO [MOD IN VECT
 2I
STC 2I
LDA i
#2E
BCO [MOD OUT VECT
 2O
OPR 4F [OUT
STC 2O
OPR 4G [IN
SAE
 2I
HLT [NO RET
JMP 0
[
[CONTROL OUT
#2J BCO [MOD OUT VECT
 2O
OPR 4F [OUT
STC 2O
JMP 0
[
[TEST CONTROL RET
[TO p+1 IF NOT RET
[TO p+2 IF RET
#2K STC 2L [SAVE
ADD 0 [SAVE RET
STC 2M
ADD 2L
BCO [MOD IN VECT
 2I
STC 2I
OPR 4G [IN
SAE
 2I
JMP 2N [NO RET
LDA i
 1
ADM [INC RET
 2M
#2M   [RET
#2N LDA i [FIX IN VECT
#2L 0
BCO
 2I
STC 2I
JMP 2M
[
[TTL SUBR
#3T LDA [SAVE RET
 0
STC 3E
SNS 4A
JMP 3G [NO SIM
ADD 9S [SIM
JMP 3F
#3G OPR 4C [JANC S
#3F BCL i [DECODE
7000
ADA i
JMP 3H
STC p+1
0
[KNOB 0
#3I SAM 0
JMP 3M
[KNOB 1
#3J SAM 1
JMP 3M
[KNOB 2
#3K SAM 2
JMP 3M
[KNOB 3
#3L SAM 3
JMP 3M
[STORE ACC IN JANC A
#3M JMP 3N
[RETURN
#3E
[TTL JMP TABLE
#3H JMP 3I
JMP 3J
JMP 3K
JMP 3L
[
[SUBRS FOR TTL
[STORE LINC ACC IN JANC ACC
#3N STC 3U [SAVE DATA
ADD 0 [SAVE RET
STC 3O
SNS 4A
JMP 3V [NO SIM
LDA i [SIM
#3U
STC 9A
JMP 3O
#3V LDA i [STORE A
 11
OPR 4M [DATA OUT
LDA i [LOAD S
 4L
JMP 2B [OUT CHK
LDA [DATA
 3U
OPR 4M [DATA OUT
LDA i [LOGIC A
 4N
JMP 2B [OUT CHK
#3O   [RETURN
[
[GET JANC A
#3W LDA [SAVE RET
 0
STC 3X
SNS 4A
JMP 3Y
ADD 9A [SIM
JMP 3X
#3Y OPR 4B
#3X   [RETURN
[
[TAGS
[SIM SW
4A=5
[JANC A IN
4B=0
[JANC S IN
4C=1
[JANC P IN
4D=2
[BINARY BN MUST END IN 4
4E=274
[MM CONTROL OUT OPR
4F=10
[MM CONTROL IN OPR
4G=11
[MM START JANC
4H=4000
[MM RESUME JANC
4I=2000
[MM RET JANC I BY I
4J=4
[MM RET TTL
4K=400
[MM CTRL LOAD JANC S
4L=200
[DATA TO JANC S
4M=4
[MM CTRL LOAD JANC A
4N=100
[MM CTRL READ JANC MEM
4O=40
[MM CTRL WRITE JANC MEM
4P=20
[MM CTRL XTRA
4Q=10
$1000
[ENTERING FROM CONTROL
#9B LDA
0
STC 9R
#9W JMP 9N
ADD 9S
BCL i
0777
ROL 3
ADA i
JMP 9C
STC p+1
0 [JMP 9C+N
#9N LDA
0
STC 9O
ADD 9P
STA
9S
ADA i
1
STC 9P
ADD 9S
ADA i
2000
STC 10
LDA 10
STC 9S
#9O 0 [JMP RETURN
[ADD
#8W JMP 9N
ADD 9S
ADA i
2000
STC 10
CLR
LDA 10
LAM
9A
OVF
JMP p+5
LDA i
7777
STC 8C
JMP 9Q
LDA i
0000
STC 8C
JMP 9Q
[DECODE ADD
#9D ADD 9S
BCL i
7760
ADA i
JMP 9L
STC p+1
0 [JMP 9L+N
[CAD
#8Z LDA i
7777
STC 9A
JMP 8W
[LDA
#8Y LDA i
0
STC 9A
JMP 8W
[CAA
#8X LDA
9A
COM
STC 9A
JMP 8W
[STO
#9E JMP 9N
ADD 9S
ADA i
2000
STC 9T
ADD 9A
STA
#9T 0
STC 9X
JMP 9Q
[JSR
#9F JMP 9N
ADD 9S
ADA i
2000
STC 10
ADD 9P
STA 10
LDA
9S
STC 9P
JMP 8B
[COMPARE
#8A ADD 9S
BCL i
7760
ADA i
JMP 9U
STC p+1
0 [JMP 9U+N
[YES
#9G JMP 9N
LDA
9S
STC 9P
JMP 9Q
[TRC
#8V JMP 9G
[BPE
#8U LDA
9A
STC p+3
LSW
SAE i
0
JMP 8B [NO
JMP 9G [YES
[BOS
#8T LDA
8C
SAE i
7777
JMP 8B [NO
JMP 9G [YES
[BZA
#8S LDA
9A
SAE i
0
JMP 8B
JMP 9G
[TAU
#8R LDA
9A
ROR 13
BCL i
7776
STC p+7
LDA 
9A
ROR 12
BCL i
7776
SAE i 
0
JMP 8B 
JMP 9G
[BRP
#8Q LDA
9A
APO
JMP 8B
JMP 9G
[DTR
#8P JMP 8B
[BPU
#8O LDA
9A
STC p+3
LSW
SAE i
0
JMP 8B
JMP 9G
[BNV
#8N LDA
8C
SAE i
0
JMP 8B
JMP 9G
[BNZ
#8M LDA
9A
SAE i
0
JMP 9G
JMP 8B
[TAN
#8L LDA
9A
ROR 13
BCL i
7776
STC p+7
ADD 9A
ROR 12
BCL i
7776
SAE i
0
JMP 8B
JMP 9G
[BRN
#8K LDA
9A
APO i
JMP 8B
JMP 9G
[ADD 1 TO COUNTER
#8B CLR
LDA i
1
LAM
9P
JMP 9Q
[DIS
#9H LDA
9A
STC 9Y
ADD 9X
SCR 3
ADA i 
400
STC 11
ADD 9Y
SCR 3
DIS 11
JMP 9Q
[SHIFT DECODE
#9I ADD 9S
BCL i
7760
ADA i
JMP 9Z
STC p+1
0 [JMP 9Z+N
[SCA
#8J LDA
9A
SCR 1
STC 9A
JMP 9Q
[SRF 
#8I LDA 
9A
SCR 1
BSE i
4000
STC 9A
JMP 9Q
[SLR
#8H LDA
9A
SCR 1
BCL i
4000
STC 9A
JMP 9Q
[ROR
#8G LDA
9A
ROR 1
STC 9A
JMP 9Q
[SLS
#8F LDA 
9A
ROL 1
BSE i
0001
STC 9A
JMP 9Q
[ROL
#8E LDA
9A
ROL 1
STC 9A
JMP 9Q
[SLL
#8D LDA
9A
ROL 1
BCL i
0001
STC 9A
JMP 9Q
[SPARE
#9J 0
[TTL
#9K LDA
9R
ADA i
1
STC 9R
JMP 9R
#9Q SNS 9V
JMP 9W
JMP 9R
#9C JMP 9D
JMP 9E
JMP 9F
JMP 8A
JMP 9H
JMP 9I
JMP 9J
JMP 9K
#9L 0
0
0
0
0
0
0
0
0
0
0
0
JMP 8Z
JMP 8Y
JMP 8X
JMP 8W
#9U JMP 8V
JMP 8U
JMP 8T
JMP 8S
JMP 8R
0
JMP 8Q
0
JMP 8P
JMP 8O
JMP 8N
JMP 8M 
JMP 8L
0
JMP 8K
#9Z JMP 8J
0
JMP 8I
0
JMP 8H
0
JMP 8G
0
JMP 8F
0
JMP 8E
0
0
0
JMP 8D
9V=4
#9R 0 [RETURN TO CONTROL
#9A 0 [ACCUMULATOR
#9P 0 [PROGRAM COUNTER
#9S 0 [MEMORY ADDRESS REGISTER
#9M 0 [MEMORY
#9X 0 [X VALUE-DISPLAY
#9Y 0 [Y VALUE-DISPLAY
#8C 0 [FLAG REGISTER