Directory of image this file is from
This file as a plain text file

$0
[RUN PROCESSOR FOR
[THE BASIC LANGUAGE 
[SYSTEM
$1
NOP
[X5  USED AS A TEMP
[X4  PROCESSOR STACK,LAST FILLED
[X3  DATA STACK,LAST FILLED
SET 3
1767
SET 4
1766
[
LDA  [6
1750+10  [U|FB2[FD3]
BCL i
6777
ROR 6
ADD 1J+10  [=RDC
STA
1J+10
STC 1F+20
NOP  [17
[
[
3A=1770  [PC1,PROGRAM COUNTER BLOCK
3B=1771  [PC2,PROGRAM COUNTER WORD
[
[LOCATION 20
$20
[BEGIN CYCLE
#4A LDA
3A  [BLOCK,PC1
COM
ADA i
#1J 1000  [PROGRAM BIC
AZE i
JMP p+13  [CORRECT BLOCK IS IN CORE
LDA i
6|0  [Q6|0
ADD 3A  [BLOCK,PC1
STC p+3
UMB 9Z  [P3
RDC
0  [READ PROGRAM BLOCK
LDA
3A  [PC1
STC 1J  [SET NEW BIC
LDA i
3000  [Q6 BASE ADDR
ADD 3B  [PC2
STC 4H+12
[
[
[INCREMENT PC
[
[
CLR  [LINK=0
LDA i
#4H 1  [CONSTANT
ADM
3B  [WORD,PC2
ROL i 4
ROR 4
STC 3B  [PC2
LAM
3A  [PC1
UMB 9Z  [P3
LDA
0  [CURRENT INSTR ADDRESS
[
[EXIT SWITCH
[
NOP
[
[
APO i
JMP p+10  [JMP=>NOT SL#
[
[CSL PROCESSING
[
COM
STA
2B  [CSL
SRO
1750+22  [TRACE INDICATOR
JMP 6O  [TRACE
JMP 4E  [NO TRACE-TEST KST
[
ROL 1
APO i
JMP p+15  [NOT TAG
[
[TAG PROCESSING
[
STC p+3  [SAVE
JMP 3D  [PUSH PS
LDA i
0
ROR 1
BCL i
6000
UMB 9X  [P1
STA 4  [B11=0=>NO DS PTR
LDA i
5400
JMP 3F-4  [STA i 4,RESET PS PTR,4E
[
ROL 1
APO i
JMP 3F  [JMP=>OPERATOR
[
[OPERAND PROCESSING
[
ROR 2
BCL i  [REMOVE INSTR CODE
7000
[ACC=CODE FOR DATA LOCATION
JMP 4B  [CONVERT TO BLOCK-WORD FORM
SET 5
1  [SAVE PTR TEMPORARILY
JMP 3D  [PUSH PROCESSOR STACK
[4 PTS TO THE TOP OF THE PROCESSOR STACK
LDA 5  [WORD
UMB 9X  [P1
STA 4  [>0=>NO DS-PTR
STA i 4  [SET WORD
LDA i 5  [BLOCK
ADA i
11  [SYMBOL TABLE ALLOTMENT-1
BCO i
0777
ADD 2D  [U|FB2[FD3]
BCL i
7000
STA i 4
SET 4  [RESTORE 4
1H
[
[EXIT SWITCH 2
JMP 4E  [TEST FOR KST
[
[
[ OPERATOR PROCESSING
[
[
#3F ROR 1
ADA i
4D  [TABLE BASE
STA 
1
SCR 7
SAE i
0017
JMP 6R  [ILLEGAL OP CODE
UMB 9Y  [P2
LDA 1
STC p+3
LDA i 1
STC p+2
0  [OPERATOR JUMP 1
0  [OPERATOR JUMP 2
[
[
[ACC=LVI OR OPERAND CODE TO BE DECODED
#4F 0  [TEMP
0  [W1  WORD COUNT
7777
0  [W0
0  [TEMP
0  [BLOCK COUNT
[ALGORITHM:  SUBTRACT 10 BLOCKS AS LONG AS POSSIBLE USING
[DOUBLE WORD ARITH.
[THEN FINISH USING 1 BLOCK DECREMENTS USING SINGLE WORD ARITH
#4B STC 4F
ADD 0
STC 4G+5
ADD 4F
MUL
4|2F  [LEN FP #
AZE i
JMP 3H-3  [USE SINGLE P ARITH
SCR i 1
STC 4F+3  [W0
ROR i 1
STC 4F+1
ADD 4F  [LVI
MUL
2F  [LEN FP #
ADM
4F+1
LDA
2G  [-#WDS|D-BLOCK
ROL 3  [-#WDS|10 D-BLOCKS
STC 4F
STC 4F+5  [0->BLOCK COUNT
SET i 1
4F
LDA 1
LAM i 1
LDA i 1
LAM i 1
STC 4F+4  [0->ACC
LAM
4F+1
STC 4F+4
LAM 1
AZE i
JMP p+6
LDA i
10  [BLOCK COUNT INCREMENT
XSK i 1
ADM i 1
JMP p-21
ADD 4F+1
APO
JMP 0
LDA i
10
JMP 4G-3
ZTA  [3H-3
STC 4F+1
STC 4F+5
#3H LDA
4F+1  [WORD COUNT
ADA
2G  [-#WDS|D-BLOCK
APO
JMP 4G
STC 4F+1
LDA i
1
ADM
4F+5  [BLOCK COUNT
JMP 3H
#4G LDA
4F+1  [WORD COUNT
STC 4F+4
SET i 1
4F+4
[1 PTS TO WD AND BLOCK
JMP  [EXIT
[
[
[CONSTANTS CARRIED FROM SCAN PROGRAM
2C=1756  [FB1[FD3]
2D=1760  [U|FB2[FD3]
2E=1753  [FB1[FD2]
2F=1777  [LEN FP #
2G=1776  [-#WDS|D-BLOCK
2B=1774  [CSL
3Z=1764
1G=1767  [DATA STACK POINTER
1H=1766  [PROCESSOR STACK POINTER
[
[
[PARAMETERS
[
9W=0  [PAGE 0
9X=1  [PAGE 1
9Y=2  [PAGE 2
9Z=3  [PAGE 3
1A=4000  [PROCESSOR STACK HI
2H=3400  [DATA STACK LO
6S=0  [RBN COMPILER
6T=14  [RBN ERROR PROC
6U=24  [RBN ERROR FILE
6V=34  [RBN TRANSITION PROGRAM
6W=50  [RBN RUN PROCESSOR
6X=62  [RBN ERROR PROC
6Y=72  [RBN SYSTEM FUNCTIONS
[
[END OF PROCESSING
[AND ERROR EXIT
[MUST RESIDE IN PAGE 0
#4N JMP 6I  [OUTPUT LAST DATA BLOCK
LDA i
RCG
STC 15
[READ IN LAP6 FROM UNIT 0
UMB 9X
LDA i 
7300
STC 16
JMP 15  [TRANSFER TO LAP6
[
[MUST RESIDE IN P0 AND NOT AT ADDR 1000-1377
#2A LDA
0
STC 1773
JMP 6I  [OUTPUT DATA BIC
LDA
1J  [PROGRAM BIC
STC 1750+15
LDA
1755  [U|FB2[SYSTEM FILE
BCL i
6777
ROR 6
ADM
p+5  [=RDC
[
LDA i
2|6X  [QN2,RBN OBJECT TIME ERROR PROC
ADD 2E  [FB1[SYSTEM FILE]
STC p+2
RDC
0  [QN|BN
[
JMP 1000  [ENTER ERROR PROC
JMP 1B  [POP TOP OF STACK
[1B MUST NOT BE IN ADDR 1000-1377
LDA i
2|6W+2  [RBN OF NON-SELF MOD CODE
ADD 2E  [FB1[SYSTEM FILE]
STC p+10
ADD 1750+5  [U|FB2[SYSTEM FILE]
BCL i
2777
ROR 6
ADD p+2
STC p+1
RDC
QN|BN
LDA
1750+15
STC 1J  [PROGRAM BIC
JMP 6  [REINIT READS
[
[END OF BASIC INTERPRETER
[8|12|69
[
[
[THE FOLLOWING ROUTINE IS USED BY #2A AND MUST NOT RESIDE IN Q2
[POP PROCESSOR STACK
[
#1B SET 1
1H  [PROCESSOR STACK PTR
LDA
0
STC p+12
UMB 9X  [P1
LDA 1  [DS-PTR
APO
JMP 1C  [POP DS ENTRY
LDA i
3  [LEN PROC STK ENTRY
ADM
1H
STC 4
JMP  [EXIT
[
[DS-POP
[ACC=DS-PTR
#1C STC 1
LDA i
0077
UMB 9X  [P1
STA i 1  [POP THE ELEMENT
SET 1
0
[CLEAN-UP
LDA
1G  [DATA STACK PTR
STA
3
SAE i
2H-5  [STACK LIMIT CHECK
APO  [SKIP
JMP 1  [RETURN
LDA i 3  [WD 2 OF TOP ENTRY
SET 3
1G  [RESTORE 3
SAE i
0077  [POPPED INDICATOR
JMP 1  [RETURN
LDA
2F  [LEN FP #
COM
ADM
1G
JMP p-21  [CHECK FOR MORE
[
[OPERATOR CODES FOR
[THE BASIC LANGUAGE SYSTEM
[
[
[NEGATION OPERATOR  3
#2L JMP 1K  [FETCH TOP
LDA 11
BCO i
4000  [REVERSE SIGN
STA 11
JMP 4E
[
[ASSIGNMENT OPERATOR 7
#2P JMP 1K  [FETCH TOP
JMP 9V+6  [ADDR OF E1 OF PS
STC 4
[4 CONTAINS PTR TO 2ND ELEMENT IN THE STACK
JMP 1M
[ACC=-1
JMP 7V  [STORE DATA
JMP 1B  [POP ARG1
JMP 1B  [POP ARG2
JMP 4E
[
[ADDITION OPERATOR  1
#2J LDA i
JMP 8A
JMP 2N+2
[
[SUBTRACTION OPERATOR  2
#2K LDA i
JMP 8Q
JMP 2N+2
[
[MULTIPLY OPERATOR  4
#2M LDA i
JMP 8R
JMP 2N+2
[
[
[DIVIDE OPERATOR  5
#2N LDA i
JMP 9A
JMP 7U  [CREATE FLOD CALL
LDA
9O-6+2000  [ARG A
STA
9O-4+2000  [ARG A IS ALSO RESULT
LMB 9X  [P1
JMP 9O
JMP 1B  [POP PS
JMP 4E
[
[RELATIONAL OPERATORS
[
[=  10
#3I LDA i
AZE i  [TEST FOR F
JMP 3N+2
[<  11
#3J LDA i
APO i  [TEST FOR F
JMP 3N+2
[<=  12
#3K LDA i
JMP 3K+3
JMP 3N+2
AZE i
JMP 0
APO
XSK i 0
JMP 0
[<>  13
#3L LDA i
AZE  [TEST FOR F
JMP 3N+2
[>  14
#3M LDA i
JMP 3M+3
JMP 3N+2
APO
AZE i
XSK i 0
JMP 0
[>=  15
#3N LDA i
APO  [TEST FOR F
STC 3N+6
JMP 1L  [FETCH ARG1
JMP 1K  [FETCH ARG2
JMP 7T  [COMPARE
[
[CRUCIAL TEST FOR F
[F=>SKIP  T=>NO SKIP
[
0
[
[
[
JMP p+5  [TRUE BRANCH
LDA i
JMP 4E-3  [RESET EXIT SWITCH
STC 4H+13
JMP 2P+5  [POP 2
JMP 1B  [POP ARG2
JMP 1B  [POP ARG1
JMP 4I  [BRANCH
[
[GOSUB  17
#3P JMP 3D  [PUSH PS
JMP 5T  [SAVE PC
SET 4
1H
LDA i 4
BSE i  [SET GOSUB LINK FLAG
2000
STA 4
JMP 4I  [BRANCH
[
[BRANCH  20
#4I LDA i
JMP 4I+4
STC 4H+13  [SET EXIT SWITCH
JMP 4A  [INPUT
ADA i
2000  [CODE =2000+2000=4000
ROR 1  [PRODUCE ADDR 2000+
STC 11  [ADDR OF JMP TABLE ENTRY
UMB 9Y  [P2
LDH 11
STH i
0
LDH i 11
STH
4|p-3
STH i
0
LDH i 11
ADD p-2
SHD i
7700
JMP p+13  [CHECK DEF
BCL i
7000
STC 3B  [PC2
LDA
p-17
ROR 3
BCL i
7000
STC 3A  [PC1
JMP 4E-3  [RESET EXIT SWITCH
[
SAE i
7777
JMP 0  [DEFINED
SAE
p-31
JMP 0  [DEFINED
JMP 6M  [UNDEFINED LABEL
[
[STACK CONSTANT OF "1."  31
#2R JMP 3D  [PUSH PS
JMP 1E  [PUSH DS
LDA i
4000  [DS-PTR DEFINED FLAG
ADD 3  [DS PTR
UMB 9X  [P1
STA 4
LDA i
5400  [FLAGS
STA i 4  [SET FLAGS
LDA i
0001  [EXP FOR 1.
STA 3
ROL 6
STA i 3
CLR
STA i 3
STA i 3
STA i 3
JMP 4E
[
[INCR FOR FOR  32
#2S LDA i
JMP 8A  [ADD ENTRY
JMP 7U  [CREATE ADD
LDA
9O-5+2000  [ARG B
STA
9O-4+2000  [ARG B IS ALSO RESULT
LMB 9X  [P1
JMP 9O  [INCREMENT
SET 4
1H
UMB 9X  [P1
LDA 4  [DS-PTR
STC 11
JMP 1M
JMP 7V  [STORE VARIABLE
JMP 4E
[
[PART OF FOR  33
#2T JMP 3D  [PUSH PS
JMP 5T  [PUSH [PC]+1
LDA i
10
ADD 1H  [PS PTR
STC 16
LDA i
-1
ADD 1H  [PS PTR
STC 17
SET i 15
-3  [#WORDS |PS ENTRY
[UMB=9X  FROM 5T ABOVE
[INTERCHANGE VARIABLE AND LINK
LDA i 16
STC p+4
LDA i 17
STA 16
LDA i 
0
STA 17
XSK i 15
JMP p-10
[
JMP 4I  [BRANCH
[
[RETURN  34
JMP 1B  [POP PROCESSOR STACK
#2U SET 4
1H  [SET PS PTR
LDA i
-4000
ADD 4
AZE i
JMP 6N  [NO STACK ENTRY
UMB 9X  [P1
LDA i 4  [LOAD WORD ENTRY
SCR 10  [ISOLATE FLAGS
SAE i 
0007
JMP 2U-1  [NOT ADDR ENTRY
LDA 4
BCL i  [ISOLATE WORD ADDR
7400
STC 3B  [PC2,WORD
LDA i 4
STC 3A  [PC1,BLOCK
JMP 1B  [POP PROCESSOR STACK
JMP 4E  [TEST KST
[
[SUBROUTINE TO EXAMINE
[SIGN BIT OF 2ND STACK
[ELEMENT
LDA i
3  [LENGTH OF PS ENTRY
ADD 1H  [PS PTR
STC 1
UMB 9X  [P1
LDA 1
STC 1
LDA 1
APO
XSK i 0  [STEP<0=>[0]+1 RETURN
JMP 0  [RETURN VIA 0
[
[COMPARE FOR FOR  36
#2W JMP 9V  [ADDR OF LINK IN STACK
STC 1
UMB 9X  [P1
LDA i 1  [LOAD WORD PORTION
SCR 10  [ISOLATE FLAGS
SAE i
0003
JMP 6N  [NEXT ERROR
JMP 9V+3  [E3 OF PS
STC 4
JMP1K+2
SET 12
11
JMP 1K  [SET R11
JMP 7T  [COMPARE VAR:LIM
[ACC=SIGNIFICANT WORD OF VAR-LIM
AZE i
JMP p+5  [REPEAT LOOP
APO
JMP p+12  [VAR<LIM
JMP 2W-13  [STEP:0
JMP p+5  [STEP>=0,FOR COMPLETED
[REPEAT LOOP
JMP 9V [ADDR OF E4 OF PS
STC 4
XSK i 4
JMP 2U+15  [TRANSFER AND POP PS
[FOR COMPLETED
JMP 1B  [POP PS
JMP 1B  [POP PS
JMP 2P+5  [1B,1B,4E
[VAR<LIM
JMP 2W-13  [STEP:0
JMP p-10  [STEP>=0,CONTINUE LOOP
JMP p-5  [STEP<0,DONE
[
[PUSH TOP PS AND COPY
[PART OF FOR  37
#2X SET 17
1H  [PS PTR
JMP 3D  [PUSH PS
UMB 9X  [P1
LDA 17
STA 4
LDA i 17
STA i 4
LDA i 17
STA i 4
JMP 4E
[
[
[UTILITY ROUTINES
[
[
[SET UP ARG 2
[MUST BE DONE BEFORE ARG1
#1L LDA
0 [LINKAGE
STC p+6
JMP 9V+6  [A[E2] OF PS
STC 4
JMP 1K+2
SET 12
11
JMP  [EXIT
[SET UP TOP OF PROC STACK
#1K SET 4
1H
UMB 9X  [P1
LDA 4  [DS-PTR
STA
11
APO
JMP 0  [DS-PTR DEFINED
SET 10
0  [LINKAGE
JMP 1E  [PUSH DATA STACK
LDA i
4000  [DS-PTR DEFINED FLAG
ADD 3  [DS-PTR
STA 4
STC 11
[DS-PTR NOW DEFINED
JMP 1M
ADM 
3
[MOVE DATA TO STACK
UMB 9Z  [P3
LDA i 1
UMB 9X  [P1
STA i 3
XSK i 5
JMP p-5
LDA
11
JMP 10  [EXIT
[UTILITY ROUTINE
#1M LDA i 4  [FLAG|WORD
BCL i
7400
ADA i
3377  [O-BUF -1
STC 1
LDA i 4  [BLOCK
SET 5
0  [LINKAGE
JMP 1F
SET 0
5
LDA
2F  [LEN FP #
COM
STC 5
LDA i
-1
JMP 0
[
#5T CLR  [LINK<-0
UMB 9X  [P1
STA 4  [NO DS-PTR DEFINED
ADD 4H  [=1
ADD 3B  [WORD,PC2
ROL i 4
ROR 4
BSE i
1400  [STACK CODE
STA i 4
SCR 13  [0->ACC
ROL i 1  [LINK->ACC
ADD 3A  [BLOCK,PC1
STA i 4
JMP 0
[
[DEVELOP STACK ADDRESS
[ENTRY 4 OF PS
#9V CLR
ADD 1B+12  [=3
APO
[ENTRY 3  9V+3
CLR
ADD 1B+12  [=3
APO
[ENTRY 2  9V+6
CLR
ADD 1B+12  [=3
APO
[ENTRY 1  9V+11
CLR
ADD 1H  [PS PTR
JMP 0  [RETURN VIA 0
[
[
[ACC=-1
#7V ADD 11
STC 11
ADD 0  [LINK
STC p+10
STC 3C  [BIC CHANGED
UMB 9X  [P1
LDA i 11
UMB 9Z  [P3
STA i 1
XSK i 5
JMP p-5
JMP  [RETURN
[
[ACC=JMP TO FLOD PKG
#7U UMB 9X  [P1
STA
9O-7+2000  [OP
SET 17
0  [LINK
JMP 1L  [FETCH STK2
BCL i
2000
STA
9O-6+2000  [ARG A
JMP 1K  [FETCH STK1
[FLOD IN P1 AND WORK AREA IN P2=>P1 STACK ADDR<2000
BCL i
2000
STA
9O-5+2000  [ARG B
JMP 17  [RETURN
[
#7T SET 17
0  [LINK
JMP 1M+14
ADM
12
JMP 1M+20  [-1->ACC
ADM
11
[
LDA i 12  [COMPARE EXP AND SIGN
BCO i 11
APO i
JMP p+6  [NUMBER SIGNS SAME
LDA 11  [NUMBER SIGN DIFFERENT
SCR 13
BCO i  [INSURE NON-ZERO
0252
JMP 17  [EXIT
[
ROL 2
STC p+5
LDA 12
COM
ADA 11
SRO i
0
COM
JMP p+4
[
LDA i 12
COM
ADA i 11
AZE
JMP 17  [RETURN
XSK i 5
JMP p-6
JMP 17  [RETURN
[
[
[
[PUSH PROCESSOR STACK
[
#3D LDA i
-3
ADM
1H  [PROCESSOR STACK PTR
STA
4
COM
ADD 1G  [CURRENT DS-PTR
APO i
JMP 6L  [OVERLAP STACKS
JMP 0  [RETURN VIA 0
[
[PUSH DATA STACK
[
#1E LDA
2F  [LEN FP#
ADM 
1G  [CURRENT DS-PTR
STA
3
ADA
2F  [LEN FP #
COM
ADD 1H  [PS PTR
APO
JMP 6L  [OVERLAP STACKS
JMP 0  [RETURN VIA 0
[
[DATA BLOCK TO CORE
[ACC= BLOCK REQUESTED
[
#1F STA i
0  [SAVE BLOCK
COM
ADA i
#1I 1000  [BIC
AZE i
JMP 0
LDA
0
STC p+14
JMP 6I  [WRITE OUT BIC
[READY TO READ BLOCK
LDA i
7|0
ADD 1F+1  [BLOCK REQ
STC p+3
UMB 9Z  [P3
RDC
0
STC 3C  [7777=>BIC NOT CHANGED
ADD 1F+1  [BLOCK REQ
STC 1I  [UPDATE BIC
JMP  [EXIT
[
[WRITE OUT DATA BIC
#6I SRO i
#3C 7777  [0=>BIC CHANGED
JMP 0  [NOT CHANGED,NO WRITE REQUIRED
LDA i
7|0  [DATA BUF=Q7,P3
ADD 1I  [BIC
STC p+6
ADD 1J+10  [=RDC
ADD 3D+5  [=4=WRC
STC p+2
UMB 9Z  [P3
0  [WRC
0  [5|BIC
STC 3C  [7777=>BIC NOT DIF TAPE
JMP 0  [RETURN VIA 0
[
[
[END OF OPERATOR CODE
[
[
[
[RESET EXIT SWITCH
[
LDA i
NOP
STC 4H+13
#4E KST
JMP 4A
KBD
SAE i
0012  [EOL
JMP 4A  [IGNORE NON EOL
JMP 6O  [USER QUERY
[
[
[
[RUN PROCESSOR 
[PRINT
[
[ACC=LINC CODE CHAR
[OUTPUT CHAR TO TELETYPE
#4X ROR 1
ADA i
3Y
STC 1
[LINKAGE
ADD 0
STC 4X+20
UMB 9Y  [P2
LDH 1
ADA i
1640
ROL 1
[ACC=TELETYPE CODE
[TELETYPE CODE IS
[B11=0
[B8-10=1
[B1-B7=ASCII CODE[REVISED
[B0=0
JMP 3X  [SEND TO TELETYPE
LDA i
1
ADM 
3Z  [CCP
[CCP=CURRENT CARRIAGE POSITION
JMP  [RETURN
[
[CR-LF
#4W LDA
0
STC 4W+13
STA
3Z  [0->CCP
LDA i
3432  [CR
JMP 3X
LDA i
3424  [LF
JMP 3X
JMP  [RETURN
[
[
[TELETYPE OUTPUT ROUTINE
#3X SET 1
0  [LINK
STC p+5
MSC 4
APO i
JMP p+7
LDA i
TT CODE
ROR 1
OPR 42
JMP p-1
JMP 1  [RETURN
ADD 1
STC p+13
LDA
3X+7
ATR
SET i 1
-435
XSK i 1
JMP p-1
SCR 1
AZE
JMP p-7
JMP  [RETURN
[
[
[
[PRINT STACK  23
#4L LDA i
-110+17  [# CHAR|LINE-MIN REMAINING
ADA
3Z  [CCP
APO i
JMP 4W  [CR-LF
[PREPARE STACK TOP
JMP 1K
LDA
11
BCL i
2000
UMB 9X  [P1
STA 
2011
[GET NEXT CHAR
LMB 9X  [P1
JMP 1V+1
JMP 2P+6  [DONE
JMP 4X  [OUTPUT
JMP p-4
[
[
[PRINT TAB  24
#4M LDA
3Z  [CCP
ADA i
22-110+1
[LINE POSITIONS 66 THRU 107=>CR-LF
APO
JMP p+3
JMP 4W  [CR-LF
JMP 4E
[
LDA
3Z  [CCP
ADA i
-22
APO
AZE i
JMP p-4
STC 15
LDA i
14  [SPACE
JMP 4X  [OUTPUT
XSK i 15
JMP p-4
JMP 4E
[
[PRINT CR-LF  21
#4J JMP 4W
JMP 4E
[
[
[PRINT TEXT  22
#4K LDA i
JMP 1P
STC 4H+13  [SET EXIT SWITCH
LDA
3Z  [CCP
ADA i
-110+1  [END OF LINE TEST
APO i
JMP 4W  [CR-LF
JMP 4A  [GET TEXT
#1P STA i
0
LDH
1P+1
SHD i
1300  [TEXT TERMINATOR
JMP 4E-3  [DONE- RESET SWITCH
JMP 4X  [OUTPUT
[ACC=CCP
ADA i
-110+1  [EOL TEST
APO i
JMP 4W  [CR-LF
LDH
4|1P+1  [NEXT CHAR
SHD i
1300  [TEXT TERMINATOR
JMP 4E-3  [DONE-  RESET SWITCH
JMP 4X  [OUTPUT
JMP 1P-5
[
[
[
[
[
[ERROR JMP LIST
$1740
#6K JMP 2A  [1
#6L JMP 2A  [2
#6M JMP 2A  [3
#6N JMP 2A  [4
#6O JMP 2A  [5
#6P JMP 2A  [6
#6Q JMP 2A  [7
#6R JMP 2A  [8
[
[SYSTEM CONSTANT AREA
[
[1750  FB1  FD 1  SOURCE FILE
[1751  CFP
[1752  U|FB2  
[1753  FB1  FD 2  SYSTEM FILE
[1754  CFP
[1755  U|FB2
[1756  FB1  FD 3  TARGET FILE
[1757  CFP
[1760  U|FB2
[1761  FB1  FD 4  DATA FILE
[1762  CFP
[1763  U|FB2
[1764  CURRENT TELETYPE CARRIAGE POSITION
[1765  LAST VARIABLE INITIALIZED
[1766  PROCESSOR STACK POINTER
[1767  DATA STACK POINTER
[1770  PC1-BLOCK-PROGRAM COUNTER|  BLOCK  CFP  ERROR FILE
[1771  PC2-WORD-PROGRAM COUNTER|  WORD  CFP  ERROR FILE
[1772  TRACE<=7777:  0=>NO TRACE
[1773  ERROR CODE
[1774  CSL=CURRENT SOURCE LINE
[1775  LAST VARIABLE USED
[1776  -#WDS|FP BLOCK
[1777  LENGTH FP #
[END OF PAGE 0
[
1V=1071
8Q=262
8R=270
9A=547
9O=30
8A=64
[RPP2 DEF
3Y=3340
4D=3600
[END OF GLOBAL DEF