File NEWACQ

Directory of image this file is from
This file as a plain text file

*20
	SEGMNT 0
	BEAC=2000
	LIM=10
	AVGPTR=12
	*20
TIME,	-2
SBINS,	-400
SAMN,	-11
N,	11
TPEBLK,	0
INTAC,	0
	*1
	PMODE
	JMP INT+2
	LMODE
	*41
	JMP INT
	*170
INT,	NOP
	PDP
	3026		/DCA INTAC
	6135
	6141
	APO I
	JMP SYNC
	CLR
	IOB
	6234
	STA I
SAVDF,	0
	SFA		/GET SPEC FUNCTIONS
	BSE I
	0100
	ESF		/FAST SAMPLE
	SAM 10
	CLR
	SAM 11
	LDF 6
	SXL 13
	LDF 4
	XSK I 4
	XSK I 5
	XSK I 6
	XSK I 7
	NOP
	STA 4
	STA I
NM1,	0
	SXL I 13
	JMP .+7
	LDA I
	5000
	STA
	BEAC
	STA 
	BEAC+1
	CLR
	SAM 12
	STA I
EP1,	0
	CLR
	SAM 10
	STA I
EP2,	0
	LDF 7
	CLR
	LDA 
	EP1
	SXL I 13
FCTR,	SCR 3		/SKIP IF PROBE
	STA I 
SAVEY,	0
	QAC
PRB1,   LAM 4
	LDF 5
	LDA
	SAVEY
PRB2,	LAM 4
/EP2
	LDF 7
	CLR
	LDA
	EP2
	SXL I 13
	SCR 3
	STA
	SAVEY
	QAC
PRB3,	LAM 5
	LDA
	SAVEY
	LDF 5
PRB4,	LAM 5
	XSK I 15
	JMP .+2
	JMP ENDBLK
	JMP CSTST
/
ENDBLK,	NOP
MORE,	LDA I
	0060
	ESF
	SNS I 0
	JMP WRTBLK+1	/NO WRITE
	LDA I
	1
	ADM
	AVGBLK
	LDA I
	1
	ADM 
	WRTBLK
	STD
	JMP .-1
	LDF 6		//
/
	SXL 13
	LDF 4
	WRI U
WRTBLK,	0
	AVGPTR=12
	XSK I AVGPTR
	JMP CLKSET
	LDF 1
	LDA I
	1
	STA
	AVGFLG!2000	/WRITE AVG
	JMP CLKSET+15
/
CSTST,	IOB
	6001
	SXL 0
	SKP
	JMP .-2
	LDF 4
	LDA I
	10
	ADM 7
	LDA I
	10
	LDF 6
	ADM 7
	JMP .		/
	JMP .
	HLT
/
SYNC,	ROL 10
	APO I		/EVENT 2
	JMP TRY3
	ROL 2
	APO I		/2 AND 3
	SKP		/NO
	JMP BOTH	/YES
	LDF 6
	SXL 13
	LDF 4
	LDA I
DELTA,	10
	ADM 5		/EVENT 2
	JMP SETOUT
TRY3,	ROL 2
	APO I
	JMP BINS-3
	LDF 6
	SXL 13
	LDF 4
	LDA
	DELTA
	ADM 6
	JMP SETOUT
BOTH,	LDF 6
	SXL 13
	LDF 4
	LDA
	DELTA
	ADM 5
	LDA
	DELTA
	ADM 6
	JMP SETOUT
/
	SET I 17
	3777
	SET 15
BINS,	SBINS
	LDA I
	1
	ADM 
	WRTBLK
	LDA I
	1
	ADM
	TRIAL
	LDF 1
	CLR
	STA
	TYPFLG!2000
	SET I 4
	3777
	SET I 5
	2377
	SET I 6
	2777
	SET I 7
	3377
	SXL 13
	JMP PROBE
	LDA I
	LAM 4
	STA
	PRB1
	STA
	PRB2
	LDA I
	LAM 5
	STA
	PRB3
	STA
	PRB4
CC,	NOP
	LDA I
	4100		/1KC AND PRESET
	IOB
	6132		/CLLR
	IOB
	6135		/CLSA POSSIBLE FLAG
SETOUT,	LDA I
	317		/ENABLE CLOCK
	IOB
	6134		/SET CLOCK INT
	JMP CSTST		/WAIT FOR CLOCK
