Directory of image this file is from
This file as a plain text file

[SAMIMP5
[SAMPLING PROGRAM FOR IMPEDANCE DATA
[TAPE REPLAYED WITH SEARCH AND CONTROL PROVIDING A GROUND LEVEL ON XL 11 WHEN STARTING POINT REACHED
[TIME CODE UNIT PROVIDES A GROUND LEVEL ON XL 10 ONCE PER SECOND TO CONTROL SAMPLING
[RESISTANCE - SAM 11
[REACTANCE  - SAM 12
[100 C|S SUPPRESSION - SAM 13
[480 SAMPLES OF RESISTANCE AND REACTANCE STORED ALTERNATELY IN UPPER MEMORY
[NEXT STARTING POINT IS 8 MINUTES AFTER FIRST
[  --
[ ----
$20
[FIND NEXT AVAILABLE BLOCK
SETi1
-176
LDAi
6010
STC 3L
RDCui
#3L 6010
LDA
3077
SAEi
3456
JMP p+10
LDAi
4
ADM
3L
XSKi1
JMP 3L-1
JMP 2I
MTBu
0
LDA
3L
BCLi
2000
STC 2L
JMP 2U
[OPTIONS
#2G SETi1
2A+3777
JMP 2M
[TIME
#2W SETi1
2Y+3777
JMP 2M
JMP 2E
JMP 2W
STA
2000
JMP 2M
JMP 2E
JMP 2W
STA
2001
JMP 2M
JMP 2E
JMP 2W
STA
2002
JMP 2M
[FREQUENCY
#1I SETi1
2B+3777
JMP 2M
JMP 2E
JMP 1I
STA
2003
[RZS|2
#3A SETi1
2C+3777
JMP 2M
JMP 2E
JMP 3A
STA
1A
JMP 3B
[RCAL
SETi1
3C+3777
JMP 2M
JMP 2E
JMP 3A
STA
1D
JMP 3B
[XCAL
SETi1
4C+3777
JMP 2M
JMP 2E
JMP 3A
STA
1E
JMP 3J
[MESSAGE PRINT
#2M SET 10
0
SXL 1
JMP p+13
OPR 1
LDAi
64
JMP 7P
JMP 7P
JMP 7P
LDAi
12
JMP 7P
JMP 3J
LDHi1
SHDi
7200
JMP 10
JMP 7P
JMP 2M+2
[ENTER DIGITS
#2E SET 10
0
CLR
STC 2J
JMP 7R
SHDi
1300
JMP 2H
SHDi
1200
JMP 2J-1
SHDi
7600   [:
JMP 2J-1
SHDi
1400
JMP 2H
JMP 7P
SHDi
2600   [C
JMP 3A
SHDi
3200   [G
JMP 2K
SHDi
4300   [P
JMP 3H
SHDi
4700   [T
JMP 2W
SHDi
3000   [E
JMP 2S
SHDi
3100   [F
JMP 1I
SHDi
4100   [N
JMP 2U
SHDi
4500   [R
JMP 1L
SHDi
4600   [S
JMP 1M
SHDi
5300   [X
JMP 1K
ADAi
-11
APOi
JMP 2E+4
ADAi
11
AZEi
CLR
STC p+5
ADD 2J
MULi
12
ADAi
0000
STC 2J
JMP 2E+4
LDAi
#2J 0000
XSKi10
JMP 10
[SUPPRESSION CAL AND ZERO
#1M JMP 7R
JMP 7P
SHDi
2600   [C
JMP 1P
SHDi
5500   [Z
JMP p+2
JMP 2H
[ZERO
JMP 1T
ADD 1Z
COM
STA
1B
JMP 1S
[CALIB
#1P JMP 1T
ADD 1Z
STA
1C
JMP 1S
[RESISTANCE CAL AND ZERO
#1L JMP 7R
JMP 7P
SHDi
2600   [C
JMP 1Q
SHDi
5500   [Z
JMP p+2
JMP 2H
[ZERO
JMP 1T
ADD 1R
COM
STA
1F
JMP 1S
[CALIB
#1Q JMP 1T
ADD 1R
STA
1G
JMP 1S
[REACTANCE CAL AND ZERO
#1K JMP 7R
JMP 7P
SHDi
2600   [C
JMP 1Y
SHDi
5500   [Z
JMP p+2
JMP 2H
[ZERO
JMP 1T
ADD 1X
COM
STA
1H
JMP 1S
[CALIB
#1Y JMP 1T
ADD 1X
STA
1J
JMP 1S
[RZS OVER RCAL
#3B SET 4
0
LDA
1D
STC 7C
LDA
1A
JMP 2X
ROL 1
STA
2R
JMP 4
[DONE MESSAGE
#1S SETi1
2D+3777
JMP 2M
#3J OPR 1
SETi1
3K+3777
JMP 2M
JMP 2E
JMP 3J
JMP 3J
[DELETE
#2H LDAi
22
JMP 7P
SROi
3777
JMP p-5
JMP 10
[NORMAL ENTRY FOR DATA SAMPLING
#2K SETi2
2077
CLR
STAi2
XSK 2
JMP p-2
SETi2
2077
[DERIVE CORRECTIONS
#3H SETi1
1B-1
LDAi1
ADAi1
STAi1
LDAi1
ADAi1
STAi1
LDAi1
ADAi1
STAi1
[SAMPLING
[WAIT FOR BEGIN LEVEL
#2N SNSi0   [WRITE DATA NOW
JMP 2L-11
SXLi1  [TELETYPE
JMP 3J
SXL 11
JMP p-5
SXL 10
JMP p-7
[BEGIN SAMPLING
JMP 1N
LDA
1U
STC 7C
ADD 1R
ADA
1F
JMP 2X
STAi2
LDA
1V
STC 7C
ADD 1Z
ADA
1B
JMP 2X
ADA
2R
ADM 2
LDA
1W
STC 7C
ADD 1X
ADA
1H
JMP 2X
STAi2
XSK 2
JMP 2Q
LDAi
0007
STC 2L+2
JMP 2L-1
LDAi
1001
ADD 2L
STC 2L
WRCu
#2L 7777
SROi
0007
JMP 2L-5
LDA
2L
AZEi
JMP 2I  [FULL TAPE
BCLi
7000
ADAi
4001
STC 2L
JMP 2W
[EVALUATE RATIO X 40
#2X SET 10
0
STA
7A
SCR 13
STC 7B
JMP 7D
LDH
7A+4000
STH
7A
LDH
7B
STH
7A+4000
LDA
7A
SCR 1
JMP 10
[DELAY
[APPROX 500 MSECS
#2Q SETi15
2077
SETi16
1037
SETi17
5037
LDAi15
SCR 1
DISi16
LDAi15
DISi17
XSK 16
JMP 2Q+6
SROi
3737
JMP 2Q
JMP 2N
[TAPE FULL
#2I MTBui
0
SETi1
2P+3777
JMP 2M
WCGu
7000
HLT
JMP 2U
[EXIT
#2S JMP 7P
WCGu
7000
HLT
[SAMPLE R AND X AND 100 C|S CHANNELS
#1N SETi3
-10
SET 4
0
CLR
STC 1R
STC 1X
STC 1Z
SAM 11
ADD 1R
STC 1R
SAM 12
ADD 1X
STC 1X
SAM 13
ADD 1Z
STC 1Z
XSKi3
JMP p-12
JMP 4
[LARGER SAMPLE, 1.7 SECONDS
#1T SET 4
0
SETi3
-2000
CLR
STC 1R
STC 1X
STC 1Z
STC 3R
STC 3X
STC 3Z
[SAMPLING
#3F SETi6
1R-1
SETi5
3R-1
SAM 11
JMP 3D
SAM 12
JMP 3D
SAM 13
JMP 3D
XSKi3
JMP 3F
SETi3
-7
#3G SETi5
3R-1
SETi6
-6
LDAi5
RORi1
STA 5
XSKi6
JMP p-4
XSKi3
JMP 3G
CLR
JMP 4
[STORAGE
#3R 0
#1R 0
#3X 0
#1X 0
#3Z 0
#1Z 0
[DP SUM
#3D STAi
0000
SCR 13
STC 3E
CLR
ADD 3D+1
LAMi6
STC 3D+1
LDAi
#3E 0000
LAMi5
STC 3D+1
LAM 6
STC 3D+1
LAM 5
LDAi5
LDAi6
JMP 0
[DPDIV2
[DOUBLE PREC.
[DIVISION SUB-
[ROUTINE.
[ON ENTRY -
[DIVIDEND MSB
[IN 7A, LSB IN
[7B, DIVISOR
[IN 7C.
[ON EXIT -
[QUOTIENT MSB
[IN 7A, LSB IN
[7B, DIVISOR
[UNCHANGED IN
[7C. REMAINDER
[IN ACCUMUL.
[AJH APR.67
#7D LDA
0
STC 7A+10
LDAi
#7C 0
AZEi
JMP 0
APOi
COM
STC 7B-11
STC 7B-13
ADD 7A
STAi
0
APOi
JMP p+6
COM
STC 7A
ADD 7B
COM
STC 7B
LDAi
3777
STC 7B+2
ADD 7B-2
STC 7B+5
CLR
ADD 7B
ROLi1
STC 7B
ADD 7A
ROLi1
STC 7A
ADD 7B-13
ROLi1
STAi
0
ADAi
0
AZEi
COM
APO
JMP p+6
STC 7B-13
LDAi
1
ADMi
#7B 0
SROi
3777
JMP 7B-25
SROi
0001
JMP 7B-25
LDA
7C+11
APOi
JMP p+5
LDA
7B-13
COM
STC 7B-13
LDA
7C
BCO
7C+11
APOi
JMP p+10
LDAi
#7A 0
COM
STC 7A
ADD 7B
COM
STC 7B
LDA
7B-13
JMP 000
[EN DP-DIV-2
[MESSAGES
#2A"
 
 
E - EXIT,  T - TIME,  F - FREQUENCY,  N - NAME,
C - CALIBRATIONS [RZS, RCAL, XCAL],
RZ - RESISTANCE ZERO, RC - RESISTANCE CALIBRATE,
XZ - REACTANCE ZERO, XC - REACTANCE CALIBRATE,
SZ - SUPPRESSION ZERO, SC - SUPPRESSION CALIBRATION.
G - START SAMPLING,
P - PROCEED WITH INTERRUPTED SAMPLING
<;
#2Y "
TIME  <;
":<:<:<;
#2B"
FREQ. <;
#2C"
HALF OF RZS = <;
#3C",  RCAL = <;
#4C",  XCAL = <;
#2D"   DONE<;
#2P"-
-
**TAPE FULL**
LOAD  FRESH TAPE ON UNIT 1 AND START 20
<;
#3K"
? <;
[L6BUFTTY
[LAP 6 COMPATIBLE VERSION OF BUFFERED TELETYPE SUBROUTINES.
[READ AND PRINT
[ALPHANUMERICS
[SUBROUTINE.
[AJH REVISED
[JUNE 1967
[LAP 6 CHARACTER
[IN ACCUM.
[PRINT
#7P STC p+13
ADD 0
STC p+14
ADD p+10
ADAi
7L
STC p+2
LDA
0
OPRi2
LDAi
0
SAEi
12
JMP 000
SROi
5252
JMP p-3
LDAi
212
JMP p-13
[READ.LEAVES
[LAP 6 CHARACTER
[IN ACCUM.
#7R LDA
0
STC p+33
ADD 1
STC p+22
ADD 2
STC p+23
OPRi1
SETi1
-101
SETi2
7L-1
SAEi2
JMP p+21
LDAi
7L
COM
ADD 2
AZEi
COM
STC p+10
LDAi
0
STC 1
LDAi
0
STC 2
LDAi
0
JMP 000
XSKi1
JMP p-23
JMP p-14
[TABLE
#7L 260
261
262
263
264
265
266
267
270
271
215
377
240
246
247
255
253
257
243
215
301
302
303
304
305
306
307
310
311
312
313
314
315
316
317
320
321
322
323
324
325
326
327
330
331
332
251
000
277
275
245
254
256
244
333
300
336
273
274
276
335
252
272
207
[END SUBROUTINE L6BUFTTY.
[NAME - 12 CHARACTERS
SETi1
2T+12+3777
JMP 2U+3
#2U OPR 1
SETi1
2T+3777
JMP 2M
SETi1
2T+4+3777
LDAi
3777
STC p+20
JMP 7R
SHDi
1200
JMP 2G
JMP p+2
JMP 7R
SHDi
1300
JMP 2U-3
JMP 7P
SHDi
1200
JMP p+6
STHi1
SROi
3777
JMP p-13
JMP 2U
LDAi
14
STHi1
SRO
p-7
JMP p-3
JMP 2U
$2004
[CORRECTION FACTORS
#1A 0   [RZS OVER 2
#1D 0   [RCAL
#1E 0   [XCAL
#2R 0   [RZS OVER RCAL
#1B 0   [R100 ZERO
#1C 0   [R100 CAL
#1V 0   [R100 CAL - R100 ZERO
#1F 0   [RSIG ZERO
#1G 0   [RSIG CAL
#1U 0   [RSIG CAL - RSIG ZERO
#1H 0   [XSIG ZERO
#1J 0   [XSIG CAL
#1W 0   [XSIG CAL - XSIG ZERO
$2040
#2T" 
NAME  ????????????
      <;
$2077
3456
[END SAMIMP5
[LAST MOD 9 OCT 69