Directory of image this file is from
This file as a plain text file

[MISC-3A
[PAGE 4
[PART OF THE FFT PROG
[SAV CONTENTS OF EITHER
[PGS 12,13,14 OR 15,16,17
[ON TP ON BLKS DETERM BY THE RSW
[IT DOESNT SAM AN EX CHA
[S COMMANDS TO SAVE
[R AFTER S SAV PGS 15,16,17
[A AFTER S SAV PGS 12,13,14
$20
STC 3D
ZTA
STC 3J
ADD 0
STC 3J+1
ADD 3D
SHD i
2400   [A
JMP 2K  [AMP AND PHASE
SHD i
3700  [L
JMP 2B [LIST AMP AND PHASE
SHD i
3200  [G
JMP 2T [GRAPH AMP OR PHASE
SHD i
4600  [S
JMP 2R+13 [FOR TVCHANN
LMB 5 [CALL FILTER
JMP 20
JMP 3J
#2T KBD i  [AMP OR PHASE ON DISP
SHD i
2400   [AMP
JMP p+5  [AMP DISP
SHD i
4100  [PHASE
JMP 2S+6
JMP 3J [INVALID CODE
LDA i  [ADD INST ON DIS PRO
LDA i6
UMB 2
STA
2E
JMP 2C
CLR
LMB 2
JMP 20
LDA i [RESTR NOP ON DIS PRO
NOP
UMB 2
STA
2E
#2S LDA i [RESTOR PAGS IN DIS PRO
JMP 3J
STC 2V
LDA i
UMB 15
JMP 2C+5
LDA i    [ADD INST JMP2E+7 IN DIS PRO
2E
ADA i
4007
UMB 2
STA
2F
JMP 2C
LDA i
-1
LMB 2
JMP 20
LDA i [RESTOR NOP IN DIS PRO
NOP
UMB 2
STA
2F
JMP 2S
#3D 0000
#2C CLR [CHANGE PAGES IN D TO 12,13,14
ADD 0
STC 2V
LDA i
UMB 12
UMB 2
STA
2A
STA
2L
ADA i
1        [UMB 13
STA
2A+3
STA
2L+3
ADD p-5 [UMB 14
STA 
2A+6
STA
2L+6
#2V RETURN [OR JMP 3J
2A=2034 [AD OF 2A IN DIS PRO
2L=2154 [AR OF 2L IN DIS PRO
2E=2073 [AD OF 2E IN DIS PRO
2F=2025 [AD OF 2F IN DIS PRO
#2B JMP 2G  [LIST AMP AND PHASE
LMB 1
JMP 20
LDA i  [RESTORE PAGES IN PA
JMP 3J
STC 2G+21
LDA i
UMB 15
JMP 2G+4
#2G CLR
ADD 0
STC 2G+21
LDA i   [CHANGE PGS IN PA
UMB12
UMB 1
STA
2064
STA
2111
ADD 2V-12
STA
2067
STA
2106
ADD 2V-12
STA
2072
RETURN
#2R KBD i  [SAV ON TP
SAE i
45   [R,SAV PGS 15,16,17
JMP p+2
JMP p+7
SAE i
24   [A,SAV PGS 12,13,14
JMP 3J
LDA i  [SET4NGS TO 12,13,14
UMB 12
JMP p+3
LDA i  [SET PGS TO15,16,17
UMB 15
STA
2J
ADA i
1
STA
2J+11
ADA i
1
STC 2J+22
#2D SET i17  [ENTER BLK NO 
-14
SET i16
-4
LDA i
2J+2
STA
2D+15
STC 2D+23
LDA i
X
STC 2D+21
LDA
2J+2
BCL i
0777
ADA i
X     [BLK NO
STA
2J+2
LDA
p-4
ADA i
1
STC p-7
XSK i17
JMP p+2
JMP 2J
XSK i16
JMP p+2
JMP p+5
ADD 2D+15
ADA i
2
JMP p+6
ADD 2D+15
ADA i
3
SET i 16
-4
STA
2D+15
STC 2D+23
JMP 2D+14
#2J UMB 12  [OR UMB 15
WRC
4|40
WRC
5|41
WRC
6|42
WRC
7|43
UMB 13  [OR UMB 16
WRC
4|44
WRC
5|45
WRC
6|46
WRC
7|47
UMB 14  [OR UMB 17
WRC
4|50
WRC
5|51
WRC
6|52
WRC
7|53
JMP 3J
#3J LMB 0
JMP 104 [NEXT KBD CODE
[ABSANGLE
[|AMPLITUDE| PHASE ANGLE -PI TO +PI X=REAL, Y=IMAG.
#2K SET i4
2000
SET i 5
2001
UMB 15  [GET X AND Y
LDA 4
STC 3K
LDA 5
STC 3K+3
UMB 16
LDA 4
STC 3K+1
LDA 5
STC 3K+4
UMB 17
LDA 4
STC 3K+2
LDA 5
STC 3K+5
ADD 3K+1 [X MSB
BCL i
3777
ROL 1
STC 4K+1 [SIGN OF X
ADD 3K+4 [Y MSB
BCL i
3777
ROL 1
STA
1K+7   [SIGN OF Y
ADD 4K+1
STC 4K+4
#6K ADD 3K+1 [X MSB
APO i [NEG
JMP p+5
JMP 1S [ABS X
3K+17  [CONST 0
3K     [X
3K
LDA
3K+4   [Y MSB
APO i
JMP p+5
JMP 1S [ABS Y
3K+17  [CONST 0
3K+3   [Y
3K+3
LDA [CHECK Y=0
3K+4   [Y MSB
AZE
JMP p+14
CLR [PHI=0
STC 3K+11
STC 3K+12
STC 3K+13
ADD 3K [AMP=X
STC 3K+6
ADD 3K+1
STC 3K+7
ADD 3K+2
STC 3K+10
JMP 4K
LDA i
JMP 1K
STC 1H
JMP 1D [Y|X
3K+3   [Y
3K     [X
3K+11
LDA
3K+11  [Y|X EXP
AZE i
JMP p+15
APO    [Y|X EKP POS
JMP p+13
LDA i
1
STA
7J-6
STC 7J
JMP 1D [X|Y
3K
3K+3
3K+11
JMP p+5
CLR
STA
7J-6
STC 7J
SET i7
0
SETi6
2000
UMB 6  [PAG W TANG TAB
LDA
3K+11  [Y|X EXP OR X|Y EXP, WHATEV IS NEG
ADA i
7      [-7 SMALLST ACCEP EXP
APO
JMP 4J+10
LDA    [EXP G,T. -7
3K+11
AZE    [EXP=0
JMP p+3
CLR
STC 3K+11
SAE 6  [COMP W EXP OF VAL ON TABL
JMP p+27
LDA 6  [GET TANG VAL
STC 3K+25
LDA i 6
STC 3K+26
LDAi 6
STC 3K+27
JMP 1S [Y|X - TABLE VALUE
3K+11
3K+25
3K+25
LDA 
3K+26
AZE i
JMP p+16
APO
JMP p+14
XSK i 6
XSK i 7
JMP p-22
#4J X  [TEMPORARY STORAGE
X
X
XSKi6
XSKi6
XSKi6
XSKi7
JMP p-34
CLR
STC 4J
ADD 7  [N,CUR ORD NUM ON TAB
STC 4J+1
JMP 1I  [FLOAT N
4J 
4J
JMP 1M  [N#30 MIN
4J
5J
3K+11
SROi [1ST OCTANT
XXXX    [1 FRM360,0 FRM 371
JMP 6J [NO,PI|2-ANGLE
LDA i
JMP 8K
STC 1H
SRO i
#7J XXXX    [1 FRM 362,0 FRM 373
JMP p+11
JMP 1W [COS PHI
3K+11
3K+6
JMP 1D  [AMP=X|COS PHI
3K
3K+6
3K+6
JMP p+10
JMP 1Y [SIN PHI
3K+11
3K+6
JMP 1D  [AMP=Y|SIN PHI
3K+3
3K+6
3K+6
#4K SRO i   [SUB PI IF X AND Y ARE NEG,OR IF X IS NEG AND Y IS POS
XXXX    [BIT 0=SIGN X
JMP 5K [YES
SRO i [NO, COM?
XXXX    [SUMATIO OF SIGNS OF X AND Y
JMP 5K+5 [YES
CLR
STC 1H
UMB 12 [STORE IN PAGES 12,13,14
LDA
3K+6
STA 4
LDA
3K+11
STA 5
UMB 13
LDA
3K+7
STA 4
LDA
3K+12
STA 5
UMB 14
LDA
3K+10
STA 4
LDA
3K+13
STA 5
XSK 5
JMP p+2
JMP 3J
LDA i 4
LDA i 4
LDA i 5
LDA i 5
JMP 2K+4
#6J CLR
ADD 0
STC p+5
JMP 1S [PI|2-ANGLE
3K+22
3K+11
3K+11
RETURN
#5K JMP 1S [SUB PI
3K+11
3K+14
3K+11
JMP 4K+3
JMP 1S [COM
3K+17
3K+11
3K+11
JMP 4K+6
#1K LDA [X LARGER?
3K+3   [Y EXP
COM
ADD 3K [X EXP
APO i
JMP p+25 [YES
SRO i [NO, Y NEG?
XXXX    [SIGN Y
JMP p+6 [YES, PHI = -PI|2
JMP 1A [NO, PHI = PI|2
3K+17
3K+22
3K+11
JMP p+5
JMP 1S
3K+17
3K+22
3K+11
LDA [AMP = Y
3K+3
STC 3K+6
ADD 3K+4
STC 3K+7
ADD 3K+5
STC 3K+10
JMP 4K+6
CLR [PHI = 0
STC 3K+11
STC 3K+12
STC 3K+13
LDA [AMP = X
3K
STC 3K+6
ADD 3K+1
STC 3K+7
ADD 3K+2
STC 3K+10
JMP 4K
#8K LDA
3K+6
COM
ADD 3K
APO i
JMP 8K-10
LDA [AMP = Y
3K+3
STC 3K+6
ADD 3K+4
STC 3K+7
ADD 3K+5
STC 3K+10
JMP 4K
#3K 0000 [X
0000
0000
0000 [Y, 3K+3
0000
0000
0000 [AMP, 3K+6
0000
0000
0000 [ANGLE PHI, 3K+11
0000
0000
0002 [PI, 3K+14
3110
1762
0000 [CONSTANT 0, 3K+17
0000
0000
0001 [PI|2, 3K+22
3110
1762
0000 [TEMP TAN FROM TABLE, 3K+25
0000
0000
#5J -6 [30 MINS. IN RADS.
2167
3200
[XXXXXXXXXXXXXXXXX[
[XXXXXXXXXXXXXXXXXX[
[FLOSBASE
[FLOD-1R PIECED
[BASIC ROUTINES
[1N,1R,1X,1Q,1H
[TEMPORARY STORAGE
0
0
[NORMALIZE STEP
#1N LDA i
0
LAM
p-2
SCR 14
LDA i
0
LAM
p-2
OVF
JMP 0
ROR i 1
BCO i
0
STA i 3
ROL i 1
ZTA
BCO
p-5
ROL 1
ROR i1
STA i 3
[NORMAL EXIT
#1R NOP      [*  #1R LDA i 4
JMP p    [*      JMP 4
[SET INDEX REGISTERS
ADD 1Q+1 [+1
ADD 1Q+1
#1X ADD 1Q+1
STA
1R+1     [*    4
ADA i
-6003 [CONSTANT 1774
STC 3
LDA 3
STC 1
LDA i3
STC 2
LDA i3
STC 3
JMP 0
[ADJUST EXPONENT
#1Q LDA i
1
ADM 3
OVF
JMP 0
APO [SKIP IF UNDERFLOW
[ERROR STOP OR RETURN
#1H HLT      [*  #1H JMP 4
CLR
STA 3
STA i3
JMP 1R-1
[END FLODBASE
[JAN 6|26|69
[ADDD
[FLOD-1R PIECED
[ADD
#1A CLR
ADD 0
JMP 1X-2
LDA 1
COM
ADA 2
OVF
JMP p+4
SCR 14 [1A+10
BCO i
-40
APO i
JMP 1A+101
STC 1N-1
STC 1N+15
[SET UP ADDITION
[REG1 POINTS TO
[ADDEND WITH LARGER
[EXPONENT
[
LDA 2
STC 1N+6 [SMALLER EXPONENT
LDA 1
STA 3 [LARGER EXPONENT
LDA i 2
LDA i1
AZE
JMP p+5
[ADDEND WITH LARGER
[EXPONENT IS ZERO
ADD 1N+6
STA 3
JMP 1A+101 [SWAP
[LOAD LEFT HALF
[OF LARGER
LDA 1
STC 1N+6
[LOAD RIGHT HALF OF LARGER
LDA i 1
ROL 1
STC 1N+1
[SCALE SMALLER
ADD 1N-1
JMP 1A+110
STC 1A+53
[CLEAR LINK
ROL i1
ZTA
ROL 1
ZZZ
ADD 1Q+1 [+1
[RIGHT + RIGHT
LAM 
1N+1
SCR 14
[LEFT + LEFT
LDA i
0    [1A+53
LAM
1N+6
OVF
JMP p+6
[OVERFLOW:INDEX EXP. AND SCALE RIGHT 1
JMP 1Q
LDA
1N+6
ROR i 1
JMP 1N+16 [EXIT
STC 0
LAM
1N+1
STC 0
LAM
1N+6
AZE    [1A+73
JMP 1A+136
SAE
1N+1
JMP 1A+136
JMP 1H+1 [ZER0 RESULT
[SWAP REG1 AND REG2
STC 1N-2 [1A+101
ADD 2
SET 2
1
STC 1
ADD 1N-2
JMP 0
[24-BIT SCALE
APO   [1A+110
COM   [1A+111
ADA i
-14
SCR i 1
ROL i 1
[IF SCALE>14, L=0
APO i
ADD p-4
APO i
CLR
ADD 1A+130
STC 1A+134
LDA 2
STC 1N-2
LDA i 2
ROL 1
SCR 14 [1A+130
ADD 1N-2
LZE i
SCR 14
SCR X  [1A+134
JMP 0
[CLEAR LINK
ROL i1 [1A+136
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[END ADDD
[JAN 6|26|69
[SUBD
[FLOD-1R PIECED
[SUBTRACT
#1S CLR
ADD 0
JMP 1X-2
LDA 2
STC 1S+16
LDA i2
COM
STC 1S+17
LDA i2
COM
STC 1S+20
SET i2
1S+16
JMP 1A+3
[TEMPORARY STORAGE
0 [1S+16
0
0
[END SUBD
[JAN 6|26|69
[DIVD
[FLOD-1R PIECED
[DIVIDE
#1D CLR
ADD 0
JMP 1X-2
[COMPUTE EXPONENT
LDA 2
COM
ADA 1
STA 3
JMP 1Q+3
JMP 1Q
[SET SIGN
LDA i 2
BCO i 1
SCR 14
STC 1N+15
[CLEAR QUOTIENT
STC 1N+1
STC 1N+6
LDA 2
AZE i
JMP 1H [DIVISOR ZERO
APO i
COM
BCL i 
4000 [1D+25
[LEFT DIVISOR
STC 1D+37
LDA i 2
APO i
COM
[CLEAR SIGN AND ADD +1
ADD 1D+25
ROL i 1
ROR 1
[RIGHT DIVISOR
STC 1N-2
LAM i
0 [1D+37
LDA 1
AZE i
JMP 1H+1
APO
COM
[LEFT DIVIDEND
STC 1D+100
LDA i 1
APO
COM
[RIGHT DIVIDEND
STC 1N-1
JMP 1D+105 [TRIAL SUB
APO
JMP p+10
LDA i
-1 [CONSTANT
JMP 1Q+2
JMP 1D+63 [DIVIDE LOOP
JMP 1D+105 [TRIAL SUB
APO i
JMP 1D+73
[SUBTRACTION SUCCEEDED
ROL i 1
STC 1D+100
ZTA
ROL 1
BCL i 
4000
JMP 1D+102
[SUBTRACTION FAILED
CLR [1D+73
ADD 1N-1
SCR 12
ADD p+2
ADM i
0 [1D+100
ZTA
STC 1N-1 [1D+102
JMP 1N
JMP 1D+61 [CLOSE LOOP
[TRIAL SUBTRACT SR
CLR [1D+105
ADD 1N-1
ADD 1N-2
ROR i 1
SCR i 12
ADD 1D+100
ADD 1D+37
JMP 0
[END DIVD
[JAN 6|26|29
[MULD
[FLOD-1R PIECED
[MULTIPLY
#1M CLR
ADD 0
JMP 1X-2 [SET INDEX REGISTERS
LDA 2 [COMPUTE EXPONENT
ADA 1
JMP 1Q+3
STA 3
LDA i 2 [SET UP MULTIPLICANDS
STC 1N-1 [LWFT HALF
LDA i 2
STC 1N-2 [RIGHT HALF
LDA i 1
MUL [L1 X L2
4000+1N-1
AZE i
JMP 1H+1 [PRODUCT ZERO
LZE
COM
STC 1N+6
ZTA
STC 1N+1
LDA 1
MUL [L1 X R2
4000+1N-2
LZE
COM
ADM 
1N+1
ZSA
STC 1M+60
LZE
COM
STC 1N+15
LDA i 1
MUL [R1 X R2
4000+1N-2
LZE
COM
ADM 
1M+60
LDA 1
MUL [R1 X L2
4000+1N-1
LZE
COM
STC 0
ZTA
LAM i
0 [1M+60
BCL i 
3777
ROL i 2
LAM 
0
LAM
1N+1
BCL i
3777
ROL i 2
LAM 
1N+6
LDA
1M+60
ROL i 2
LDA 
1N+1
ROL i 1
STC 1N+1
[ 6LEAR LINK
ROL i 1 [1M+104
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[END MULD
[JAN 6|26|69
[COSSIND
[COS OR SIN OF X
[DOUBLE PRECISION
[TAYLOR SERIES
[USES FLOD-1R 1A,1M,1S,1D,1R,1Q,1H,1N,1X
[JMP 1W [COS, 1Y FOR SIN
[ADDR X
[ADDR RESULT
[
[COS OF X
[ONE  1W-22
1
2000
0
[POWER OF X 1W-17
0
0
0
[FACTORIAL  1W-14
0
0
0
[TERM  1W-11
0
0
0
[X"2  1W-6
0
0
0
[N  1W-3
0
0
0
#1W CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC 1W+121
ADD 3 [ADDR RESULT
STA
1W+116
STA
1W+106
STC 1W+110
[ONE TO SUM,POWER X,FACT
ADD 1W-22
STA 3
STA
1W-14
STC 1W-17
ADD 1W-21
STA i3
STA
1W-13
STC 1W-16
STA i3
STC 1W-12
STC 1W-15
[0 TO N
STC 1W-3
STC 1W-2
STC 1W-1
LDAi
JMP 1A
STA
1W+105
BCOi
JMP 1S
STC 1W+103
ADD 2
STA
p+6
STC p+6
LDAi2
AZEi
JMP 1W+121
JMP 1M
ADDRX
ADDR X
1W-6
[LOOP
JMP 1M [1W+55
1W-17
1W-6
1W-17
JMP 1A
1W-22
1W-3
1W-3
JMP 1M
1W-3
1W-14
1W-14
SROi
2525
JMP p-12
JMP 1D
1W-17
1W-14
1W-11
LDA
p+4
BCOi
ALTERNATE + , - 1W+103
STC p+1
JMP 1S [1W+105
ADDR RESULT [1W+106
1W-11
ADDR RESULT
LDAi
30
ADD 1W-11
COM
ADA
ADDR RESULT [1W+116
APO
JMP 1W+55
RETURN [1W+121
[ENTER SIN OF X
#1Y CLR
ADD 0
JMP 1X-1
ADD 1R+1
STC 1W+121
ADD 3
STC 1Y+20
ADD 2
STC p+3
JMP 1S
1Y+23
ADDR X
1W-11
SET i2
1W-11
SET i3
ADDR  RESULT [1Y+20
CLR
JMP 1W+5 
1  [PI|2  1Y+23
3110
1762
[END COSSIND
[JAN 9|1|69
[JAN 9|1|69
[FLINTD
[FLOD-1R PIECED
[FLOAT INTEGER
#1I CLR
ADD 0
JMP 1X-1
LDA i
26
JMP 1F+3
[END FLINTD
[JAN 6|26|69
[FLFRD
[FLOD-1R PIECED
[FLOAT FRACTION
#1F CLR
ADD 0
JMP 1X-1
STC 1N-1
STC 1N+15
LDA 2
STC 1N+6
ADD 1N-1 [EXPONENT
STA 3
LDA i 2
ROL 1
STC 1N+1
ADD 1N+6
AZE   
JMP 1F+23
SAE
1N-1
JMP 1F+23
JMP 1H+1 [ZERO RESULT
[ CLEAR LINK
ROL i1 [1F+23
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[END FLFRD
[JAN 6|26|69
[XXXXXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXXXXX