Directory of image this file is from
This file as a plain text file

[LINCDMP6
[
[SEND START OF BLK
[WITH 4 BITS OF BN
[IN CODES
[0X80-0X8F
[
[THE END OF BLK
[ IS 0X90  FOR A GOOD BLK
[AND 0X91 FOR A
[BAD BLK
[
[SCAN THE TAPE ON
[UNIT 1U AND COUNT
[THE BAD BLOCKS.
[PUT THE BAD BLOCK
[NUMBERS AT 1400
[
[SENSE SWITCH 0 WILK
[TERMINATE THE SCAN
[
[
1U=u
$1
JMP 20
$20
LDA i
4|0
STC 1F
SET i 12
0  [BAD COUNTER
SET i 13
1400-1
SET i 14
-1000
SET i 15
RCG
SET i 16
7300
LDA i
4|0
STC 1B
[
#1A SNS i 0
JMP 1C [ SKIP CHECK
RDE i 1U
#1B 4|0
AZE
JMP 1E
LDA i 
1
ADM
1B
XSK i 14
JMP 1A
CHK 1U
0 [REWIND
JMP 1C [DUMP 
[
[
#1E LDA
1B
BCL i
7000
STA i 13
XSK i 12
JMP 0 [RTN
HLT [CANT HAPPEN
#1C LDA [BAD CNT
12
AZE
#1I HLT [ # BAD BLKS
[
[ AFTER A GOOD OR BAD
[ FIRST PASS, RESET
[THE ERROR PTRS
[AND SEND ALL BLOCKS
[ TO THE TTY
LDA
12
AZE i
JMP 1L
COM
STC 12
SET i 13
1400-1
STA  i 13
XSK i 12
JMP p-2
#1L SET i 12
0
SET i 13
1400-1
[NOW DUMP TAPE IN
[ GROUPS OF 4 BLOCKS
SET i 14
-200
[128 GROUPS OF 4
#1D SET i 7
2C-1
CLR
STA i 7
[MARK BLK GOOD
RDE i 1U
#1F 4|0
AZE
JMP 3A
LDA
1F
ADA i
1001
STC 1H
STA i 7
RDE i 1U
#1H
AZE
JMP 3B
LDA
1H
ADA i
1001
STC 1J
STA i 7
RDE i 1U
#1J
AZE
JMP 3C
LDA
1J
ADA i
1001
STC 1K
STA i 7
RDE 1U
#1K
AZE
JMP 3D
[ UPPER MEMORY IS FULL
SET i 13
4|3777
[SEND UPPER MEMORY
[ONE BLK AT A TIME
SET i 7
2C-1
SET i 6
-4
#1M LDA
1F
BCL i 
7000
#1Q STA i
#1N 0  [LOCAL BN
JMP 2D [SEND
[START OF BLOCK
#1G LDH i 13
[DO AN XFER CHECK
BCO 
4C
STA
4C
LDH 13
ADA i
440
[BIAS DATA BY 32
[AND SET THE
[STOP BIT
ROL 1
JMP 2S
XSK i 5
JMP 1G
JMP 1P [END 
[THIS BLK
XSK i 6
JMP 1Q
LDA i
4
ADM
1F
XSK i 14
JMP 1D
CHK 1U
0
[ CHECK FOR FUZZY
[ BLOCKS DURING
[ TAPE DUMP
LDA
12
AZE i
JMP 15 [RTN TO LAP
#3I HLT [EXAMINE A REG
[ AND 1400 TO REVIEW
[ BADLY DUMPED BLKS
JMP 15 [ RTN
JMP 15 [RTN TO LAP
[
[
[TRANSFER CHECK
#4C 0
[
[ONE FLAG LOCATION
[FOR EACH BLK IN
[A GROUP OF 4
#2C 0
0
0
0
[
[
[SEND ONE CHARACTER
[LONG CODE TO PRESERVE
[BOTH TIMING AND
[THE RELAY REGISTER
#2R RTA PATTERN
[BIT ZERO CLEARED
#2T ORIGINAL TTY CHAR
[THEN ROTATED
[
[6-BIT PATTERNS FOR 
[EACH BIT SENT
[TO THE RELAY REGISTER
#2P[0 START BIT
1 DATA 0
2
3
4
5
6
7
8
9 STOP BIT
[
9B=-12
9S=2P-1
[
#2S SET 17
0
STC 2T
RTA
BCL i
1
STC 2R
[BUILD BIT STREAM
SET i 10
9S
SET i 11
9B
#2A LDA
2T
BCL i
7776
BSE
2R
STA i 10
SRO
2T
NOP
XSK i 11
JMP 2A
[ SEND THE BITS
SET i 10
9S
SET i 11
9B
#2B LDA i 10
ATR
[ WASTE CYCLES
[9600
JMP p+1
JMP p+1
NOP
[
XSK i 11
JMP 2B
JMP 17
[
[HANDLE ERROR BLKS
[RETRY 10 TIMES
#3A SET 17
0
LDA
1F
JMP 3E
#3B SET 17
0
LDA
1H
JMP 3E
#3C SET 17
0
LDA
1J
JMP 3E
#3D SET 17
0
LDA
1K
[
[
#3E SET i 11
-10
STA
3G
STC 3H
#3F RDE i 1U
#3G QN,BN BAD BLK
AZE i
JMP 17 [GOOD XIT
XSK i 11
JMP 3F [RETRY
[FAILED
[READ IT ANYWAY
RDE i 1U
#3H QN,BN
AZE i
JMP 17 [GOOD XIT
XSK i 12
NOP
LDA
3G
BCL i
7000
STA i 13
JMP 17 [BACK TO DUMP
[
[
[GENERATE START OF
[BLOCK
#2D SET 1
0
BCL i
7760
[FOUR BITS OF BN
BSE i
600
[0X80 AND STOP BIT
ROL 1
JMP 2S [SEND
[ INITIALIZE
[ XFER CHECK
CLR
STC 4C
SET i 5
-1000
[512 DATA CHARS
[ PER BLK
JMP 1
[
[END THIS BLK
#1S 0[LOCAL CHAR
[
#1P SET 1
0
[FORMAT AND SEND
[XFER CHECK
[FORMAT 6 BIT SUM
[AS A NORMAL DATA
[CHARACTER
LDA
4C
BCL i
7700
ADA i
440
ROL 1
JMP 2S
LDA i
620
[0X90 AND STOP BIT
STC 1S
LDA i 7
AZE
JMP 1T [BAD
LDA
1S
ROL 1
JMP 2S [GOOD
JMP 1W
#1T LDA 
1S
ADA i
#1V 1
ROL 1
JMP 2S
#1W LDA
1N
ADD 1V
JMP 1
[
[
$1400 [ERROR BLKS
#4X 0
0
0
0
0
0
0
0
[
[[