Directory of image this file is from
This file as a plain text file

[PONG 22 NOV 73
CLR
STC 5A
STC 5B
#1Z LDAi
0400
STC 2X
STC 2Y
STC 2V
ADD 1K
SROi
#1S 0000
COM
STC 2H
#1H JMP 1B [PADDLE POSITIONS
JMP 1E [PADDLE DISPLAY
JMP 1G [BALL DISPLAY
JMP 1F [NET DISPLAY
JMP 1A [TOP AND BOTTOM LIMITS
JMP 1C [END LIMITS
JMP 1H
[SCORE IMMINENT
#4F JMP 1B
JMP 1E
JMP 1G
JMP 1F
JMP 1A
JMP 1J [SCORE?
JMP 4F
[PADDLE POSITIONS
JMP 000
#1B LDA
0
STC 1B-1
SAM 1
ROL 1
MUL
2M+4000
STC 3L
SAM 7
ROL 1
MUL 
2M+4000
STC 3R
JMP 1B-1
[DISPLAY BALL
JMP 000
#1G LDA
0
STC 1G-1
LDAi
#2H 0002 [HORIZ.INCREMENT, 1 - 3
ADD 2X
BCLi
7000
STC 2X
ADD 2X
STC 1
LDAi
#2V 0003 [VERT.INCREMENT, -3 - +3
ADM
2Y
DIS 1
SROi
3737
JMP p-3
JMP 1G-1
[CHECK TOP AND BOTTOM LIMITS
JMP 000
#1A LDA
0
STC 1A-1
LDA
2Y
ADD 2T
SCR 2
AZEi
JMP p+7
LDA
2Y
ADD 2B
SCR 2
AZE
JMP 1A-1
LDA
2V
COM
STC 2V
JMP 1A-1
[CONSTANTS AND VARIABLES
#2X 0400 [BALL X
#2Y 0000 [BALL Y
#2T -340 [TOP LIMIT
#2B +340 [BOTTOM LIMIT
#2R -740 [RIGHT PADDLE X
#2L -40 [LEFT PADDLE X
#2M 3600 [MULTIP.FOR PADDLE Y ADJUST
#2P -20 [PADDLE DISPLAY START POINT
#3R 0000 [RIGHT PADDLE Y
#3L 000 [LEFT PADDLE Y
[NUMERICAL CONSTANTS
#1K 1
#2K 2
#3K 3
#4K 4
#5K 5
#6K 6
[CHECK END LIMITS
JMP 000
#1C LDA
0
STC 1C-1
ADD 2H
APOi
JMP p+10
LDA
2X
ADD 2L
SCR 2
AZEi
JMP 1L
JMP 1C-1
LDA
2X
ADD 2R
SCR 2
AZEi
JMP 1R
JMP 1C-1
[DISPLAY PADDLES
JMP 000
#1E LDA
0
STC 1E-1
SETi3
-40
ADD 2L
COM
STC 1
ADD 2P
ADD 3L
DIS 1
ADAi
1
XSKi3
JMP p-4
SETi3
-40
LDA
2R
COM
STC 1
ADD 2P
ADD 3R
DIS 1
ADAi
1
XSKi3
JMP p-4
JMP 1E-1
[DISPLAY NET
JMP 000
#1F LDA
0
STC 1F-1
SETi1
377
SETi3
-17
LDAi
-340
DIS 1
ADAi
1
SROi
3737
JMP p-5
ADAi
32
XSKi3
JMP p-4
JMP 1F-1
[PADDLE - BALL COINCIDENCE
#1L ADD 3L
JMP p+2
#1R ADD 3R
COM
ADD 2Y
STAi
#2S 0000 [NEG.IF BALL BELOW PADDLE,POS.IF ABOVE
SCR 1
AZEi
JMP 4A [DIFF.0,1
SCR 1
AZEi
JMP 4B [DIFF.2
SCR 1
AZEi
JMP 4C [DIFF.4
SCR 1
AZEi
JMP 4D [DIFF.10
SCR 1
AZEi
JMP 4E [DIFF.20
JMP 4F [MISSED
#4A ADD 6K
STC 1T
JMP 4L-1
#4B ADD 5K
STC 1T
ADD 1K
JMP 4L-1
#4C ADD 5K
JMP 4D+1
#4D ADD 3K
STC 1T
ADD 2K
JMP 4L-1
#4E ADD 3K
STC 1T
ADD 3K
STC 2V
#4L LDA
2S
APOi
JMP p+5
LDA
2V
COM
STC 2V
LDA
2H
COM
SCR 13
BCOi
#1T 0000
STC 2H
JMP 1C-1
[SCORE?
JMP 000
#1J LDA
0
STC 1J-1
LDA
2X
SCR 2
AZEi
JMP 5R
LDA
2X
ADAi
-777
SCR 2
AZE
JMP 1J-1
#5L LDAi
1
ADD 5B
STC 5B
STC 1S
JMP p+7
#5R LDAi
1
ADD 5A
STC 5A
COM 
STC 1S
SETi10
0
#5D LDAi
#5A 0000
ROL 2
ADAi
5M-1
STC 2
SETi1
600
SETi3
-4
CLR
DSCi2
XSKi3
JMP p-2
LDAi
#5B 0000
ROL 2
ADAi
5M-1
STC 2
SETi1
140
SETi3
-4
CLR
DSCi2
XSKi3
JMP p-2
XSKi10
JMP 5D
LDA
5A
SHDi
1200
JMP 5D-2
LDA
5B
SHDi
1200
JMP 5D-2
JMP 1Z
#5M 0000
0000
4136
3641 [0
0000
0000
0000
0077 [1
0000
0000
4523
2151 [2
0000
0000
4122
3651 [3
0000
0000
2414
0477 [4
0000
0000
5172
0651 [5
0000
0000
1506
4625 [6
0000
0000
4443
6050 [7
0000
0000
5123
2651 [8
0000
0000
5122
3651 [9
7700
0000
4136
3641 [10
[END MATRICES
[END PONG
[1 DEC 75