/
PROBE,	LDA I
	LAM 6
	STA
	PRB1
	STA
	PRB2
	LDA I
	LAM 7
	STA
	PRB3
	STA
	PRB4
	JMP CC
/
TAPEQ,	324
	301
	320
	305
	240
	302
	314
	313
	240
/
ASTART,	IOB
        6046          
	SET I 3
	TAPEQ-1
	SET I 2
	-11
	LDA I 3
	IOB
	6041
	JMP .-2
	IOB
	6046
	XSK I 2
	JMP .-7
	SET I 2
	-3
	CLR
	STC TPESET
	IOB
	6031
	JMP .-2
	IOB
	6036		/KRB
	IOB
	6046
	BCL I
	7770
	ADA I
TPESET,	0
	ROL 3
	STC TPESET
	XSK I 2
	JMP .-16
	JMP CRRET
	LDA
	TPESET
	ROR 3
	STC TPESET
        LDA I  
        4000
	BSE 
	TPESET
	STA 
	WRTBLK		/INITIALIZE WRTBLK
	STA
	AVGBLK
	CLR
	SET I 2
	-3
	STC NSET
	IOB 
	TSF
	JMP .-2
	LDA I
	316
	IOB
	6046
	IOB
	6041
	JMP .-2
	LDA I
	240
	IOB
	6046
	IOB
	6031
	JMP .-2
	IOB
	6036
	IOB
	6041
	JMP .-2
	IOB
	6046
	BCL I
	7770
	ADA I
NSET,	0
	ROL 3
	STC NSET
	XSK I 2
	JMP .-21	/GET N
	JMP CRRET
	LDA
	NSET
	ROR 3
	STA
	N
	COM
	STC SAMN
	CLR
	STA I
TRIAL,	0
	SET I 2
	-30
	SET I 3
	TYPEIT-1
	IOB
	6041
	JMP .-2
	LDA I 3
	IOB
	6046
	XSK I 2
	JMP .-7
	CLR
	ATR		/CLEAR RELAYS
	LDA I
	60
	ESF
	CLR
	IOB
	6132
AVGSET,	SET I AVGPTR
	3777
	CLR
	LDF 4
	STA I AVGPTR
	LDF 5
	STA AVGPTR
	LDF 6
	STA AVGPTR
	LDF 7
	STA AVGPTR
	XSK AVGPTR
	JMP AVGSET+2
	LDF 1
	LDA I
	1
	STA
	TYPFLG!2000	/DONT TYPE ZEROS
	LDA I
	-1
	STA
	AVGFLG!2000	/AVG WRITE OUT
	LDA I
	215
	IOB
	6046		/TLS
	IOB
	6041
	JMP .-2
	LDA I
	212
	IOB
	6046
	SET AVGPTR
	SAMN		/N FOR AVERAGE
	RTA
	BCO I
	0001
	ATR		/FLIP K6
CLKSET,	LDA
	TIME
	IOB
	6133		/CLAB, PRESET NUMBER
	CLR
	IOB
	6132      /CLLR TO STOP CLOCK
	LDA I
	60
	IOB
	6134		/CLEN 
	IOB
	6135		/CLSA TO CLEAR CLOCK
	IOB
	6001
	LIF 1
	JMP DISPLA	/WAIT FOR SYNC ---
/
	TLS=6046
	TSF=6041
/
CRRET,	LDA
	0    
        STC CRRETT
	IOB
	TSF
	JMP .-2
	LDA I
	215
	IOB
	TLS
	IOB
	TSF
	JMP .-2
	LDA I
	212
	IOB
	TLS
	LDA I
CRRETT,	0
	STC 0
	JMP 0
/
TYPEIT,	322
	305
	323
	324
	301
	322
	324
	240
	302
	331
	240
	314
	323
	240
	324
	317
	240
	260
	265
	263
	263
	215
	212
/CUT IN HERE FOR TTY SERVICE BEFORE IOB AND 6001
/
/
AVG,	STD
	JMP .-1
	LDA I 
	60
	ESF
	SET I 17
	3777
	CLR
	SET 14
	SBINS
	SNS I 0
	JMP RESET	/SUPPRESS TAPE
	LDF 6
	JMP WRTSET
	LDF 5
	JMP WRTSET
	LDF 4
	JMP WRTSET
	JMP RESET
