Directory of image this file is from
This file as a plain text file

[OCTDUMP
[
[  OCTAL OUTPUT ON TELETYPE OF VALUES STORED ON TAPE.   1 BLOCK PER PAGE.
[  FOR CLASSIC LINC, uLINC AND PDP-12
[
[USES BUFFERED TAPE ON uLINC, PDP-12
[
$1
JMP 20
[
$20
HLT
CLR
SNS i 4
JMP p+2
ADD 4Z  [14
STC 4H
LSW
STA
1H+1
STA
1F+12
BCL i
7000
BSE i
3000
STC 3A+1  [STARTING BLOCK
RSW
AZE
JMP p+2
ADD 1Z  [1
COM
STC 17  [-# OF BLKS
[WHICH VALUES TO PRINT
SNS 0
JMP p+3
BSEi
421
SNS 1
JMP p+3
BSEi
1042
SNS 2
JMP p+3
BSEi
2104
SNS 3
JMP p+3
BSEi
4210
STA
3R
STC 4K
SNS 5
COM
STC 4G+2
JMP 100
[
$100
HLT
LDAi
STA
SNSi 0 [WHICH PRINTER?
JMP p+3
LDAi
JMP 7S
STC 3C
SNS 1
JMP 1C
RSW [IF CONST USED
AZE i
JMP 1C
STC 9A  [CONST
LDA i
MUL
STC 4G-1
SNS 2
JMP 1C+3
LDA i
4000+9A
STC 4G
JMP p+7
#1C LDA i  [NO CONST
JMP 4G+1
STC 4G-1
LDA i
9A
STC 4G
LDA i
3333
STA
4T
STC 4U
JMP p+2  [WHAT COMPUTER  - FOR TTY2
JMP 1F  [PDP-12
0006    [DJR-12
JMP p+2
JMP p+2  [OTHER LINCS
JMP 0
CLR
MSC 4
APO
JMP 1H   [uLINC
LDA i    [CLASSIC LINC
NOP
STA
4L+10
STC 7R-1
JMP 1H
#1F LDA i    [HERE IF PDP-12
NOP
STC 7X
LDA i
OPR 14
STC 7X+1
LDA i
JMP 1A
STC 4L+10
LDA i  [EXT UNITS
XXX
ROL 2
BCL i
7774
0001  [AXO-12
LDA i
JMP 1J
STC 5A+1
ADD p-10  [uBIT
SCR 6
BCL i
7767
JMP 1I
[
#1H LDAi [UNIT FOR LINCS
X
SCR 6
BCL i
7707
#1I ADA i
RDC
STC 3A
SETi 7
-5
LDAi
14
JMP 7P
LDAi
12
JMP 7P
XSKi 7
JMP p-7
[
[PRINT BN
#3A RDC X
3|XXX
LDAi
14
JMP 7P
LDAi
12
JMP 7P
LDH
3A+1
BCLi
70
JMP 7P
LDH
4|3A+1
BCLi
7
ROR 3
JMP 7P
LDH
4|3A+1
BCLi
70
JMP 7P
LDHi
":;
JMP 7P
LDA i
#1Z 1
ADM
3A+1
[PRINT LOCS AT TOP OF COLUMNS
SETi 10
-1
LDAi
14
JMP 7P
XSKi 10
JMP p-4
SETi 12
4|3X-1
#3M SETi 13
-7
SROi
#3R XXX
JMP 3N
LDAi
4003
ADM
12
JMP 3P
#3N LDHi 12
JMP 7P
XSKi 13
JMP p-3
SETi 10
-1
LDAi
14
JMP 7P
XSKi 10
JMP p-4
#3P SROi
3567
JMP 3M
SETi 12
1377
SETi 13
1477
SETi 14
1577
SETi 15
1677
SET i 16
-100
[
#4A LDA i
12
JMP 7P
LDA  [LINE COUNTER
16
ADA i
100
AZE i
CLR
STA i
#4B XXX
SCR 3
BCL i
7770
AZE
JMP p+3
LDA i
14
JMP 7P
LDA
4B
BCL i
7770
JMP 7P
LDA i
LDA i 11
STC 4D
#4C SROi
#4K 7777
JMP 4E
LDAi
1
ADM
4D
JMP 4S
#4E LDAi [SPACE
14
JMP 7P
SRO i
#4T 3333
JMP 4E
LDA i
1
ADM
4D
#4D LDA i 12
MUL
#4G 9A
SRO i
0000
APO i
JMP p+6
COM
STC 4I
LDA i
17
JMP p+4
STC 4I
LDA i
#4Z 14
JMP 7P
LDA i
#4H 0  [14 IF NO LEADING ZEROS
STC 4J
LDA i
#4I XXX
ROL 3
STA
4I
BCL i
7770
AZE
JMP 4J+2
LDA i
#4J 14
JMP p+6
STC p+4
CLR
STC 4J
LDA i
XXX
JMP 7P
SRO i
#4U 3333
JMP 4I-1
LDA
4I
ROL 3
BCL i
7770
JMP 7P
#4S SROi
3567
JMP 4C
KST
JMP 4L
KBD
SHD i
"H;   [HALT,RTN 20
JMP 20
SHD i
1212
JMP 5A+1
SET i 17  [STOP AT END OF BLOCK
-1
#4L XSK i 16
JMP 4A
LDA i
12
JMP 7P
XSK i 17
JMP p+2
JMP p+3
MSC 3    [NO PAUSE uLINC
[IS NOP CLASS, JMP 1A PDP-12
JMP 3A
[
#5A HLT
NOP  [JMP 1J PDP-12
SET i 15   [RTN LAP6
RCG
SET i 16
7010
JMP 15
[
#9A 0  [CONST
[
[PRINT ROUTINE
#7P SET 6
0
ADAi
7Q
#3C STA [JMP 7S IF TELETYPE
3B
SAEi
7Q+12
JMP 3B-1
OPR 6 [TERMINATE LINE AND PRINT
JMP 6
LDA
#3B X
OPRi 13
JMP 6
[TTY2
[  TELETYPE PRINT OF THE CHARACTER WHOSE LINC CODE IS IN ACCUMULATOR AS 00XX
[SEE #7R-1, #7X AND #7X+1 COMMENTS
[
#7S STC p+2
LDA
XXX  [LOC OF ASKII CODE IN TABLE BEL2W
BSE i
3400
STC 7U+1
JMP 7U  [NOP FOR CLASSIC LINC
#7R ADD 7U+1
ROL 1
STA i
XXX  [WORKCODE
BCL i
7776
ATR
SET i 11  [DELAY LOOP
-430
XSK i 11
JMP p-1
LDA
p-11
SCR 1
SRO i
3777
JMP p-16
[CHECK FOR EOL
LDA
7S+2
SAE i
7Q+12
JMP 6
SRO i
5252
JMP p-3
LDA i
212  [LINE FEED
JMP 7S+3
[uLINC OR PDP 12
#7U LDA i
XXX  [TELETYPE CODE
#7X OPR 42  [NOP FOR PDP 12
JMP p-1  [OPR 14 FOR PDP 12
JMP 7U-13
[
[ASKII CODE TABLE
[  IN ORDER OF LINC CODE NUMBERING
#7Q 260  [0
261  [1
262  [2
263  [3
264  [4
265  [5
266  [6
267  [7
270  [8
271  [9
[LINC CODE 12
215  [EOL, I.E., CARRIAGE RETURN
377  [DEL,I.E., DOES NOTHING
240  [SPACE
246  [i
247  [p
255  [-
253  [+
334  [|
243  [#
215  [CASE,I.E., CARRIAGE RETURN
[LINC CODE 24
301  [A
302  [B
303  [C
304  [D
305  [E
306  [F
307  [G
310  [H
311  [I
312  [J
[LINC CODE 36
313  [K
314  [L
315  [M
316  [N
317  [O
320  [P
321  [Q
322  [R
323  [S
324  [T
[LINC CODE 50
325  [U
326  [V
327  [W
330  [X
331  [Y
332  [Z
251  [META, I.E., ARROW
257  [SLANTED SLASH  -  NOT AVAILABLE FROM KEYBOARD
277  [?
275  [=
[LINC CODE 62
245  [u
254  [,
256  [.
244  [$
333  [[
300  [_, I.E., CIRCUMFLEX
336  [", I.E., ARROW UP
273  [;, I.E., ARROW DOWN
274  [<
276  [>
[LINC CODE 74
335  []
252  [*
272  [:
207  [RINGS BELL ONLY
[
#1J CLR
0001  [AOX ON PDP-12
JMP 5A+2
[
[COLUMN HEADERS
#3X "  0     100    200    300   ;
[NO PAUSE PDP-12
[
#1A 0021   [XOA-12
BSE i
0010
0001   [AXO-12
JMP 3A
[
[
[
[END OCTDUMP
[
[JMF,HEB,JB
[NOV 23,1971