Directory of image this file is from
This file as a plain text file

[PRINT MANUSCRIPT
[QUARTER 2,3
[CONVERT WITH TT SRS
[BLOCK 322
$1000
RDC 7E
3|7D+35
CLR
ADD 1377 [BN
BSE i
6000
STC 5B+1
ADD 1376 [RDC u
STA
5B+7
BSE i
i    [RDC i u
STC 5B
SET i 5
6E
SET i 3
9J+2
LDA 5 [1ST LN
AZE i
JMP p+6
ADA i
-1
AZE i
COM
STC 5K-4 [REQUEST
ADD 5A+1  [1
STC 8L [PAGE #
LDA i 5
AZE
STC 5K+7 [2ND LN
LDA i 5
SAE i
7777
JMP p+3
LDA i
6312
STA 3
LDA i 5
STA i 3
LDA i 5
STA i 3
LDA i 5
STA i 3 [MOVE NAME
LDA i 
-0
STA i 3
SET i 15
RCG 7E
SET i 3
7401
SET i 5
-1
LDA
5A+3 [PRESENT LN
SAE i
0   [1ST LN
JMP 5S
ADD 5A+1 [1
STC 8C [LINE #
#5K JMP 8Z [PAGE PRESET
JMP 8X [LINE FEED
SET i 13
-100
LDA
5A+3
SAE i
7776
JMP 5L [PRINT LINE
[DONE
JMP 8B-1 [WAIT FOR KEY
[PARTIAL PRINT
#5S JMP 5A [UP LINE
LDA i
12
SHD i 3
JMP 5K-7
JMP p-2
[PRINT LINE
#5L JMP 5A [UP LINE
SET 2
3
LDH i 2 [1ST CHARACTER
SHD i
7700
JMP 8A [DONE
SHD i
2200
JMP 5M
SHD i
6600   [$
JMP 5M
JMP 8W-2 [SPACE4
JMP 8W-2
JMP 8W-2
JMP 8W-2
SET i 13
-74
#5M LDH i 3
SHD i
1200
JMP 5P [EOL
JMP 8W [PRINT CHAR
LDH 3
SHD i
1400
JMP 5C [COUNT TO NEXT SPACE
#5N XSK i 13
JMP 5M
LDH i 3
SHD i
1200
JMP 5P
[TT LINE CONTINUES PAST PAGE BREAK
XSK i 5
JMP p+2
JMP 8Z [PAGE PRESET
JMP 8X
SET i 13
-100
LDH 3
JMP 5M+4
[COUNT TO NEXT SPACE OR EOL. DO NOT BREAK WORDS AT END OF TT LINE.
#5C SET i 4
1
SET 2
3
LDH i 2
SHD i
1200
JMP p+5
XSK i 4
SAE i
14
JMP p-7
LDA
13
ADD 4
APO
JMP 5N [WILL FIT
LDA i
-101
ADD 4
APO i
JMP 5N [WONT FIT ON ONE LINE ANYWAY
JMP 5N+2 [PUT ON NEXT LINE
[EOL
#5P LDA
5A+3
ADD 5A+1 [1
STC 8C  [LINE #
#5Q XSK i 5
JMP 5K+1
JMP 5K
[MS ADDRESS CHECK AND UP LINE NUMBER
#5A LDA i
1
ADM i
0  [CURRENT LN
LDA
3
BCL i
4000
ADA i
-3377
APO
JMP 0 [STILL IN QUARTER 6
#5B READ TAPE
QUARTER 6
ADD p-1
ADA i
1001
APO
STC p+2
READ TAPE
7|777
ADD 5B+1
ADD 5A+1
STC 5B+1
ADD 3
ADA i
-400
STC 3
JMP 0
$1376
RDC 7B
7A
6E=2371
9J=771
[CONVERT WITH TTSRS
[PMAPR13
$1400
[TT SRS
[77-END PRINT
LDA i
-4
ADM
5
SAE i
-4-70
JMP p+2
JMP 8B-1
JMP 8T
#8A XSK i 5
JMP p-2
LDA i
17  [-
JMP 8W
KBD i  [WAIT FOR KEY
#8B SET i 16
7|7D
JMP 15
[PAGE PRESET
#8Z SET i 5
-4
SET 14
0
JMP 8X
JMP 8T
XSK i 5
JMP p-2
LDA i
17
JMP 8W [-
JMP 8X
JMP 8T
LDH
9J+2
SHD i
6300
JMP p+7
SET i 2
9J+2-4000
JMP 8Y [NAME
LDA i
63
JMP 8W [,
LDA i
#8L 0   [PAGE #
JMP 8P 
LDA i
1
ADD p-4
STC p-5
ADD 8C  [LINE #
AZE i
JMP 8X-5
JMP 8W-2 
JMP 8W-2
SET i 2
8S-2-4000
JMP 8Y  [LN=
LDA i
#8C 0   [LN
JMP 8P  [PRINT #
JMP 8X
JMP 8T
SET i 5
-70  [LINES|PAGE
JMP 14
[KST, CARRIAGE RETURN
#8X SET 7
0
KST
JMP p+5
KBD
SHD i
1200
JMP 8B [END PRINT
LDA i
12
JMP 8W [CARRIAGE
LDA i
3424
JMP 8W+4 [LINE FEED
JMP 7
[LINE FEED ONLY
#8T SET 7
0
JMP 8T-4
[PRINT #, LEADING ZEROS
#8R SET 4
0
JMP 8M
JMP 8W
JMP 8N
JMP 8R+2
[PRINT #, NO LEADS
#8P SET 4
0
AZE
JMP p+3
JMP 8W
JMP 4
JMP 8M
AZE
JMP 8R+3
JMP 8N
JMP 8P+6
[# SRS
#8M ROL 3
STA i
NUMBER
BCL i
7770
JMP 0
#8N LDA
8M+2
SRO i
3567
JMP 0
JMP 4
[PRINT
LDA i
14 [SPACE
#8W ADA i
8U
STC 17
LDA 17
SET 17
0
STC p+7
RTA
SET i 11
-13
#8V BCL i
1
SRO i
TT CODE
ADD p-3 [1
ATR
SET i 12
-430
XSK i 12
JMP p-1
XSK i 11
JMP 8V
JMP 17
[PRINT LINE OR LABEL
SET i 2
8S-4000
#8Y SET i 13
0   [CHARS|LINE
SET 7
0
LDH i 2
SHD i
1200
JMP 7 [END LAP LINE
SHD i
7700
JMP 7 [END NAME
JMP 8W
XSK i 13
JMP 8Y+4
LDH i 2 [END OF TT LINE
SHD i
1200
JMP 7
XSK i 5
JMP 8J
[TT LINE CONTINUES PAST PAGE BREAK
#8K LDA
2
STC p+6
JMP 8Z [PAGE PRESET
SET i 2
5T-4000
JMP 8Y [LABEL
SET i 2
RESET
#8J JMP 8X
SET i 7
JMP 5M+2
SET i 14
-12
JMP 8W-2
XSK i 14
JMP p-2
SET i 13
-66
LDH 2
JMP 8Y+5
[LIST HEADINGS
3741  [LN=
6112
#8S 1414 [VALUE LINE
5124
3750
3014
3734
4130
1414
1412
[TELETYPE CODES
#8U 3540
3542
3544
3546
3550
3552
3554
3556
3560
3562
3432 [EOL
3576
3500
3514
3516
3532
3526
3670
3506
3576
3602
3604
3606
3610
3612
3614
3616
3620
3622
3624
3626
3630
3632
3634
3636
3640
3642
3644
3646
3650
3652
3654
3656
3660
3662
3664
3576
3576 [META
3576 [?
3572
3512
3530
3534
3510
3666
3600 [_
3674 ["
3566 [;
3570 [<
3574 [>
3672 []
3524 [*
3564 [:
7A=350
7B=0
7D=300
7E=0
[TELETYPE SUBROUTINES FOR LIST, PRINT MS, AND PRINT INDEX
[Q3
[TTJAN20