/
WRTSET,	LDA
	0
	STC WRET
	SET I 17
	4000
	JMP SET1
	JMP WRITE
	SET I 17
	5000
	JMP SET1
	JMP WRITE
	SET I 17
	6000
	JMP SET1
	JMP WRITE
	SET I 17
	7000
	JMP SET1
	JMP WRITE
	LDA I
WRET,	0
	STC 0
	JMP 0
/
SET1,	LDA
	0
	STC RET4
	LDA
	AVGBLK
	BCL I
	7000
	BSE
	17
	STC AVGBLK
	LDA I
RET4,	0
	STC 0
	JMP 0
/
WRITE,	LDA 
	0
	STC RET
	LDA I
	1
	ADM
	AVGBLK
	LDA I
	1
	ADM
	WRTBLK
	STD
	JMP .-1
	WRI U
AVGBLK,	0
	LDA I
RET,	0
	STC 0
	JMP 0
/
RESET,	SET I 17
	3777
	SET 15
	SAMN
	LDA I
	60
	ESF
	JMP AVGSET
/
/
/
/DISPLAY PROGRAM FOR DATA COLLECTION
/
	SEGMNT 1
	*20
DISPLA,	CLR
	IOB
	6046		/TLS
	JMP .+1		/ENABLE INTERUPT
	SKP
DBINS,	-400
	LDF 0
	SET I 17
	WRTABL-1
	SET I 16
	-3		/DISPLAY TRIAL NUMBER
	LDA
	TRIAL!2000
	ROL 3
	STC TEMWRT
UNPACK,	LDA I
TEMWRT,	0
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17	/GET HALF CHAR
	LDA I 3		/GET OTHER HALF
	STA I 17
	XSK I 16
	JMP UNPACK
DISGO,	SET I 17
	WRTABL-1
	SET I 1
	10
	SET I 16
	-6
	SET 3
	DBINS
	LDA I 
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS TRIAL NUMBER
	LDF 0
	SET I 17
	BLKTBL-1
	SET I 16
	-3		/DIS BLOCK NUMBER
	LDA
	AVGBLK!2000
	ROL 3
	STC TEMWRT
BKPACK,	LDA 
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA 
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP BKPACK
DISBK,	SET I 17
	BLKTBL-1
	SET I 1
	600
	SET I 16
	-6
	SET 3
	DBINS
	LDA I
	300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS BLOCK NUMB
	CLR
	RSW
	BCL I
	7770
	BSE I 
	0640
	STA
	IELD
IELD,	0	/SET DF SELECTED BY RITE SWTCHS
	SNS I 1		/SMALLEST
	JMP .+5
	SET I 2
K3777,	3777
	SAM 1
	JMP DISLOP
	SET I 2
KBMP2,	2377
	SNS I 2
	JMP .+3
	SAM 2
	JMP DISLOP
	SET I 2
	2777
	SNS I 3
	JMP .+3
	SAM 3
	JMP DISLOP
	SET I 2
	3377
	SNS I 4
	JMP .+3
	SAM 4
	JMP DISLOP
	SNS I 5
	JMP DISGO	/SUPPRESS INTEGRAL
	JMP CALC
	IOB
	6031
	JMP DISINT
IO,	IOB
	6036		/KRB
	STA I
ELECT,	0
	ADA I
	-260
	APO
	JMP ERR
	LDA
	ELECT
	ADA I
LIM5,	-264
	APO I
	JMP ERR
	LDA
	ELECT
	BCL I
	7770
	STC ELECT
DISINT,	LDA I
	INTBL-1
	ADA
	ELECT		/FORM SET
	STC 11
	LDA 11
	STC INTSTR
	STC INT1
	STC INT2
	LSW
	BCL I
	7760
	BSE I
	SCR 0
	STC SHIFT
	LDA
	ELECT
	BSE I
	SAM 0
	STC SMPIT
	SET I 12
INTSTR,	0
	SET I 13
	-122
	JMP INTLUP-3
	LDA I
	10
	STC HORIZ
	JMP DISIN
	SET I 13
	-122
	CLR 
	STC INT1
	STC INT2
	JMP INTLUP-3
	LDA I
	300
	STC HORIZ
	JMP DISIN
	SET I 13
	-131
	CLR
	STC INT1
	STC INT2
	JMP INTLUP-3
	LDA I
	600
	STC HORIZ
	LDA I
	-300
	STC VERT
	JMP DISIN
/SCALE FACTOR
	SET I 17
	CSTBL-1
	SET I 16
	-3
	LDA
	SHIFT
	BCL I
	7760
	ROL 3
	STC TEMWRT
