Directory of image this file is from
This file as a plain text file

[MMINST   4|17|71
[MM INSTRUMENTAL PROG
[---------------
[PRE DATA PRO 6000
[---------------
[USES BETA 1,2,3,4,5
[USES TAGS 1,2,3
[R A ELLIS
[WASHINGTON UNIVERSITY
[COMPUTER SYSTEMS LAB
[ST. LOUIS, MO. 63110
$1
HLT
[RESTART LAP6 IN 0,1
JMP 1L
$20
[------------------------------------------
[MAIN PROG
LMB 0
JMP 2P [PRESET
LMB 0
JMP 2R [MAIN SUBR
JMP p-2 [NO KST OR THRU
JMP 3N
[END MAIN PROG
[------------------------------------------
[ACROSS PAGE ENTRANCES
[PRESET ENT
$1000
#2P ZTA
STC 2Q
ADD 0
STC 2Q+1
JMP 1B
[
[MAIN SUBR ENT
$1010
#2R ZTA
STC 1R
ADD 0
STC 1R+1
JMP 1A
[CONTROL OUT AND CHK
$1020
#2S STC 3B
ZTA
STC 2T
ADD 0
STC 2T+1
LDA i
#3B
JMP 1G
#2T 0 [RET
0
[CONTROL OUT ENT
$1040
#2U STC 3C
ZTA
STC 2W
ADD 0
STC 2W+1
LDA i
#3C
JMP 1N
#2W 0 [RET
0
[CHECK CTRL RET ENT
$1060
#2Z STC 3D
ZTA
STC 3A
ADD 0
STC 3A+1
LDA i
#3D
JMP 1O [CHK CTRL
JMP 3A [NO RET
LDA i  [RET
1
ADM
3A+1
#3A 0 [RET
0
[PRESET ON
#1B CLR
OPR 2F [OUT
[PRESET OFF
LDA i
6000
OPR 2F [OUT
STA i
#2I   [IN VECTOR
STA i
#2O   [OUT VECTOR
#2Q 0 [RET
0
[MAIN SUBR
#1A JMP 1X [READ AND DISP REGS
[DISP CTRL IN AND OUT
LDA i
140
STC 2X
STC 2Y
OPR 2G [CTRL IN
STA [UPDATE IN VECT
 2I
JMP 2D
LDA i
-20
STC 2Y
LDA i
140
STC 2X
LDA
2O [OUT VECT
JMP 2D
KST i
JMP p+3
#1R  [RET
0
KBD i
SHD i
"D;
JMP 1D [DATA OUT
SHD i
"C;
JMP 1C [CONTROL
SHD i
"L;
JMP 1L [LAP6
STC 2N [OTHER KEY
LDA i
 1
ADM
 1R+1
LDA i
#2N  [KEY VALUE
JMP 1R
[LAP6
#1L UMB 0
LDA i
 RCG
STA
 2015
LDA i
 7300
STA
 2016
UMB 1
LMB 0
JMP 15
[DATA OUT
#1D RSW
STC 1E
#2M KBD i
STA
 1F
ADA i [LE 3J?
 -3J
APO i
JMP 2M [NO
3K [WHICH INTER?
 1F
ADA i [GE 4?
 -3
APO
JMP 2M [NO
LDA
 1F
SHD i
 1000
JMP 2M [= 10
SHD i
 1100
JMP 2M [= 11
#3I LDA i [MAKE OPR
 OPR 3F
ADM
 1F
LDA i [OUT DATA
#1E 0
#1F   [OPR N
JMP 1R
[CONTROL OUT
#1C KBD i
STA
 1P
ADA i
 -11 [BIT LE 9?
APO i
JMP 1C [NO
LDA i [MAKE ROL N
 ROL
ADM
 1P
LDA i
1
#1P  [ROL
JMP 1N [CTRL OUT
JMP 1R
[
[READ AND DISP DATA IN
#1X LDA
0
STC 1Y
CLR
OPR 3E
STC 1V
OPR 3E+1
STC 1V+1
OPR 3E+2
STC 1V+2
OPR 3E+3
STC 1V+3
LDA i [VERT
300
STC 2V
LDA i [HORIZ 0
40
STC 2H
SET i 4
1V-1
SET i 5
-4
#1W LDA i 4
JMP 1I [DISP IN
LDA i [INCR H
200
ADM
2H
XSK i 5
JMP 1W
3G [WHICH INTER?
CLR
OPR 3E+4
STC 1V
OPR 3E+5
STC 1V+1
OPR 3E+6
STC 1V+2
OPR 3E+7
STC 1V+3
LDA i [VERT
 240
STC 2V
LDA i [HORIZ 0
 40
STC 2H
SET i 4
 1V-1
SET i 5
 -4
#3H LDA i 4
JMP 1I [DISP #
LDA i [INC H
 200
ADM
 2H
XSK i 5
JMP 3H
#1Y [RET
#1V 0 [IN 0
0 [IN 1
0 [IN 2
0 [IN 3
[
[DISP #
[4 DIGIT # IN ACC
[H POSIT IN 2H
[V POSIT IN 2V
#1I STC 1H
ADD 0
STC 1U
SET i 3 [# CHARS
 -4
SET i 1
#2H  [H POSIT
#1M LDA i
#1H
ROL 3
STA
 1H
BCL i
 7770
ROL 1
ADA i
 1K
STC 2
LDA i
#2V  [VERT POSIT
DSC 2
DSC i 2
XSK i 1
XSK i 1
XSK i 3
JMP 1M
#1U   [RET
[CHARS 0-7
#1K 4136
3641
2101
0177
4523
2151
4122
2651
2414
0477
5172
0651
1506
4225
4443
6050
[
[BINARY DISP
#2X [HORIZ 0
#2Y [VERT 0
#2D STC 2A
ADD 0
STC 2J
SET 1 [H POSIT
 2X
SET i 5
-4
#1Z SET i 4
-3
#2E LDA i
#2A
APO
JMP 2C [1
LDA i [0
4136
STC 2K
LDA i
3641
STC 2L
JMP 2B
#2C LDA i
2101
STC 2K
LDA i
0177
STC 2L
#2B ADD 2A
ROL 1
STC 2A
ADD 2Y [VERT
DSC i
#2K
DSC i
#2L
XSK i 1
XSK i 1
XSK i 4
JMP 2E
LDA i
40
ADM
1
XSK i 5
JMP 1Z
#2J  [RET
[
[MM SUBRS
[CONTROL OUT AND CHK
#1G STA
 1J
BCO [MOD IN VECT
 2I
STC 2I
LDA i
#1J
BCO [MOD OUT VECT
 2O
OPR 2F [OUT
STC 2O
NOP [WAIT A BIT
NOP
NOP
NOP
OPR 2G [IN
SAE
 2I
HLT [NO RET
JMP 0
[
[CONTROL OUT
#1N BCO [MOD OUT VECT
 2O
OPR 2F [OUT
STC 2O
JMP 0
[
[TEST CONTROL RET
[TO p+1 IF NOT RET
[TO p+2 IF RET
#1O STA
 1Q
COM
STC 3L
ADD 0 [SAVE RET
STC 1S
ADD 1Q
BCO [MOD IN VECT
 2I
STA
 2I
BCL i
#3L  0 [IN MASK
STC 3M
OPR 2G [IN
BCL
 3L
SAE i
#3M  0 [MASKED 2I
JMP 1T [NO RET
LDA i
 1
ADM [INC RET
 1S
#1S  [RET
#1T LDA i [FIX IN VECT
#1Q
BCO
 2I
STC 2I
JMP 1S
[
[TO DISPLAY A GRAPH
#3N RDC i u
4|430
RDC i u
5|431
RDC i u
6|432
RDC u
7|433
LDA i
40
JMP 1G
SET i 3
-2000
SET i 4
2000-1
LDA i 4
OPR 6
LDA i 
100
JMP 1G
XSK i 3
JMP p-6
LDA i
200
JMP 1N
LMB 0
JMP 2R
JMP p-2
JMPp-3
[CONTROL OUT: 10 OR 47
2F=10
[CONTROL IN: 11 OR 67
2G=11
[1ST DATA IN: 0 OR 70
3E=0
[0TH DATA OUT: 0 OR 50
3F=0
[DATA DISP SWITCH: JMP 1Y OR NOP
3G=JMP 1Y
[TOP OF DATA OUT RANGE: 12 OR 11
3J=12
[DATA OUT CHANNEL RAGE TEST SWITCH: LDA OR JMP 3I
3K=LDA