Directory of image this file is from
This file as a plain text file

[
[
[     JANC
[ M GRALIA
[ FEB 4
[
[TEXT DISPLAYING ROUTINE
[
[SAYS "HELLO WESLEY;
$0
#9A LDA [SETUP ORIGIN
9X
STO
3A
LDA
9Y
STO
3B
LDA [WHICH TEXT?
3S
BPE
9C
LDA [USE "JANC SAYS;
1B
TRC
9D
#9C LDA [USE "HELLO WESLEY;
1A
#9D STO
3P
JSR
6A+1
TRC
9A
[
[INTERPRET UNPACKED DATA
#6A TRC
0
#6B LDA [BEGIN CODE INTERPRET
3P
STO
6C
LDA [FETCH CODE
#6C 0
ADD [ADD TABLE ORIGIN
6E
STO
6D
LDA [UPDATE POINTER
3P
ADD
3S
STO
3P
TRC [GO TO TABLE
#6D 0
#6E p+1 [JUMPS TO PLOTTERS
TRC
6A
TRC
2A
TRC
2B
TRC
2C
TRC
2D
TRC
2E
TRC
2F
TRC
2G
TRC
2H
TRC
2J
TRC
2K
TRC
2L
TRC
2M
TRC
2N
TRC
2P
TRC
2Q
TRC
2R
TRC [NEXT CHAR
6F
0
0
[MOVE RIGHT TO NEXT CHAR POSITION
#6F LDA [CHECK LEFT MARGIN
3A
ADD
3Q
STO
3A
BRN [STILL IN LEFT HALF
6B
CAA [OFF SCREEN?-
3R
BRN [YES, STOP
6A
TRC [NORMAL EXIT
6B
[
[DISPLAY SEGMENT A
#2A LDA [SET X
3A
ADD
3D
STO
3M
LDA [SET Y
3B
ADD
3J
STO
3N
TRC
2T
[
[DISPLAY SEGMENT B
#2B LDA [SET X
3A
STO
3M
LDA [SET Y
3B
ADD
3J
STO
3N
TRC
2T
[
[DISPLAY SEGMENT C
#2C LDA [SET X
3A
ADD
3D
STO
3M
LDA [SET Y
3B
STO
3N
TRC
2S
[
[DISPLAY SEGMENT D
#2D LDA [SET X
3A
ADD
3D
STO
3M
LDA [SET Y
3B
ADD
3J
STO
3N
TRC
2V
[
[DISPLAY SEGMENT E
#2E LDA [SET X
3A
STO
3M
LDA [SET Y
3B
STO
3N
TRC [GO DISPLAY
2S
[
[DISPLAY SEGMENT F
#2F LDA [SET X
3A
STO
3M
LDA [SET Y
3B
STO
3N
TRC [GO DISPLAY
2U
[
[DISPLAY SEGMENT G
#2G LDA [SET X
3A
ADD
3C
STO
3M
LDA [SET Y
3B
STO
3N
TRC
2S
[
[DISPLAY SEGMENT H
#2H LDA
3A
ADD
3D
STO
3M
LDA [SET Y
3B
STO
3N
TRC
2T
[
[DISPLAY SEGMENT J
#2J LDA
3A
STO
3M
LDA
3B
STO
3N
TRC
2T
[
[DISPLAY SEGMENT K
#2K LDA [SET X
3A
ADD
3D
STO
3M
LDA [SET Y
3B
ADD
3K
STO
3N
TRC [GO DISPLAY
2S
TRC
6B
[
[DISPLAY SEGMENT L
#2L LDA [SET X
3A
ADD
3D
STO
3M
LDA [SET Y
3B
ADD
3K
STO
3N
TRC [GO DISPLAY
2U
[
[DISPLAY SEGMENT M
#2M LDA
3A
STO
3M
LDA
3B
ADD
3K
STO
3N
TRC
2S
[
[DISPLAY SEGMENT N
#2N LDA
3A
STO
3M
LDA [SET Y
3B
STO
3N
TRC
2V
[
[DISPLAY SEGMENT P
#2P LDA [SET X
3A
ADD
3C
STO
3M
LDA [SET Y
3B
ADD
3K
STO
3N
TRC [DISPLAY
2S
[
[DISPLAY SEGMENT Q
#2Q LDA [SET X
3A
ADD
3D
STO
3M
LDA [SET Y
3B
ADD
3K
STO
3N
TRC
2T
[
[DISPLAY SEGMENT R
#2R LDA [SET X
3A
STO
3M
LDA [SET Y
3B
ADD
3K
STO
3N
TRC
2T
[
[DISPLAY MICROSEGMENT S
#2S LDA [SET COUNTER
3H
STO
3Z
LDA [SET Y
3N
ADD [SKIP ORIGIN POINT
3U
STO
3N
LDA
3M
#4S STO [SET + DISPLAY
3M
LDA
3N
DIS
CAD [UPDATE COUNT
3Z
BRN [RETURN
6B
STO
3Z
LDA [CALC Y
3N
ADD
3U
STO
3N
LDA
3M
TRC
4S
[
[DISPLAY MICROSEGMENT T
#2T LDA [SET COUNTER
3G
STO
3Z
LDA [SET X
3M
#4T ADD [CALC + DISPLAY
3T
STO
3X
LDA
3N
DIS
CAD [UPDATE COUNT
3Z
BRN [RETURN
6B
STO
3Z
LDA
3X
TRC
4T
[
[DISPLAY MICROSEGMENT U
#2U LDA [SET COUNTER
3G
STO
3Z
LDA [SET X
3M
STO
3X
LDA [SET Y
3N
#4U ADD [UPDATE Y
3U
STO
3Y
LDA [UPDATE X
3X
ADD
3T
STO [SET + DISPLAY
3X
LDA
3Y
DIS
CAD [UPDATE COUNT
3Z
BRN [RETURN
6B
STO
3Z
LDA
3Y
TRC
4U
[
[DISPLAY MICROSEGMENT V
#2V LDA [SET COUNTER
3G
STO
3Z
LDA [SET X
3M
STO
3X
LDA [SET Y
3N
#4V ADD [UPDATE  Y
3V
STO
3Y
LDA [UPDATE X
3X
ADD
3T
STO [SET + DISPLAY
3X
LDA
3Y
DIS
CAD [UPDATE COUNT
3Z
BRN [RETURN
6B
STO
3Z
LDA
3Y
TRC
4V
[
[CONSTANTS
#3A 0 [CURRENT X ORIGIN
#3B 0 [CURRENT Y ORIGIN
[.5 CHAR WIDTH
#3C 200
[NEG OF 3C
#3D 7600
[# PTS IN X DIRECTION
#3G 4
[# PTS IN Y DIRECTION
#3H 5
[.5 CHAR HEIGHT
#3J 300
[NEG OF 3J
#3K 7500
[PRECESSING SPEED
#3L 7770
#3M 0 [MICROSEGMENT X ORIGIN
#3N 0 [MICROSEGMENT Y ORIGIN
#3P 0 [POINTS TO TEXT
[CHARACTER-CHARACTER SPACING
#3Q 450
[SCREEN RIGHT MARGIN
#3R 3400
#3S 1 [NUMBER ONE
[SPACING WITHIN SEG - X
#3T 25
[SPACING WITHIN SEG - Y
#3U 36
[NEG OF 3U
#3V 7742
#3X 0 [TS FOR X
#3Y 0 [TS FOR Y
#3Z 0 [TS FOR COUNTER
[TEXT BEGINNING X,Y ORIGINS
#9X 4600
#9Y 0
#1A p+1 [TEXT "HELLO WESLEY;
6 [H
24
20
22
16
34
42
4 [E
2
6
20
24
36
40
42
6 [L
24
36
40
42
6 [L
24
36
40
42
4 [0
2
6
24
36
40
34
16
42
42 [SPACE
6 [W
24
36
30
40
34
16
42
4 [E
2
6
20
24
36
40
42
4 [GOOD S
2
6
20
22
34
40
36
42
6 [L
24
36
40
42
4 [E
2
6
20
24
36
40
42
10 [Y
14
30
0
#1B p+1 [TEXT "JANC SAYS;
2 [J
4
12
30
36
24
42
24 [A
6
2
4
16
34
20
22
42
24 [N
6
10
32
34
16
42
4 [C
2
6
24
36
40
42
42 [SPACE
4 [S
2
10
32
40
36
42
24 [A
6
2
4
16
34
20
22
42
10 [Y
14
30
42
4 [S
2
10
32
40
36
0