SCPACK,	LDA
	TEMWRT
	ROL 3
	STA
	TEMWRT
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP SCPACK
	SET I 17
	CSTBL-1
	SET I 1
	300
	SET I 16
	-6
	LDA I
	-150
	DSC I 17
	XSK I 16
	JMP .-4
	JMP DISGO
/
/
/
	LDA
	0
	STC JMPLUP
INTLUP, LDA I 12
	APO
	COM		/ABS VALUE
SHIFT,	0
	STA I
ACSAVE,	0
	QAC
	LAM I
INT1,   0
	LDA
	ACSAVE
	LAM I
INT2,   0
SMPIT,	0
	ADA 
	INT2
	DIS 12
INTOUT, XSK I 13
	JMP INTLUP
	LDA I
JMPLUP,	0
	STC 0
	JMP 0
/
INTBL,	2002
	2402
	3002
	3402
/
ERR,    JMP IO
	PDP
	PMODE
	TSF
	JMP .-1
	CLA CLL
	TAD K277
	TLS		/TYPE ?
	TSF
	JMP .-1
	CLA CLL
	TAD K215
	TLS
	TSF
	JMP .-1
	CLA CLL
	TAD K212	/CRLF
	TLS
	KSF
	JMP .-1
	LINC
	LMODE
	JMP IO
	PMODE
K277,	277		/?
K215,	215
K212,	212
	LMODE
/
/
DISIN,	LDA
	0
	STC RET17
	SET I 17
	INTABL-1
	SET I 16
	-4
	LDA
	INT2
	STC INTWRD
INPACK,	LDA I
INTWRD,	0
	ROL 3
	STA
	INTWRD
	BCL I
	7770
	ROL 1
	ADA I
	PATERN
	STA
	3
	LDA 3
	STA I 17
	LDA I 3
	STA I 17
	XSK I 16
	JMP INPACK	/SET UP INTEGRAL FOR PRECS
	SET I 17
	INTABL-1
	SET I 1
HORIZ,	0
	SET I 16
	-10
	LDA I
VERT,	-300
	DSC I 17
	XSK I 16
	JMP .-4		/DIS PRECS INT
/
	LDA I
RET17,	0
	STC 0
	JMP 0
/
CSTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
INTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/DISPLAY SUBROUTINE
DISLOP,	STA I
DTEM,	0
	LDA
	0
	STC DRET
	SET 3
	DBINS
	XSK I 2
	LDA
	DTEM
	ADA 2
	DIS 2
	XSK I 3
	JMP .-6
	LDA I
DRET,	0
	STC 0
	JMP 0
/
/
PATERN,	4136
	3641
	2101
	0177
	4523
	2151
	4122
	2651
	2414
	0477
	5172
	0651
	1506
	4225
	4443
	6050
	5126
	2651
	5120
WRTABL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	00
	0
	0
	0
	0
	0
	0
	0
	0
BLKTBL,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
/TTY OUTPUT
CALC,	 CLR
	SAM 7
	STA 
	PTRRES
	COM
	STC LIMIT
	SET I 3
	-400
	SET I 4
	3777
	CLR
	SAM 1
	ADA I
PTRRES,	0
	DIS I 4
	XSK I 3
	JMP .-6
	LDA I
	300
	STA
	HORIZ
	STC VERT
	LDA 
	PTRRES
	STC INT2
	JMP DISIN	/SHOW LIMIT OF RESPONSE
	LDA I
	-300
	STC VERT
         LDA I
TYPFLG, 1
	SAE I
	0
	JMP IO-3
	CLR
	LDA I
	1
	STC TYPFLG	/SHOW TYPED OUT
	LDF 0
	LDA
	TRIAL!2000
	JMP BINDEC
	JMP BLANK
	LDF 6
	SXL 13
	LDF 4
	CLR
	JMP PTRTST+7
	SET I 13
	-400
	SET I 14
	3377		/GET CS/US POINTERS
PTRTST,	LDA I 14
	ADA I
	-6
	APO I
	JMP PTRGOT
	XSK I 13
	JMP PTRTST
	LDA
	LIMIT
	COM
	JMP BINDEC
	CLR
	SET I 13
	-400
	SET I 14
	3777		/NIC MEM
NMTST,	LDA I 14
	ADA I
LIMIT,	0
	APO I
	JMP NMCR
	XSK I 13
	JMP NMTST
	JMP RR-2
