Directory of image this file is from
This file as a plain text file

*20
/PATTERN WORDS FOR CHAR DISPL.
	PMODE
	*1200
ZSTART,	4522            /AT SIGN
       	1645
   	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	4177		/[
	0000
	2040		/\
	0410
	0		/]
	7741
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6006		/"
	60
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0523
	5000		/APOSTROPHY
	60
	4136		/(
	0
	0		/)
	3641
	2050		/*
	50
	404		/+
	437
	605		/,
	0
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	2601		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?
ZZEND,	2055
/END OF PATRNS TABLE
	LMODE
	SEGMNT 0
	*40
	0000
	IOB
	PMODE
	RMF
	LMODE
	JMP WAIT1
START,	LDA I
	2000
	STC BLK
	LDA I
	LDF 3
	STC DF
	SFA
	CLR
	BSE I
	100
	ESF
	CLR
	LSW
	BCL I
	7700
	ADA I
	1
	COM
	STC 7
	SET I 6
	7777
	SET I 17
	3777
	LDF 1
	STA I 17
	XSK 17
	JMP .-2
	LDF 2
	STA I 17
	XSK 17
	JMP .-2
	LDF 3
	STA I 17
	XSK 17
	JMP .-2
	LDF 4
	STA I 17
	XSK 17
	JMP .-2
	LDF 5
	STA I 17
	XSK 17
	JMP .-2
	LDF 6
	STA I 17
	XSK 17
	JMP .-2
	LDF 7
	STA I 17
	XSK 17
	JMP .-2
	LDF 1
CLK,	SET I 13
	-377
	PDP
	PMODE
	CLA
	CLEN
	CLAB
	CLLR
	TAD K100
	CLLR
	CLSA
	CLA
	TAD NT
	CLAB
	CLA
	TAD K200
	CLEN
	CLA
	TAD K203
	CLEN
	LINC
	LMODE
	JMP LDISP
K100,	100
K200,	200
K203,	203
NT,	-4
WAIT1,	JMP CHBL
	SAM 10
	RSW
	ROL 3
	BCL I
	7770
	STA
	RTSW
	AZE I
	JMP WAIT2
	SAE I
	1
	SKP
	JMP .+6
	SAE I
	2
	SKP
	JMP .+5
	JMP .+7
	LDA I
	-4
	JMP .+6
	LDA I
	-15
	JMP .+3
	LDA I
	-36
	STC .+2
WAIT3,	SET I 11
	0
	SAM 14
	STA I 17
	SAM 10
	STA I 16
	XSK I 11
	JMP .-1
	XSK I 13
	JMP WAIT3
	LDA
	BLK
	STA
	IND2
	ADA I
	400
	STC IND3
	LDA I
RTSW,	0
	STA
IND2,	0
	STA
IND3,	0
	JMP CLK
WAIT2,	SAM 14
	STA I 17
	SAM 10
	STA I 16
	XSK I 13
	JMP .-5
	LDA
	BLK
	STA
	IND
	ADA I
	400
	STC IND1
	STA
IND,	0
	STA
IND1,	0
	JMP CLK
	LMODE
LDISP,	SAM 0
	SAM 0
	STC Y
	SAM 4
	SAM 4
	STC Y1
	SAM 1
	SAM 1
	ADA I
	1000
	BCL I
	6000
	ROL 1
	STC CUR1
	SAM 2
	SAM 2
	ADA I
	1000
	BCL I
	6000
	ROL 1
	BSE I
	1
	STC CUR2
	SET I 15
	1001
	LDA
	BLK
	STC 10
	XSK I 10
	JMP DSCA
MORE,	LDA 10
	ADA I
Y,	0
	DIS I 15
	LDA I
CUR1,	0
	SAE
	15
	SKP
	JMP CUR
	LDA 10
	ADA I 10
	SCR 1
	ADA
	Y
	DIS I 15
	LDA I
CUR2,	0
	SAE
	15
	SKP
	JMP CUR
	SNS I 4
	JMP SWP2
SWTS,	SNS I 0
	JMP SAMP
	IOB
	PMODE
	IOF
	LMODE
	SNS I 5
	JMP START
	SNS 1
	JMP NCHBL
	XSK I 6
	JMP NCHBL
	XSK I 7
	SKP
	JMP CHBL
NCHBL,	SNS I 2
	JMP STR
	SNS I 3
	JMP RED
	XSK 15
	JMP MORE
	JMP LDISP
SAMP,	IOB
	PMODE
	ION
	LMODE
	XSK 15
	JMP MORE
	JMP LDISP
SWP2,	LDA
	15
	ADA I
	-2
	STC 15
	LDA
	10
	ADA I
	400
	BSE I
	2000
	STC D
	LDA
D,	0
	ADA I
Y1,	0
	DIS I 15
	LDA
	D
	STA
	E
	ADA I
	1
	STC F
	LDA 
E,	0
	ADA
F,	0
	SCR 1
	ADA
	Y1
	DIS I 15
	JMP SWTS
CHBL,	LDA
	0
	STC EXIT
	SNS 4
	JMP SING
	LDA
	BLK
	ADA I
	-2777
	APO I
	JMP .+5
	LDA I
	3000
	STC BLK
	JMP DF
	LDA I
	2000
	STC BLK
	LDA
	DF
	SAE I
	LDF 7
	JMP IDF
	LDA I
	LDF 0
	STC DF
IDF,	LDA I
	1
	ADM
	DF
DF,	0000
	SET I 6
	7777
	LSW
	BCL I
	7700
	ADA I
	1
	COM
	STC 7
	LDA I
BLK,	0000
	STA
	17
	ADA I
	400
	STC 16
	SNS I 4
	JMP EXIT
	LDA I
	1400
	STC 16
EXIT,	0000
SING,	LDA
	BLK
	SAE I
	3400
	JMP IBLK1
	LDA I
	1400
	STC BLK
	LDA
	DF
	SAE I
	LDF 7
	JMP IDF1
	LDA I
	LDF 0
	STC DF
IDF1,	LDA I
	1
	ADM
	DF
IBLK1,	LDA I
	400
	ADM
	BLK
	JMP DF
STR,	LDA
	BLK
	SNS 4
	JMP .+3
	BCL I
	400
	STA
	BLK
	ROL 1
	BCL I
	777
	STC .+5
	RSW
	BCL I
	7000
	ADA I
	0000
	STC ON
	WRI 10
ON,	0
	SNS 4
	JMP LDISP
	LDA
	ON
	ADA I
	1001
	STC .+2
	WRI 10
	0
	JMP LDISP
RED,	LDA
	BLK
	SNS 4
	JMP .+3
	BCL I
        0400
	STA
	BLK
	ROL 1
	BCL I
	777
	STC .+5
	RSW
	BCL I
	7000
	ADA I
	0000
	STC OFF
	RDE 10
OFF,	0
	SNS 4
	JMP LDISP
	LDA
	OFF
	ADA I
	1001
	STC .+2
	RDE 10
	0
	JMP LDISP
CUR,	SET I 2
	-4
	CLR
	ADD 0
	STC CURR
	ADD 15
	STC .+2
	SRO I
	0
	JMP .+6
	SAM 5
	SAM 5
	SCR 1
	STC CURY
	JMP .+5
	SAM 6
	SAM 6
	SCR 1
	STC CURY
	LDA I
CURY,	0
	ADA I
	1
	DIS 15
	XSK I 2
	JMP .-4
CURR,	0
DSCA,	LDA 
	0
	STC DSCR
	LDA
	BLK
	STC .+2
	LDA
	0
	BCL I
	7770
	ADA I
	-3
	COM
	APO
	CLR
	BSE I
	SCR
	STC X
	LDA
	CUR1
	COM 
	ADA
	CUR2
	APO
	COM
X,	SCR 1
	STC UNPAC+1
	SET I 4
	TAB-1
	SET I 2
	-4
UNPAC,	LDA I
	0
	ROL 3
	STA
	UNPAC+1
	BCL I
	7770
	BSE I
	60
	STA I 4
	XSK I 2
	JMP UNPAC
	LDA
	TAB+3
	STC TAB+4
	LDA I
	56
	STC TAB+3
	SET I 2
	TAB-1
	SAM 3
	SAM 3
	ADA I
	600
	STC 1
	SET I 3
	-12
DSCB,	LDA I 2
	ROL 1
	ADA I
	ZSTART
	STC 4
	SAM 7
	SAM 7
	ADA I
	-300
	DSC 4
	DSC I 4
	LDA I
	4
	ADM
	1
	XSK I 3
	JMP DSCB
DSCR,	0
TAB,	0
	0
	0
	0
	0
	40
	15
	23
	5
	3
	0
	0
ATAB,	0
/PATTRN TABLE IS AT 1200-1400
/SCRATCH AREA 1400-1777
	SEGMNT 2
	*20
	LIF 0
	JMP START
	0000
/TITLE:  NFIZZ
/MARCH 15,1971
/FOR HANDLING GROSS ELECTRODE AND
/FIELD POTENTIALS.
/ANALOGUE CHANNELS 10 AND 14 USED
/CLOCK CHANNEL THREE IS TIME ZERO
/SNS 0-SAMPLE ON CHANNELS 10 AND 14
/      WITH TIME ZERO AT CL3
/SNS 1-ROTATE THROUGH STORED BLOCKS
/     28 IF SINGLE SWEEP,14 IF DUAL
/SNS 2-RECORD VIEWED BLOCK(S) ON UNIT
/     ONE.  RSW 3-11 SELECT BLOCK.
/SNS 3-TAKE BLOCK FROM UNIT 1 TO VIEW.
/     RSW SELECTS BLOCK(S).
/SNS 4-DUAL SWEEP FOR VIEWING,RECORDING,
/     AND RETRIEVING DOUBLE BLOCKS.
/SNS 5-CLEAR ALL STORAGE AREA.
/POT 0-VERT FOR SWEEP 1-CH 10 INPUT.
/POT 4-VERT FOR SWEEP 2-CH14 INPUT.
/POTS 1&2-HORIZONTALS FOR CURSORS.
/POTS 5&6-VERTICAL FOR CURSORS.
/POTS 3&7-VERT AND HORIZ FOR MSEC
/      READOUT.
/LSW 6-8 SELECT SPEED FOR SCANNING
/     BLOCKS.
/RSW 0,1,&2 SELECT MAGNIFICATION OF
/     SWEEP. ALL OFF=8MS SWEEP
/	       2 ON =16MS
/	       1 ON =32MS
/	       0 ON =64MS
/CURSOR READS OFF IN OCTAL MILLISECONDS
/NEVER HIT I/O PRESET START 20
/IF YOU MUST I/O PRESET, START LS 44