Directory of image this file is from
This file as a plain text file

[LAP6A,MSDISPLY
[INITIAL SETTINGS
$15
RCG 7E
7|7D [INITIAL START
JMP 20
JMP 1A [START 20
JMP 1A
STC 20
SET i 17
JMP 1C-4
WRC 7E
7D
JMP 1C-4
#1A SET i 2
6777
LDA i
2065
STA i 2
COM
STA i 2
SET i 3
7001
SET i 5
6D
LDA i
5|7A-1
STA
3B+7 [BN FOR BQ
STC 3W+11
ADD p-4 [FOR CHECKING WA TOO FULL
ADD 1W+11 [1000
STC 1G
ADD 1T+2 [FOR CONTROL BLOCK NOT FULL
STC 3L+7
STC 2X+5
ADD 1P
STA
3A+1
STC 3A+3
ADD 4A+3
STA
5B+1  [LNS|FRAME
ROL 4 [140-VERT
STC 5E+6
[KNOB SET
#1B JMP 5V [READ KNOB
STC 5F+2
COM
STC 1T+5 [TAPE OK
[SET TELETYPEWRITER
RTA
BSE i
1
ATR
[FIRST CHARACTER
#1C SET i 6
-777
JMP 5A
KBD
SET i 17
1H-4000 [CHARS
SHD i 17
JMP 1Y [1ST CASE
SHD i 17
JMP 1C+2 [EOL
SHD i 17
JMP 1D [DELETE
[REGULAR CHARACTER
#1R STH i 2
JMP 3G
JMP 3H
JMP 1L
JMP 3P
XSK i 6
JMP 1F
LDA i
12 [LINE TOO LONG
[EOL
#1E STH i 2
SET 6
3
LDH i 6
SHD i 
5600
JMP 1M
[REGULAR EOL
#1W JMP 3K
COM
ADD 3A+3
STC 3A+3 [MAX LN
JMP 1T
JMP 3G
JMP 3H
JMP 1L
JMP 3P
LDA
3A+3
AZE i
JMP 1D
LDA i [WA FULL
#1G 6|7A
SAE i
6|7G-1 [INDEX-1
JMP 1C
[DELETE WHOLE LINE
#1D LDA i
1
SAE
3A+3
JMP p+2
JMP 1A
SAE
3A+1
JMP p+2
JMP 1C
COM
JMP 3K+2
ADD 3A+3
STC 3A+3
JMP 1T
JMP 1K
JMP 1C
[DELETE UNFINISHED LINE OR META
#1K SET 10
0
JMP 3M
LDA i
-1
JMP 1L+2
STC 1L+3
JMP 3N+4
JMP 1K+2
SET 3
2
JMP 10
[COUNT PLAYGROUND
#1L LDA i
#1P 1
ADM i
PLAYGROUND SCORE
AZE
XSK i 0
ADD 1W+11 [1000
JMP 0
[TAPE NOT OK
#1T CLR
STC 2X+5 [CLEAR META EXIT
STC p+3
JMP 0
SRO i
7777  [OK IF ONE
XSK i 0 [OK
JMP 0 [NOT OK
[META CHECK
#1M LDH i 6
ADA i
-7
APO
JMP 4A
LDH 6
SHD i
3100  [FREE META
JMP 2J
ROL 6
STC 0
LDH i 6
ADD 0
SET i 1
6Z-2
SET i 7
-20
XSK i 7
JMP p+3
JMP 3N+4
JMP 1K-2
#1N XSK i 1
SAE i 1
JMP p-6
LDA i 1
JMP 1777
[KNOB SET
[NEW LINES|FRAME
#5L STA
5F+2
STA
5B+1 [LINES|FRAME
ROL 4
STC 5E+6 [VERTICAL
JMP 5B
[LOCATES
[LOCATE #
#4A LDA i
-4000
ADM
6
JMP 4U
ADD 1P
STA
4T
STC 4M
JMP 3N+4
JMP 1K
CLR
ADD 3A+1
COM
LAM
4T
JMP 1T+4
JMP 4S
LZE i
JMP 4L
LDA i
#4M REQ LN
COM
STC p+4
CLR
ADD 3A+3
LAM i
CHECK MAX
LDA
3A+3
LZE i
STC 4M
JMP 4L
[LOCATE FORWARD
[FORWARD PAGE
#4P LDA
5B+1
ADD 1K+4
AZE
JMP 4F+2
[FORWARD LINE
#4F CLR
ADD 1P
STC 4T
SET 10
1T+5 [TAPE STATUS
JMP 4H
LDA
10
STC 1T+5
JMP 1C
[SLIDE FORWARD
#4H SET 13
0
JMP 3A
JMP 13
JMP 3J
JMP 4J
JMP 3K
ADM
4T
#4J JMP 3E
JMP 3G
JMP 3H [WQ FULL
LDA
4T
AZE
JMP 4H+2
JMP 13
[PLAYGROUND FULL
#3P SET 17
0
JMP 3A
JMP 17
LDA
3B+7
STC 3F
SET 14
2
#3R LDH i 4
SHD i
7700
JMP 3S
STH i 2
JMP 3E
JMP 3G
NOP
JMP 3R
#3S STH i 2
JMP 3W
JMP 3B
SET 2
14
ADD 3A+6
STC 1G [WA FULL
JMP 3F-3
#3T LDA i
RDC 7B
JMP 3W+2
JMP 17
[MSINPUT SUBROUTINES
[CHECK WQ FULL
#3G SET 15
0
XSK i 0
LDA i
7377
SAE
2
JMP 0
JMP 3W
JMP 3B
JMP 1T [TAPE NOT OK
SET i 2
6777
JMP 3A [WA FULL
STC 1G
JMP 15
[WQ FULL-FIX BPL AND BQ
#3H SET 15
0
LDA i
-400
ADD 3
STC 3
ADD 3A+1
STA 5
XSK i 5
SET i 16 [WQ TO BQ
2777
SET i 14
2377
SET i 12
-400
LDA i 16
STA i 14
XSK i 12
JMP p-3
LDA
5
SAE i
6E
JMP 15
LDA i [CONTROL TABLE FULL
JMP 1T [MAKE TAPE ALWAYS NOT OK
STC 3L+7
SET i 5
6D
JMP 15
[CHECK CQ EMPTY
#3E SET 15
0
LDA
4
AZE
JMP 0
JMP 3X
JMP 3C
SET i 4
7377  [FIX PFA
JMP 15
[CHECK CONTINUATION
#3A LDA i
CURRENT LN
SAE i
MAXIMUM LN
XSK i 0
LDA i
BIGGEST BLOCK USED IN WA
JMP 0
[FIX BNS
SET 15
0
LDA i
#3F BQBN SAVED
SAE
3B+7
JMP p+2
JMP 3V-4
STA
3B+7
STC 3W+11
JMP 3B+6 [RDC BQ
ADD 3B+7
JMP 3V-11 [RDC CQ
[CQ TO WQ
#3J LDH i 4
STH i 2
SHD i
1200
XSK i 0
JMP 0
[EOL FIXES
#3K LDA i
1
ADD 3A+1
STC 3A+1
SET 3
2
ADD 1K+4
JMP 0
[MAKE TAPE OK
#3L SET 15
0
SET 4
2
LDA i
7777
STH i 4
STC 1T+5
ADD 3A+1
STA 5
LDA i
WRC i 7B
JMP 3W+2
ADD 3B+7
STA i
BQBN SAVED
BSE i
2000
STC 3C+1
JMP 3X
JMP 3C
LDA i
400
ADD 2
STC 4
#3V LDA i
6777
STC 1L+3
JMP 3G+15
[CHECK WQ EMPTY
#3M SET 15
0
LDA i
6777
SAE
2
JMP 0
ROL 3
JMP 3B+2
JMP 3B+6 [RDC BQ
ADD 3C
JMP 3W+2
SET i 2
7377
ADD 5
SAE i [CONTROL TABLE NOT EMPTY
6D
ADD 1K+4  [-1
STC 5
JMP 3G+15
[LOWER PSA, PFA
#3N LDA i
-4000
ADD 4
STC 4
LDA i
-4000
ADD 2
STC 2
LDH 2
SHD i
1200
XSK i 0
JMP 0
[DECODE META
#4U SET 16
0
CLR
STC 4T
LDH i 6
SHD i
1400
JMP p-3
ADD 1M+2
APO i
JMP 4T-1
LDH 6
ADD 4T
ROL 3
JMP 4U+3
LDA i
#4T NUM TO MOVE
ROR 3
JMP 16
[TAPE SRS FOR STRING SLIDE
[WQ WRC OR RDC, FWD OR BWD
#3W LDA i
WRC 7B
STC p+6
LDA i
1001
ADM
p+3
STC 3A+6 [WA BN
TAPE INSTR
BN-Q6
LDA
3B+7
STC p-3
JMP 0
[BQ RDC,FWD OR BWD
#3B LDA i
1
ADM
p+4
STC 3W+11
JMP 0
RDC i 7B
BN-Q5
JMP 0
[CQ FIX
#3X LDA i
1
ADM
3C+1
STC 3D
JMP 0
[CQ RDC FWD
#3C RDC 7B
BN-Q7
JMP 0
[CQ WRC BWD
WRC 7B
#3D BN-Q7
JMP 0
[META EXIT
SET i 17
JMP 1C-4 [FOR EXIT
#2X SET 1
0
JMP 3N+4
JMP 1K
SRO i
0
JMP 1
LDA i
-0
STC p-4
SET i 16
7|7D
WCG i 7E
7|7D
JMP 1
$1000
[ADD MANUSCRIPT
#2M JMP 2D
JMP p+2
JMP p+4 [NAME,UNIT
LDA
6E+1
JMP 2U+3
RDC i 7E
3|7D+24
JMP 1403
RDC 7E
3|7D+3
JMP 1C
[LOAD BINARY
#2K JMP 2D
NOP
JMP 2E
RDC i 7E
3|7D+24
JMP 1400
[DISPLAY
[ONCE PER ENTRY
#5A SET 17
0
#5B LDA i
LINES-FRAME
COM
STC 14
ADD 3A+1
STC 5C+3
SET 10
2
ADD 2
ADA i
-235-4000
STC 5D
LDH 10
SHD i
1200
JMP 5C
LDA i
-4000
ADM
10
SAE i
#5D NO MATTER
JMP 5D-11
LDA i
-1
ADD 5C+3
ROL 1
STC 5E+3
[PRESET-ONCE PER FRAME
#5E SET 14
10
LDA i
LN-1 FOR DIS
STC 5K+1
LDA i
VERT COOR
STC 5M+3
[ONCE PER LINE
#5F JMP 5V [READ KNOB
SAE i
KNOB 7 [LINES|FRAME
JMP 5L
KST i
JMP 17
[DISPLAY LN
#5H SET i 1
1013
LDA i
2
ADD 5K+1
STC 5K+1
JMP 5K
AZE
JMP 5J
ADA i
24
ADD 1
STC 1
JMP 5K-3
JMP p-7
#5J JMP 5Z+1
JMP 5K-3
JMP 5J
[FIRST CHARACTER
#5N SET i 1
1157
JMP 5X
LDH i 14
SHD i
2200
JMP 5P
SHD i
6600
JMP 5P
SHD i
5600
JMP 5Y
SET i 1
1277
#5P JMP 5Z
JMP 5X
LDH i 14
SAE i
12
JMP 5P
LDA i
1063
SAE
1
JMP 5W
JMP 5F
[DISPLAY META
#5Y LDA i
-337
STC 5M+3 [VERT
ADD 4U   [56
JMP 5W+5 [HORIZ
JMP 5Z
SET i 1
1103
JMP 5Z+6
JMP 5P+1
[DISPLAY
#5Z ROL 1
ADA i
#5M 6A-1
STC 12
ADA i
VERT COOR
DSC i 12
DSC i 12
XSK i 1
XSK i 1
XSK i 1
XSK i 1
JMP 0
#5W CLR
LDA i
-37
LAM
5M+3
BCL i 
7020
SET i 1
1063
KST i
JMP 17
SAE i
340
JMP 0
STC 5E+6 [MOVE DISPLAY TO TOP OF SCOPE
JMP 0
[CHK END OF FRAME
#5X LDA
2
SAE
14
JMP 0
SET i 1
1753
LDA i
156  [MARKER
JMP 5Z+1
JMP 5E
[EOL-LOWER LN
#5C LDA i
-1
ADM i
LN FOR DIS
AZE i
JMP 5E-2
XSK i 14
JMP 0
JMP 5E-2
[COUNT DIGITS
SRO i
4210
JMP 5J+3
#5K LDA i
LN FOR DIS
ROL 3
STA
5K+1
BCL i
7761
JMP 0
[KNOB SUBROUTINE
#5V SAM 7
SCR 4 [+,-7 OR +,-17
ADD 1M+2 [-7,GIVES -0 TO -16 OR -26 TO +10
APO i
CLR  [TOO BIG
ADD 1W+1 [17, GIVES 1 TO 17 OR -7 TO 17
APO i
JMP 0 [1 TO 17
LDA i
1     [TOO SMALL
JMP 0
[BACKWARD PAGE
#4Q LDA
5B+1
ADD 1K+4
AZE
JMP 4B+2
[BACKWARD LINE
#4B CLR
ADD 1P
STC 4T
JMP 1T+4
JMP p+2
JMP 4D
JMP 3A
JMP 3L
[BACKWARD SLIDE
#4D LDA i
1
SAE
3A+1
JMP p+2
JMP 1C
JMP 3M
[CHECK CQ FULL
#4C LDA i
7377
SAE 
4
JMP 4E
JMP 3D-1 [WRC CQ
STC 4
ADD 4E+5
JMP 3X+2
#4E LDH 2
STH 4
JMP 3N
JMP 4C-1
LDA i
-1
JMP 3K+2
ADM
4T
AZE
JMP 4C-7
JMP 1C
[LOCATE-TAPE NOT OK
#4S LZE
JMP 4F+1
COM
STC 4T
JMP 3A
JMP p+2
JMP 4D
JMP 3L
[FIND REQUEST IN CONTROL BLOCK
#4L CLR
SET i 5
6D-2
ADD 1P
STC 4T
LDA 5
STC 3A+1
LDA i 5
COM
STC p+4
CLR
ADD 4M
LAM i
NO MATTER
LZE
JMP 4L+3
#4G LDA i
5000+7A-6D-1
ADD 5
STC 3F
JMP 3F-3
SET i 2
6777
SET i 4
7377
JMP 4F+3
[META PARAMETER DECODE
[LN-NAME-UNIT
#2D CLR
SET i 12
6E
STA 12
STA i 12
COM
STA i 12
STA i 12
STA i 12
STA i 12
STA i 12
SET 1
0
[LINE NUMBER
SET i 12
6E-1
SET i 17
-2
SET 14
6
#2F JMP 4U
STA i 12
LDH 6
SHD i
1200
JMP 1
SAE i
63   [COMMA
JMP p+4
XSK i 17
JMP 2F-2
JMP p+5
CLR
STA 12
SET 6
14
[NAME
#2N SET i 12
6E+4001
SET i 16
-11
XSK i 1
LDH i 6
SHD i
1400
JMP p-3
SHD i
1200
JMP 1N-2
SHD i
6300
JMP 2U
STH i 12
LDH i 6
XSK i 16
JMP p-11
JMP 1N-2 [ERROR
[UNIT
#2U JMP 4U
SET 0
1
ROL 3
STA
6E+6
BCL i
50
AZE i
JMP 0
JMP 1N-2 [ERROR
[TAPE FIX
SET i 17
JMP 1C-4
#2T SET 1
0
JMP 3N+4
JMP 1K
JMP 1T+4
JMP p+2
JMP 2X+4
LDA i
7776
STC 4T
JMP 4H
JMP 3L
JMP 2X+7
[SM,CM,CB SR
#2Y LDA
0
STC p+6
JMP 2D
JMP 1N-2 [ERROR
JMP 2X-2
RCG i 7E
1|7D+20
RETURN
[CV,SM SR
#4Z LDA i
1
SAE
3A+3
JMP 0
JMP 1N-2 [ERROR
[LIST,PRINT MS,QUICK PRINT SR
#2W SET 11
0
JMP 2D
JMP p+3
JMP 2X-2
JMP 11
JMP 4Z
XSK i 11
JMP 11
[DISPLAY INDEX, COPY FILE, PRINT INDEX SR
#2Z SET 11
0
JMP 2D
JMP p+2
JMP 1N-2 [ERROR
LDA
6E
JMP 2U+3
JMP 2X-2
JMP 11
[EXIT, LOAD BINARY SR
#2E SET 11
0
LDA i
LDA i
STC 20
STC 2X+5
SET i 17
JMP 20
JMP 2T
JMP 11
[COPY
#2P JMP 2T-2
RDC i 7E
7D+36
JMP 17
[CONVERT
#2C JMP 4Z
JMP 2T-2
RCG i 7E
2|7D+30
JMP 1002
[SAVE MANUSCRIPT
#2S JMP 4Z
JMP 2D
JMP 1N-2 [ERROR
JMP 2T-2
RDC i 7E
7D+20
ADD 3V-12 [LAST BN
JMP 23
[SAVE BINARY
#2B JMP 2Y
JMP 22
[COPY MANUSCRIPT
#2L JMP 2Y
JMP 20
[COPY BINARY
JMP 2Y
JMP 21
[COPY FILE
JMP 2Z
RDC i 7E
7D+14
JMP 17
[LIST
#2A JMP 2W
JMP 2I-3
JMP 2T-2
RCG i 7E
2|7D+30
RDC i 7E
1|7D+33
JMP 1000
RCG i 7E [FILE MS
1|7D+20
JMP 24
[PRINT MANUSCRIPT
#2I JMP 2W
JMP p+5
JMP 2T-2
RDC i 7E
2|7D+22
JMP 1000
RCG i 7E
2|7D+20 [FILE MS
JMP 25
[DISPLAY INDEX
#2G JMP 2Z
RDC i 7E
7D+25
JMP 17
[PRINT INDEX
#2Q JMP 2Z
RDC i 7E
7D+25
JMP 20
[EXIT
#2R JMP 2E
MTB 7E
0
HLT
MTB i 7E
0
HLT
JMP 20
[FREE
#2J LDH i 6 [2ND CHAR
STC p+5
JMP 2T-2
RDC 7E
7D+17
LDA i
2ND CHARACTER
JMP 20
[DISPLAY SYMBOL TABLE
#2V JMP 2X-2
RCG i 7E
1|7D+10
JMP 14
[1ST CASE
#1Y JMP 5A
KBD
SET i 17
1H+4000
SHD i 17
JMP 1C [DELETE
SHD i 17
JMP 4B [W
SHD i 17
JMP 4F [1
SHD i 17
JMP 4Q [Q
AZE i
JMP 4P [0
JMP 2H-1
JMP 1C [ILLEGAL
[LATER CHARACTERS
#1F JMP 5A
KBD
SET i 17
1H-4000
SHD i 17
JMP 1Z [CASE
SHD i 17
JMP 1E [EOL
SHD i 17
JMP 1K-2 [DELETE
JMP 1R
[LATER CASE
#1Z JMP 5A
KBD
SHD i
1300
JMP 1K-2
JMP 2H-1
JMP 1F [ILLEGAL
[CHECK CASE
ADA i
#2H -32
APO i
JMP 0 [ILLEGAL
ADD 3H+11 [76
JMP 1R
[CHARACTER TABLE
#1H 2312
1352
 144
$1777
STC 0
[GRID PATTERNS
$2001
#6A 4136
3641
2101
0177
4523
2151
4122
2651
2414
0477
#6C 5172
0651
1506
4225
4443
6050
5126
2651
5122 [9
3651
4020
2055
4020 [DEL
2055
0000
0000
0101
0126
3700
3424
0404
0404
0404
0437
0000
0077
3614
1436
4020 [CASE
2055
4477
7744
#6B 5177
2651
4136
2241
4177
3641
4577
4145
4477
4044
#6G 4136
2645
1077
7710
7741
0041
4142
4076
1077
4324
#6L 0177
0301
3077
7730
3077
7706
4177
7741
4477
3044
#6Q 4276
0376
4477
3146
5121
4651
4040
4077
0177
7701
#6V 0176
7402
0677
7701
1463
6314
0770
7007
4543 [Z
6151
0404 [META
0404
2504
0416
4020 [?
2055 [CASE,SPACE
#6F 1212
1212
0107
0107
0500
0006
0001
0000
4577
7745
4177
0000
0101 [_
0101 [CASE,CASE
0070 ["
0070 [CASE,A
0700 [;
0700 [CASE,B
2410 [<
0042 [CASE,C
4200 [>
1024 [CASE,D
0000 []
7741 [CASE,E
2050 [*
0050 [CASE,F
2200 [:
0000 [CASE,G
[META COMMANDS
#6Z 2440 [AM
JMP 2M
4640 [SM
JMP 2S
2651 [CV
JMP 2C
2643 [CP
JMP 2P
3053 [EX
JMP 2R
3734 [LI
JMP 2A
4625 [SB
JMP 2B
2753 [DX
JMP 2G
2746 [DS
JMP 2V
2640 [CM
JMP 2L
2625 [CB
JMP 2L+2
2631 [CF
JMP 2L+4
3742 [LO
JMP 2K
4340 [PM
JMP 2I
4353  [PX
#6Y JMP 2Q
[CONTROL TABLE
0 [MUST HAVE 2 ZEROS HERE
0
#6D
[META PARAMETERS
$2371
#6E 0
0
0
0
0
0
0
7A=350 [WA
7B=0 [WA UNIT
7C=430 [FILE
7D=300 [LAP5
7E=0 [LAP5 UNIT
7G=426
[MSJAN20
[END MS6A