NMCR,	JMP BLANK
        LDA
	13
	ADA I
	400
	STA I
TIMER,	0
	ADA
	TIMER
	ADA
	TIMER		/THREE TIMES
	JMP BINDEC
	SXL 13
	JMP PROB
RR,     JMP CRLF
	LDA I
AVGFLG,	0
	APO
	JMP IO-3
	JMP CRLF
	LIF 0
	JMP AVG
/
PTRGOT,	LDA
	13
	ADA I
	400
	STA I
CNTR1,	0
	ADA
	CNTR1
	ADA
	CNTR1
	JMP BINDEC
	JMP BLANK
	LDA I
	30
	ADM
	13
	LDA I
	30
	ADM
	14
	JMP PTRTST
/
PROB,	LDA I
	252
	JMP TYPCHR
	JMP RR
/
CRLF,	LDA
	0
	STC RET9
	LDA I
	215
	JMP TYPCHR
	LDA I
	212
	JMP TYPCHR
	LDA I
RET9,	0
	STC 0
	JMP 0
/
TYPCHR,	STC CHAR
	LDA
	0
	STC RET8
	IOB
	6041
	JMP .-2
	LDA I
CHAR,	0
	IOB
	6046
	LDA I
RET8,	0
	STC 0
	JMP 0
/
PRINT,	STC WORD
	LDA
	0
	STC RET6
	LDA I
WORD,	0
	ROL 3
	STA
	WORD
	BCL I
	7770
	ADA I
	260
	JMP TYPCHR
	XSK I 3
	JMP WORD-1
	LDA I
RET6,	0
	STC 0
	JMP 0
/
BLANK,	LDA
	0
	STC RET7
	LDA I
	240
	JMP TYPCHR
	LDA I
	240
	JMP TYPCHR
	LDA I
	240
	JMP TYPCHR
	LDA I
RET7,	0
	STC 0
	JMP 0
/
BINDEC,	STC VAR
	LDA
	0
	STC RETBIN
	SET I 17	/ONES
	-12
	SET I 16
	-12		/TENS
	SET I 15
	-12		/HUNDREDS
	SET I 14
	-12		/THOUSANDS
	LDA I
VAR,	0
	APO I
	JMP K1024
	ROL 1
	APO
	JMP K3072
	LDA
	VAR
	BCL I
	4000
	STC VAR
	LDA I
	11
	ADM 
	17		/ADD 8
	LDA I
	4
	ADM
	16		/ADD 40
	LDA I
	2
	ADM
	14		/ADD 2000
	JMP CONV-6
/
K3072,	LDA I
	2
	ADM
	17
	LDA I
	7
	ADM
	16
	LDA I
	3
	ADM
	14
	LDA
	VAR
	BCL I
	4000
	STC VAR
	JMP CONV-6
/
K1024,	ROL 1
	APO I
	JMP CONV-6
	LDA I
	4
	ADM
	17
	LDA I
	2
	ADM
	16
	LDA I
	1
	ADM
	14
	JMP CONV-6
/
	LDA
	VAR
	ADA I
	1
	COM
	STC 1
CONV,	XSK I 1
	SKP
	JMP CNVCMP
	XSK I 17
	JMP CONV
	SET I 17	/ONE OVERFLOW
	-12
	XSK I 16
	JMP CONV
	SET I 16	/TEN OVERFLOW
	-12
	XSK I 15
	JMP CONV
	SET I 15
	-12		/HUND OVERFLOW
	XSK I 14
	JMP CONV
	JMP CONV
/
CNVCMP,	LDA
	14
	ADA I
MINUS1,	272
	JMP TYPCHR
	LDA
	15
	ADA
	MINUS1
	JMP TYPCHR
	LDA
	16
	ADA 
	MINUS1
	JMP TYPCHR
	LDA
	17
	ADA
	MINUS1
	JMP TYPCHR
	LDA I
RETBIN,	0
	STC 0
	JMP 0
/
/SYNC SIGNAL (PRECS PULSE) GOES INTO INPUT 1
/ELECTRODE ONE GOES TO COMPARATOR 0 AND 1
/ELECTRODE TWO GOES TO COMPARATOR 2 AND 3
/ELECTRODE THREE GOES TO COMPARATOR 4 AND 5
/ELECTRODE FOUR GOES TO COMPARATOR 6 AND 7
/EMG GOES TO COMPARATOR 10


Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search